Sorry your browser is not supported!

SYNC RATE 50 : SYNC ON : SET WINDOW LAYOUT 0, 0, 0
AUTOCAM OFF : BACKDROP OFF : DRAW TO BACK

#CONSTANT user32 = 1
#CONSTANT gdi32  = 2

LOAD DLL "user32.dll", user32
LOAD DLL "gdi32.dll", gdi32

CreateMaps()

MAKE OBJECT SPHERE 1, 32, 32, 32
TEXTURE OBJECT 1, 1
SET BUMP MAPPING ON 1, 2

REPEAT

   PASTE IMAGE 1, 0, 0

   TURN OBJECT LEFT 1, COS(A)
   POSITION OBJECT 1, 0, 0, 50 + SIN(A) * 10

   MX = MX - MOUSEMOVEX()
   MY = MY + MOUSEMOVEY()
   POINT LIGHT 0, MX, MY, 50

   SET CURSOR 0, 0
   PRINT "FPS: ", SCREEN FPS()

   INC A
   SYNC

UNTIL MOUSECLICK()

DELETE DLL user32
DELETE DLL gdi32
END

`--- Functions ------------------------------------------------------------------------------------

FUNCTION CreateMaps()

   HIDE WINDOW

   hDsk  = CALL DLL(user32, "GetDesktopWindow")
   hDC   = CALL DLL(user32, "GetWindowDC", hDsk)
   DskW  = CALL DLL(gdi32, "GetDeviceCaps", hDC, 8)
   DskH  = CALL DLL(gdi32, "GetDeviceCaps", hDC, 10)

   `--- BackMap ----------------------------------
   CREATE BITMAP 1, SCREEN WIDTH(), SCREEN HEIGHT()
   LOCK PIXELS

   FOR DskX = DskW / 2 - SCREEN WIDTH() / 2 TO DskW / 2 + SCREEN WIDTH() / 2 - 1
      FOR DskY = DskH / 2 - SCREEN HEIGHT() / 2 TO DskH / 2 + SCREEN HEIGHT() / 2 - 1
         C = CALL DLL(gdi32, "GetPixel", hDC, DskX, DskY)
         DOT BmpX, BmpY, RGB(RGBB(C), RGBG(C), RGBR(C))
         INC BmpY
      NEXT DskY
      BmpY = 0
      INC BmpX
   NEXT DskX

   UNLOCK PIXELS
   GET IMAGE 1, 0, 0, SCREEN WIDTH(), SCREEN HEIGHT(), 1
   DELETE BITMAP 1

   `--- NormalMap --------------------------------
   CREATE BITMAP 2, SCREEN WIDTH(), SCREEN HEIGHT()
   LOCK PIXELS

   BmpX = 0
   BmpY = 0

   FOR DskX = DskW / 2 - SCREEN WIDTH() / 2 TO DskW / 2 + SCREEN WIDTH() / 2 - 1
      FOR DskY = DskH / 2 - SCREEN HEIGHT() / 2 TO DskH / 2 + SCREEN HEIGHT() / 2 - 1
         NX = CALL DLL(gdi32, "GetPixel", hDC, DskX - 1, DskY)
         R = RGBB(NX)
         NX = CALL DLL(gdi32, "GetPixel", hDC, DskX + 1, DskY)
         R = (R - RGBB(NX) + 255) / 2
         NY = CALL DLL(gdi32, "GetPixel", hDC, DskX, DskY - 1)
         G = RGBB(NY)
         NY = CALL DLL(gdi32, "GetPixel", hDC, DskX, DskY + 1)
         G = (G - RGBB(NY) + 255) / 2
         DOT BmpX, BmpY, RGB(R, G, 255)
         INC BmpY
      NEXT DskY
      BmpY = 0
      INC BmpX
   NEXT DskX

   UNLOCK PIXELS
   GET IMAGE 2, 0, 0, SCREEN WIDTH(), SCREEN HEIGHT(), 1
   DELETE BITMAP 2

   CALL DLL user32, "ReleaseDC", hDsk, hDC
   RESTORE WINDOW

ENDFUNCTION

`name of texture, image number, texture flag (s. get image)
LoadNormalMap("pizza.jpg", 1, 1)
PASTE IMAGE 1, 0, 0
WAIT KEY
END

`--- Functions ------------------------------------------------------------------------------------

FUNCTION LoadNormalMap(File$, Img, Flag)

   FOR Bmp = 255 TO 1 STEP -1
      IF BITMAP EXIST(Bmp) = 0 THEN EXIT
   NEXT Bmp

   FOR MB = 255 TO 1 STEP -1
      IF MEMBLOCK EXIST(MB) = 0 THEN EXIT
   NEXT MB

   IF Bmp = 0 OR MB = 0 OR FILE EXIST(File$) = 0 OR IMAGE EXIST(Img) = 1 THEN EXITFUNCTION 0

   LOAD BITMAP File$, Bmp
   MAKE MEMBLOCK FROM BITMAP MB, Bmp

   LOCK PIXELS

   FOR X = 0 TO BITMAP WIDTH()
      FOR Y = 0 TO BITMAP HEIGHT()

         R = (GrayScale(MB, X - 1, Y) - GrayScale(MB, X + 1, Y) + 255) / 2
         G = (GrayScale(MB, X, Y - 1) - GrayScale(MB, X, Y + 1) + 255) / 2
         DOT X, Y, RGB(R, G, 255)

       NEXT Y
   NEXT X

   UNLOCK PIXELS

   GET IMAGE Img, 0, 0, BITMAP WIDTH(), BITMAP HEIGHT(), Flag
   DELETE MEMBLOCK MB
   DELETE BITMAP Bmp

ENDFUNCTION 1

FUNCTION GrayScale(MB, X, Y)

   if X < 0 then X = 0
   if Y < 0 then Y = 0
   if X > MEMBLOCK DWORD(MB, 0) - 1 THEN X = MEMBLOCK DWORD(MB, 0) - 1
   if Y > MEMBLOCK DWORD(MB, 4) - 1 THEN Y = MEMBLOCK DWORD(MB, 4) - 1
   C = MEMBLOCK DWORD(MB, 12 + (MEMBLOCK DWORD(MB, 0) * Y + X) * 4)
   C = RGBR(C) * 0.30 + RGBG(C) * 0.59 + RGBB(C) * 0.11

ENDFUNCTION C