Sorry your browser is not supported!

set display mode 800,600,32
sync on
sync rate 60

hide mouse
autocam off

make object cube 1,25

rem red side
make object cube 2,25
color object 2,RGB(255,0,0)
ghost object on 2

rem cyan side
make object cube 3,25
color object 3,RGB(0,255,255)
ghost object on 3

glue object to limb 2,1,0
position object 2,5,0,0

glue object to limb 3,1,0
position object 3,-5,0,0

rem matrix for reference
make matrix 1,5000,5000,25,25
randomize matrix 1,100

color backdrop rgb(32,32,32)


do
   gosub _move_object

   sync
loop

_move_object:
   speed=5
   objx#=object position x(1)
   objz#=object position z(1)
   yang#=wrapvalue(object angle y(1)+mousemovex())

   yrotate object 1,yang#

   newx#=newxvalue(objx#,yang#,speed*(upkey()-downkey()))
   newz#=newzvalue(objz#,yang#,speed*(upkey()-downkey()))

   objy#=get ground height(1,newx#,newz#)+25

   position object 1,newx#,objy#,newz#

   set camera to follow newx#,objy#,newz#,yang#,100,objy#+30,1,0

return

` This code was downloaded from The Game Creators
` It is reproduced here with full permission
` http://www.thegamecreators.com

hide mouse

graphics:

rem set sync rate
sync on : sync rate 20

rem number of cubes to see
numobjects=4

rem red/blue only flag
redblueonly=0

rem size of cubes
size=100/numobjects

rem red/blue separation factor
sep#=0.055

rem z offset of world
zoffset=200

rem x,y,z point of a cube
dim x(numobjects)
dim y(numobjects)
dim z(numobjects)

rem x,y,z direction forward or back of each axis
dim xdir(numobjects)
dim ydir(numobjects)
dim zdir(numobjects)

rem speed of each axis
dim xspd(numobjects)
dim yspd(numobjects)
dim zspd(numobjects)

rem spin
dim spinspd(numobjects)
dim spin(numobjects)

for i=0 to numobjects-1

  rem start each object in a random direction
  xdir(i)=rnd(1)
  ydir(i)=rnd(1)
  zdir(i)=rnd(1)

  rem start each object at a random position
  x(i)=rnd(300)-150
  y(i)=rnd(300)-150
  z(i)=rnd(300)-150

  rem start each object at a random speed
  xspd(i)=rnd(5)+2
  yspd(i)=rnd(5)+2
  zspd(i)=rnd(5)+2

  rem start spin
  spinspd(i)=rnd(5)
  spin(i)=rnd(360)

next i


rem create the objects
for i=0 to numobjects-1

  rem make objects
  make object sphere i*2+1, size
  make object sphere i*2+2, size

  rem color objects
  color object i*2+1, rgb(255, 0, 0)
  color object i*2+2, rgb(0, 0, 255)

  rem make object transparent
  ghost object on i*2+1
  ghost object on i*2+2

next i

rem set background to black
color backdrop rgb(0,0,0)
sync

do

if escapekey() then break

rem move each object a little bit
for i=0 to numobjects-1

  rem calculate a new position for object
  if xdir(i)=1 then x(i)=x(i)+xspd(i) else x(i)=x(i)-xspd(i)
  if ydir(i)=1 then y(i)=y(i)+yspd(i) else y(i)=y(i)-yspd(i)
  if zdir(i)=1 then z(i)=z(i)+zspd(i) else z(i)=z(i)-zspd(i)

  rem bounds check (bounce if out of bounds)
  bounce=0
  if x(i)>100 then x(i)=100 : xdir(i)=0 : xspd(i)=rnd(5)+2 : bounce=1
  if x(i)<-100 then x(i)=-100 : xdir(i)=1 : xspd(i)=rnd(5)+2 : bounce=1
  if y(i)>75 then y(i)=75 : ydir(i)=0 : yspd(i)=rnd(5)+2 : bounce=1
  if y(i)<-50 then y(i)=-50 : ydir(i)=1 : yspd(i)=rnd(5)+2 : bounce=1
  if z(i)>250 then z(i)=250 : zdir(i)=0 : zspd(i)=rnd(5)+2 : bounce=1
  if z(i)<-125 then z(i)=-125 : zdir(i)=1 : zspd(i)=rnd(5)+2 : bounce=1

  rem if bounce change color
  if bounce

`color
    r=210+rnd(255-210)
    
    b=rnd(255-128)+128
    if (b+g)<200 then b=200-g

    rem color objects
    if redblueonly
      color object i*2+1, rgb(r, 0, 0)
      color object i*2+2, rgb(0,055, b)
    else
      color object i*2+1, rgb(r, 0, 0)
      color object i*2+2, rgb(0, g, b)
    endif

    rem if bounce change spin speed
    spinspd(i)=rnd(5)

  endif

  rem set object to new calculated position
  position object i*2+1, (0-z(i))*sep#+x(i),y(i),z(i)+zoffset
  position object i*2+2, x(i),y(i),z(i)+zoffset

  rem spin the object a little bit
  spin(i)=wrapvalue(spin(i)+spinspd(i))

  rem make object spin every direction
  rotate object i*2+1, spin(i), spin(i), spin(i)
  rotate object i*2+2, spin(i), spin(i), spin(i)

next i

rem update screen
sync

loop