Downloading with progress indicator - Is it possible in DB Pro?

Author

Message

Monzi

19

Years of Service

User Offline

Joined: 10th May 2004

Location: Denmark

Posted: 19th Apr 2006 18:06

Link

I've asked this before. But i'm trying my luck again, is there ANY way to download via DB Pro and have some sort of progress indication? I know how to download via urlmon and so forth, but are there any other ways to do it so that you can get some kind of progress indication?

Back to top

Profile PM Email

Olby

20

Years of Service

User Offline

Joined: 21st Aug 2003

Location:

Posted: 19th Apr 2006 22:43

Link

Yes, if im correct then Nicolas Kingsley coded a prog that will allow your program to update it self from any http adress with progress bar showing the process of downloading.

"Gangsters die, they don't go to heaven where angels fly!"
AMD Sempron 3.1+ Ghz, 512MB Ram, ATI R9550 256MB Ram, Sound Blaster Live!, WinXP SP2, DirectX 9.0c

Back to top

Profile PM Website

CattleRustler

Retired Moderator

20

Years of Service

User Offline

Joined: 8th Aug 2003

Location: case modding at overclock.net

Posted: 20th Apr 2006 01:08

Link

XUpdate!

Back to top

Profile PM

spooky

21

Years of Service

User Offline

Joined: 30th Aug 2002

Location: United Kingdom

Posted: 20th Apr 2006 02:03

Link

Also, take a look at this old post;

http://forum.thegamecreators.com/?m=forum_view&t=59361&b=6

There is some interesting code showing how to download files directly into a memblock buffer. It uses some very interesting windows dlls to download the file. Currently it is setup to download whole files at once, but looks like it's very easy to sequentially download a file in as many chunks as you want, giving you the option of showing a progress bar.

Boo!

Back to top

Profile PM Website

Monzi

19

Years of Service

User Offline

Joined: 10th May 2004

Location: Denmark

Posted: 21st Apr 2006 18:16

Link

Olby: tried it, it isnt suitable for my needs. Same goes for XUpdate cattlerustler.

Spooky: this seems VERY interesting. I'm looking into it right now :o)

Back to top

Profile PM Email

Monzi

19

Years of Service

User Offline

Joined: 10th May 2004

Location: Denmark

Posted: 21st Apr 2006 23:05 Edited at: 21st Apr 2006 23:06

Link

Ok, i've come some way with this project now. Now i only have ONE problem. I need to get the filesize of the file before the download starts.

I've found out that this can be done with this:
http://msdn.microsoft.com/library/default.asp?url=/library/en-us/wininet/wininet/httpqueryinfo.asp
in the wininet.dll

but i dont understand how to translate this to DB Pro language. Can anyone help me? Spooky?

Back to top

Profile PM Email

spooky

21

Years of Service

User Offline

Joined: 30th Aug 2002

Location: United Kingdom

Posted: 22nd Apr 2006 00:20

Link

I'm no expert I'm afraid. I can see that command is certainly the one to use, specially the bit about HTTP_QUERY_CONTENT_LENGTH.

If no-one else comes up with the answer, I'll try and cobble something together over the weekend.

Boo!

Back to top

Profile PM Website

Monzi

19

Years of Service

User Offline

Joined: 10th May 2004

Location: Denmark

Posted: 22nd Apr 2006 14:10 Edited at: 22nd Apr 2006 14:11

Link

Spooky this is what i have so far. This gets the downloading done with sucess in 1024 byte chuncks. But the only thing i cant figure out how to use is the
test=call dll(1,"HttpQueryInfoA",url,HTTP_QUERY_CONTENT_LENGTH,fsize,ffsize,0)

DLFile("http://dataphone.games.tucows.com/files/","FishTycoonSetup.exe")
Wait Key

Function DLFile(Url$,FileName$)

If File Exist(FileName$)=1 then Delete File FileName$

Downloaded=0
   load dll "wininet.dll", 1

call dll 1, "InternetAttemptConnect", 0
   con = call dll(1, "InternetCheckConnectionA",URL$, 1)

if con = 0
      print "Internet connection not found!"
      end
   endif

make memblock 1,1024
   buffer = get memblock ptr(1)
   size   = make memory(4)
   make memblock 2,4096
   fsize  = get memblock ptr(2)

