Sorry your browser is not supported!

` this is a simple demonstration of ray casting

` set up the program
phy start
autocam off
sync on
sync rate 60
color backdrop 0
position camera 0, 20, -70

rem stripe textures
load image "stripe5.png",8
make object sphere 8,400,48,48
texture object 8,8
scale object texture 8,6,6
set object cull 8,0
load image "stripe6.png",1

` create some objects
make object cube 1, 5
position object 1, 0, 0, 0
phy make rigid body static box 1

make object cube 2, 5
position object 2, -15, 0, 0
phy make rigid body static box 2

make object cube 3, 5
position object 3, 15, 0, 0
phy make rigid body static box 3

make object cube 4, 5
position object 4, 0, 20, 0
make object box 5, 1, 15, 1
position object 5, 0, 15, 0
texture object 4,1
texture object 5,1

` show Dark Physics logo
load image "logo.png", 100000
sprite 1, 0, 600 - 60, 100000

` main program loop
do
   ` display information
   set cursor 0, 0
   print "This program demonstrates ray casting in action"
   print "The ray casting is taking place from the object at the top of the screen"
   print "When it hits an object that object turns blue"
   print "Use the arrow keys to move the position of the ray cast left and right"

   ` set all objects to black
   for i = 1 to 3
      color object i, 0
   next i

   ` get the position of object 4
   x# = object position x ( 4 )
   y# = object position y ( 4 )
   z# = object position z ( 4 )

   rem px#,py#,pz# a second point you want your ray to go trough. In this case the box to the right position.
   rem change this value if you want
   px# = 15
   py# = 0
   pz# = 0
   rem x#,y#,z# the coördinates of the object you can move with the arrowkeys. From here the ray starts.
   rem calculate the difference.
   rem You get a vector from one point to another.
   rx# = px# - x#
   ry# = py# - y#
   rz# = pz# - z#
   rem calculate the vector length
   l# = vectorlength( rx#,ry#,rz#)
   rem normalise the vector
   rx# = (px# - x#)/l#
   ry# = (py# - y#)/l#
   rz# = (pz# - z#)/l#

   ` cast a ray down
   rem value = phy ray cast all shapes ( x#, y#, z#, 0, -1, 0 )
   value = phy ray cast all shapes ( x#, y#, z#, rx#, ry#, rz# )

   ` if the ray hit something then colour that object blue
   if phy get ray cast hit( )= 1
        color object phy get ray cast object ( ), rgb ( 0, 0, 255 )
   endif

   `move the ray cast left
   if leftkey ( )
      move object left 4, 0.4
      move object left 5, 0.4
   endif

   ` mvoe the ray cast right
   if rightkey ( )
      move object right 4, 0.4
      move object right 5, 0.4
   endif

   ` update the simulation and screen
   phy update
   text 0,100,str$(rx#) + " " + str$(ry#) + " " +str$(rz#) + " "
   sync
loop


function vectorlength( rx#,ry#,rz#)
l# = sqrt(rx# ^ 2 + ry# ^ 2 + rz ^ 2)
endfunction l#

phy start

sync on
sync rate 60

obj_hero = 1
make object box obj_hero,3,3,3
color object obj_hero,rgb(255,0,0)
herox# = 0.0 : heroy# = 1.5 : heroz# = 0.0
position object obj_hero,herox#,heroy#,heroz#
yrotate object obj_hero,0

obj_floor = 2
make object plane obj_floor,50,50
xrotate object obj_floor,90

obj_box1 = 3
make object box obj_box1,10,10,10
position object obj_box1,10,0,10
phy make rigid body static mesh obj_box1

obj_box2 = 4
make object box obj_box2,15,10,15
position object obj_box2,-13,0,-13
phy make rigid body static mesh obj_box2


position camera 0,50,-30
point camera 0,0,0

do

   gosub HandleControls

   position object obj_hero,herox#,heroy#,heroz#

   sync
loop


HandleControls:
   text 0,0,"Left/Right cursor to turn, AWSD to move"
   joyx# = 0.0
   joyy# = 0.0

   key = scancode()

   if key = 30 `A
      joyx# = -0.5
   endif

   if key = 17 `W
      joyy# = -0.5
   endif

   if key = 31 `S
      joyy# = 0.5
   endif

   if key = 32 `D
      joyx# = 0.5
   endif

   if leftkey()=1
      angle# = object angle y(obj_hero) - 2
      yrotate object obj_hero,angle#
   endif

   if rightkey()=1
      angle# = object angle y(obj_hero) + 2
      yrotate object obj_hero,angle#
   endif

   angle# = wrapvalue(object angle y(obj_hero))
   text 0,32,"Hero angle y : "+str$(angle#)

   `make a vector and a matrix
   null = make vector3(1)
   null = make matrix4(2)

   `set the vector as the joystick input
   set vector3 1, joyx#, 0.0, joyy#*-1

   rotate y matrix4 2, angle# * 0.0174532925194

   `normalize the vector
   normalize vector3 1,1

   `now transform the vector
   transform coords vector3 1, 1, 2

   value = phy ray cast all shapes (herox#, heroy#, heroz#, x vector3(1),0,z vector3(1))

   text 400,400,"vectorx : "+str$(x vector3(1)) + "   vectorz : "+str$(z vector3(1))
   text 400,416,str$(value)
   text 400,432,str$(val#)

   if value<>0
      val# = phy get ray cast distance()
      if phy get ray cast hit() = 1

         if val#>-1.0 and val#<2.5
            text 400,384,"HIT !!!"
            color backdrop rgb(rnd(255),rnd(255),rnd(255))
            HeroColliding = 1
         else
            HeroColliding = 0
         endif
      endif
   endif

   if HeroColliding = 0 `only move when not colliding with objects
      inc herox#, x vector3(1)
      inc heroz#, z vector3(1)
   else
      HeroColliding = 0
   endif

return