inet = call dll(1, "InternetOpenA", "media", 0, "", "", 0)
   url = call dll(1, "InternetOpenUrlA", inet,URL$+FileName$, "", 0, 0, 0)
   test = call dll(1, "HttpQueryInfoA",url,HTTP_QUERY_CONTENT_LENGTH,fsize,ffsize,0)

open to write 1,FileName$
   Repeat
      call dll 1, "InternetReadFile", url, buffer,1024, size
      s=*size
      for i = 0 to s - 1
         write byte 1, memblock byte(1, i)
      next i
      CLS
      print "Downloading: "+FileName$
      If test=1 then print "File size  : "+str$(*ffsize)+" bytes"
      Inc Downloaded,1024
      print "Downloaded : "+Str$(Downloaded)+" bytes"
   Until s=0

call dll 1, "InternetCloseHandle", url
   close file 1
   call dll 1, "InternetCloseHandle", inet

delete memory size
   delete memblock 1
   delete dll 1
EndFunction

+ Code Snippet

DLFile("http://dataphone.games.tucows.com/files/","FishTycoonSetup.exe")
Wait Key

Function DLFile(Url$,FileName$)

   If File Exist(FileName$)=1 then Delete File FileName$

   Downloaded=0
   load dll "wininet.dll", 1

   call dll 1, "InternetAttemptConnect", 0
   con = call dll(1, "InternetCheckConnectionA",URL$, 1)

   if con = 0
      print "Internet connection not found!"
      end
   endif

   make memblock 1,1024
   buffer = get memblock ptr(1)
   size   = make memory(4)
   make memblock 2,4096
   fsize  = get memblock ptr(2)

   inet = call dll(1, "InternetOpenA", "media", 0, "", "", 0)
   url = call dll(1, "InternetOpenUrlA", inet,URL$+FileName$, "", 0, 0, 0)
   test = call dll(1, "HttpQueryInfoA",url,HTTP_QUERY_CONTENT_LENGTH,fsize,ffsize,0)

   open to write 1,FileName$
   Repeat
      call dll 1, "InternetReadFile", url, buffer,1024, size
      s=*size
      for i = 0 to s - 1
         write byte 1, memblock byte(1, i)
      next i
      CLS
      print "Downloading: "+FileName$
      If test=1 then print "File size  : "+str$(*ffsize)+" bytes"
      Inc Downloaded,1024
      print "Downloaded : "+Str$(Downloaded)+" bytes"
   Until s=0

   call dll 1, "InternetCloseHandle", url
   close file 1
   call dll 1, "InternetCloseHandle", inet

   delete memory size
   delete memblock 1
   delete dll 1
EndFunction

Back to top

Profile PM Email

spooky

21

Years of Service

User Offline

Joined: 30th Aug 2002

Location: United Kingdom

Posted: 23rd Apr 2006 00:05

Link

Today is your lucky day. This dll stuff is quite interesting when start playing.

Code to determine filesize of a file on the internet BEFORE you download it - ideal for progress bar where you need to know size beforehand:

+ Code Snippet

sync on : sync rate 0

#constant HTTP_QUERY_CONTENT_LENGTH = 5

url$="http://xxxxxx"

load dll "wininet.dll",1

inet = call dll(1, "InternetOpenA", "media", 0, "", "", 0)
url = call dll(1, "InternetOpenUrlA", inet, url$, "", 0, 0, 0)

make memblock 1,16
buffer as dword
buffer = get memblock ptr(1)
buffersize as dword
buffersize = make memory(4)
*buffersize=get memblock size(1)

test = call dll(1, "HttpQueryInfoA",url,HTTP_QUERY_CONTENT_LENGTH,buffer,buffersize,0)
` returns 0=error or 1=ok

bufferlength=*buffersize
fsize$=""
for f=1 to bufferlength
   fsize$=fsize$+chr$(memblock byte(1,f-1))
next f
fsize=val(fsize$)

print "Filesize = ";fsize

call dll 1, "InternetCloseHandle", url
call dll 1, "InternetCloseHandle", inet

delete memory buffersize
delete memblock 1
delete dll 1

sync : sync
wait key

Boo!

Back to top

Profile PM Website

Monzi

19

Years of Service

User Offline

Joined: 10th May 2004

Location: Denmark

Posted: 23rd Apr 2006 01:09

Link

Great!

Thanx spook

Back to top

Profile PM Email

spooky

21

Years of Service

User Offline

Joined: 30th Aug 2002

Location: United Kingdom

Posted: 23rd Apr 2006 01:25

Link

Also, as an extra check that file actually exists, you can use another info check variable to get the http status code, like 200 = file exists, or 404 = file doesnt exist.

Add a new constant;

+ Code Snippet

#constant HTTP_QUERY_STATUS_CODE = 19

and some code;

+ Code Snippet

*buffersize=get memblock size(1)
test = call dll(1, "HttpQueryInfoA",url,HTTP_QUERY_STATUS_CODE,buffer,buffersize,0)
bufferlength=*buffersize
status$=""
for f=1 to bufferlength
   status$=status$+chr$(memblock byte(1,f-1))
next f
print "HTTP STATUS CODE = ";status$

Most important that buffersize is reset before each call to that dll as it expects it to be size of memblock on input, and then resets to size of requested info on output

Boo!

Back to top

Profile PM Website

spooky

21

Years of Service

User Offline

Joined: 30th Aug 2002

Location: United Kingdom

Posted: 23rd Apr 2006 02:43 Edited at: 23rd Apr 2006 16:12

Link

I got bored and tidied the code up a bit. I have remove the MAKE MEMORY command in favour of memblocks because I prefer them. Also note the use of HTTP_QUERY_FLAG_NUMBER which means that buffer is filled as a DWORD instead of ascii characters. Makes things much easier to understand.

I'll probably write something similar to your chunks download and make a suite of functions that I'll post in code snippets during the week.

sync on : sync rate 0

url$="http://xxx"

filesize=remotesize(url$)

if filesize = -1
   print "Sorry, Problem retrieving filesize"
else
   print "File size = ";filesize
endif

sync : sync
wait key
end

function remotesize(u$)
   filesize as dword
   filesize=-1
   HTTP_QUERY_CONTENT_LENGTH = 5
   HTTP_QUERY_STATUS_CODE = 19
   HTTP_QUERY_FLAG_NUMBER = 0x20000000
   load dll "wininet.dll",1
   hInternet = call dll(1,"InternetOpenA","media",0,"","",0)
   if hInternet <> 0
      hRequest = call dll(1,"InternetOpenUrlA",hInternet,u$,"",0,0,0)
      if hRequest <> 0
         make memblock 1,4
         lpvBuffer as dword
         lpvBuffer = get memblock ptr(1)
         make memblock 2,4
         lpdwBufferLength as dword
         lpdwBufferLength = get memblock ptr(2)
         *lpdwBufferLength=get memblock size(1)
         bRet=call dll(1,"HttpQueryInfoA",hRequest,HTTP_QUERY_STATUS_CODE+HTTP_QUERY_FLAG_NUMBER,lpvBuffer,lpdwBufferLength,0)
         if bRet <> 0
            statuscode as dword
            statuscode=*lpvBuffer
            if statuscode = 200
               *lpdwBufferLength=get memblock size(1)
               bRet=call dll(1,"HttpQueryInfoA",hRequest,HTTP_QUERY_CONTENT_LENGTH+HTTP_QUERY_FLAG_NUMBER,lpvBuffer,lpdwBufferLength,0)
               if bRet <> 0
                  filesize=*lpvBuffer
               endif
            endif
         endif
         call dll 1,"InternetCloseHandle",hRequest
         delete memblock 1
         delete memblock 2
      endif
      call dll 1,"InternetCloseHandle",hInternet
   endif
   delete dll 1
endfunction filesize

+ Code Snippet

sync on : sync rate 0

url$="http://xxx"

filesize=remotesize(url$)

if filesize = -1
   print "Sorry, Problem retrieving filesize"
else
   print "File size = ";filesize
endif

sync : sync
wait key
end

function remotesize(u$)
   filesize as dword
   filesize=-1
   HTTP_QUERY_CONTENT_LENGTH = 5
   HTTP_QUERY_STATUS_CODE = 19
   HTTP_QUERY_FLAG_NUMBER = 0x20000000
   load dll "wininet.dll",1
   hInternet = call dll(1,"InternetOpenA","media",0,"","",0)
   if hInternet <> 0
      hRequest = call dll(1,"InternetOpenUrlA",hInternet,u$,"",0,0,0)
      if hRequest <> 0
         make memblock 1,4
         lpvBuffer as dword
         lpvBuffer = get memblock ptr(1)
         make memblock 2,4
         lpdwBufferLength as dword
         lpdwBufferLength = get memblock ptr(2)
         *lpdwBufferLength=get memblock size(1)
         bRet=call dll(1,"HttpQueryInfoA",hRequest,HTTP_QUERY_STATUS_CODE+HTTP_QUERY_FLAG_NUMBER,lpvBuffer,lpdwBufferLength,0)
         if bRet <> 0
            statuscode as dword
            statuscode=*lpvBuffer
            if statuscode = 200
               *lpdwBufferLength=get memblock size(1)
               bRet=call dll(1,"HttpQueryInfoA",hRequest,HTTP_QUERY_CONTENT_LENGTH+HTTP_QUERY_FLAG_NUMBER,lpvBuffer,lpdwBufferLength,0)
               if bRet <> 0
                  filesize=*lpvBuffer
               endif
            endif
         endif
         call dll 1,"InternetCloseHandle",hRequest
         delete memblock 1
         delete memblock 2
      endif
      call dll 1,"InternetCloseHandle",hInternet
   endif
   delete dll 1
endfunction filesize

Boo!

Back to top

Profile PM Website

Monzi

19

Years of Service

User Offline

Joined: 10th May 2004

Location: Denmark

Posted: 23rd Apr 2006 17:53

Link

Here is what i've put together:

DLFile("http://dataphone.games.tucows.com/files/","FishTycoonSetup.exe")

Function DLFile(Url$,FileName$)

If File Exist(FileName$)=1 then Delete File FileName$

load dll "wininet.dll", 1
   call dll 1, "InternetAttemptConnect", 0
   con = call dll(1, "InternetCheckConnectionA",URL$, 1)

If con = 0
      Print "Internet connection not found!"
      end
   EndIf

make memblock 1,1024
   buffer = get memblock ptr(1)
   size   = make memory(4)
   inet = call dll(1, "InternetOpenA", "media", 0, "", "", 0)
   URL = call dll(1, "InternetOpenUrlA", inet,URL$+FileName$, "", 0, 0, 0)

#constant HTTP_QUERY_CONTENT_LENGTH = 5
   make memblock 2,16
   buffer as dword
   buffer = get memblock ptr(2)
   buffersize as dword
   buffersize = make memory(4)
   *buffersize=get memblock size(2)
   test = call dll(1, "HttpQueryInfoA",url,HTTP_QUERY_CONTENT_LENGTH,buffer,buffersize,0)

bufferlength=*buffersize

fsize$=""
   for f=1 to bufferlength
      fsize$=fsize$+chr$(memblock byte(2,f-1))
   next f
   fsize=val(fsize$)
   Downloaded=0
   If Fsize>1000 then FSize$=Str$(fsize/1024)+" kb"
   open to write 1,FileName$
      Repeat
         Call DLL 1, "InternetReadFile", URL, buffer,1024, size
         s=*size
         For i = 0 to s - 1
            Write Byte 1, memblock byte(1, i)
         Next i
         CLS
         Print "Downloading: "+Url$+FileName$
         If test=1
            If Timer()>SpeedTimer+1000
               Speed=Downloaded-Downloaded2
               Speed$=Str$((Speed)/1024)+" kb/s"
               SpeedTimer=Timer()
               Downloaded2=Downloaded
            EndIf
            Print "File Size  : "+Fsize$
            Print "% Done     : "+Str$((downloaded*100)/fsize)+"%"
            Print "Speed      : "+Speed$
         EndIf
         Inc Downloaded,1024
         rem Print "Downloaded : "+Str$(Downloaded)+" bytes"
      Until s=0
   close file 1

call dll 1, "InternetCloseHandle", URL
   call dll 1, "InternetCloseHandle", inet

delete memory size
   delete memblock 1
   delete memblock 2
   delete dll 1
EndFunction

+ Code Snippet

DLFile("http://dataphone.games.tucows.com/files/","FishTycoonSetup.exe")

Function DLFile(Url$,FileName$)

   If File Exist(FileName$)=1 then Delete File FileName$

   load dll "wininet.dll", 1
   call dll 1, "InternetAttemptConnect", 0
   con = call dll(1, "InternetCheckConnectionA",URL$, 1)

   If con = 0
      Print "Internet connection not found!"
      end
   EndIf

   make memblock 1,1024
   buffer = get memblock ptr(1)
   size   = make memory(4)
   inet = call dll(1, "InternetOpenA", "media", 0, "", "", 0)
   URL = call dll(1, "InternetOpenUrlA", inet,URL$+FileName$, "", 0, 0, 0)

   #constant HTTP_QUERY_CONTENT_LENGTH = 5
   make memblock 2,16
   buffer as dword
   buffer = get memblock ptr(2)
   buffersize as dword
   buffersize = make memory(4)
   *buffersize=get memblock size(2)
   test = call dll(1, "HttpQueryInfoA",url,HTTP_QUERY_CONTENT_LENGTH,buffer,buffersize,0)

   bufferlength=*buffersize

   fsize$=""
   for f=1 to bufferlength
      fsize$=fsize$+chr$(memblock byte(2,f-1))
   next f
   fsize=val(fsize$)
   Downloaded=0
   If Fsize>1000 then FSize$=Str$(fsize/1024)+" kb"
   open to write 1,FileName$
      Repeat
         Call DLL 1, "InternetReadFile", URL, buffer,1024, size
         s=*size
         For i = 0 to s - 1
            Write Byte 1, memblock byte(1, i)
         Next i
         CLS
         Print "Downloading: "+Url$+FileName$
         If test=1
            If Timer()>SpeedTimer+1000
               Speed=Downloaded-Downloaded2
               Speed$=Str$((Speed)/1024)+" kb/s"
               SpeedTimer=Timer()
               Downloaded2=Downloaded
            EndIf
            Print "File Size  : "+Fsize$
            Print "% Done     : "+Str$((downloaded*100)/fsize)+"%"
            Print "Speed      : "+Speed$
         EndIf
         Inc Downloaded,1024
         rem Print "Downloaded : "+Str$(Downloaded)+" bytes"
      Until s=0
   close file 1

   call dll 1, "InternetCloseHandle", URL
   call dll 1, "InternetCloseHandle", inet

   delete memory size
   delete memblock 1
   delete memblock 2
   delete dll 1
EndFunction

It shows the progress in % and shows the speed of the download in kb/s.

Back to top

Profile PM Email

Sayan Master

18

Years of Service

User Offline

Joined: 24th Jun 2005

Location:

Posted: 23rd Apr 2006 22:27

Link

hello,

Monzi sorry to say that but your last code don't work, it would seem that the 'buffer' isn't filled properly.

Power is everything

Back to top

Profile PM

Sayan Master

18

Years of Service

User Offline

Joined: 24th Jun 2005

Location:

Posted: 24th Apr 2006 08:10

Link

sorry for the double post but i found the problem:

you defined buffer = get memblock ptr(1) and then buffer = get memblock ptr(2), so you overwrited the first value.

Power is everything

Back to top

Profile PM

Monzi

19

Years of Service

User Offline

Joined: 10th May 2004

Location: Denmark

Posted: 24th Apr 2006 10:38 Edited at: 24th Apr 2006 10:41

Link

Yes, thank you Sayan Master :o)

Here is the cleaned up and updated code:

DLFile("http://dataphone.games.tucows.com/files/","FishTycoonSetup.exe")

Function DLFile(Url$,FileName$)

If File Exist(FileName$)=1 then Delete File FileName$

Load DLL "wininet.dll", 1
   Call DLL 1,"InternetAttemptConnect",0
   Con=Call DLL (1,"InternetCheckConnectionA",URL$,1)

If Con=0
      Print "Internet connection not found!"
      End
   EndIf

INet = Call DLL (1,"InternetOpenA","media",0,"","",0)
   URL  = Call DLL (1,"InternetOpenUrlA",INet,URL$+FileName$,"",0,0,0)

#Constant HTTP_QUERY_CONTENT_LENGTH=5
   Make MemBlock 2,16
   BufferI as dword
   BufferSize as dword
   BufferI      = Get MemBlock Ptr(2)
   BufferSize  = Make Memory(4)
   *BufferSize = Get MemBlock Size(2)
   QueryInfo   = Call DLL (1,"HttpQueryInfoA",url,HTTP_QUERY_CONTENT_LENGTH,BufferI,BufferSize,0)

BufferLength=*BufferSize

FSize$=""
   For F=1 to BufferLength : FSize$=FSize$+CHR$(MemBlock Byte(2,F-1)) : next F
   FSize=Val(FSize$)
   If FSize>1000 then FSize$=Str$(FSize/1024)+" kb"

Make Memblock 1,1024
   Buffer = Get MemBlock Ptr(1)
   Size   = Make Memory(4)
   Downloaded=0

Open to Write 1,FileName$
      Repeat
         Call DLL 1,"InternetReadFile",URL,Buffer,1024,Size
         S=*Size
         For I=0 to S-1 : Write Byte 1,Memblock Byte(1,I) : Next I
         CLS
         Print "Downloading: "+Url$+FileName$
         If Timer()>SpeedTimer+1000
            Speed=Downloaded-Downloaded2
            Speed$=Str$((Speed)/1024)+" kb/s"
            SpeedTimer=Timer()
            Downloaded2=Downloaded
         EndIf
         Print "Speed      : "+Speed$
         If QueryInfo=1
            Progress$=Str$((downloaded*100)/fsize)+"%"
            Print "File Size  : "+Fsize$
            Print "Progress   : "+Progress$
         EndIf
         Inc Downloaded,1024
      Until S=0
   Close File 1

Call DLL 1,"InternetCloseHandle",URL
   Call DLL 1,"InternetCloseHandle",INet

Delete Memory Size
   Delete MemBlock 1
   Delete MemBlock 2
   Delete DLL 1

EndFunction

+ Code Snippet

DLFile("http://dataphone.games.tucows.com/files/","FishTycoonSetup.exe")

Function DLFile(Url$,FileName$)

   If File Exist(FileName$)=1 then Delete File FileName$

   Load DLL "wininet.dll", 1
   Call DLL 1,"InternetAttemptConnect",0
   Con=Call DLL (1,"InternetCheckConnectionA",URL$,1)

   If Con=0
      Print "Internet connection not found!"
      End
   EndIf

   INet = Call DLL (1,"InternetOpenA","media",0,"","",0)
   URL  = Call DLL (1,"InternetOpenUrlA",INet,URL$+FileName$,"",0,0,0)

   #Constant HTTP_QUERY_CONTENT_LENGTH=5
   Make MemBlock 2,16
   BufferI as dword
   BufferSize as dword
   BufferI      = Get MemBlock Ptr(2)
   BufferSize  = Make Memory(4)
   *BufferSize = Get MemBlock Size(2)
   QueryInfo   = Call DLL (1,"HttpQueryInfoA",url,HTTP_QUERY_CONTENT_LENGTH,BufferI,BufferSize,0)

   BufferLength=*BufferSize

   FSize$=""
   For F=1 to BufferLength : FSize$=FSize$+CHR$(MemBlock Byte(2,F-1)) : next F
   FSize=Val(FSize$)
   If FSize>1000 then FSize$=Str$(FSize/1024)+" kb"

   Make Memblock 1,1024
   Buffer = Get MemBlock Ptr(1)
   Size   = Make Memory(4)
   Downloaded=0

   Open to Write 1,FileName$
      Repeat
         Call DLL 1,"InternetReadFile",URL,Buffer,1024,Size
         S=*Size
         For I=0 to S-1 : Write Byte 1,Memblock Byte(1,I) : Next I
         CLS
         Print "Downloading: "+Url$+FileName$
         If Timer()>SpeedTimer+1000
            Speed=Downloaded-Downloaded2
            Speed$=Str$((Speed)/1024)+" kb/s"
            SpeedTimer=Timer()
            Downloaded2=Downloaded
         EndIf
         Print "Speed      : "+Speed$
         If QueryInfo=1
            Progress$=Str$((downloaded*100)/fsize)+"%"
            Print "File Size  : "+Fsize$
            Print "Progress   : "+Progress$
         EndIf
         Inc Downloaded,1024
      Until S=0
   Close File 1

   Call DLL 1,"InternetCloseHandle",URL
   Call DLL 1,"InternetCloseHandle",INet

   Delete Memory Size
   Delete MemBlock 1
   Delete MemBlock 2
   Delete DLL 1

EndFunction

Back to top

Profile PM Email

Sorry your browser is not supported!

DLL Talk / Downloading with progress indicator - Is it possible in DB Pro?