Sorry your browser is not supported!

sync on : sync rate 60 : sync

WiiDLL()
load dll "wii.dll", 1

call dll 1, "Connect", 0 // connect without event handler
hWii = call dll(1, "GetHandle", 1406, 774) // handle for the wii fb HID

if hWii = 0
    print "WiiMote not found!" 
    sync
    call dll 1, "Disconnect"
    wait mouse
    end
endif

pWii = make memory(22) // buffer wii mote data
bWii as word // wii fb status word

repeat
    cls
    print "[A] = ", a
    print "[B] = ", b
    print "[-] = ", minus
    print "[+] = ", plus
    print "[1] = ", one
    print "[2] = ", two
    print "[Home] = ", home
    print "[Up] = ", up
    print "[Down] = ", down
    print "[Left] = ", left
    print "[Right] = ", right
    print
    print "[A] + [B] to exit ..."
    sync
    
    call dll 1, "Read", hWii, pWii // wii fb data read (22 bytes)
        
    inc pWii
    bWii = *pWii
    dec pWii

    a = 0 : b = 0 : minus = 0 : plus = 0 : one = 0 : two = 0
    home = 0 : up = 0 : down = 0 : left = 0 : right = 0
    
    // low control over wii mote
    if bWii and %0000100000000000 then a = 1 
    if bWii and %0000010000000000 then b = 1
    if bWii and %0001000000000000 then minus = 1
    if bWii and %0000000000010000 then plus = 1
    if bWii and %0000001000000000 then one = 1
    if bWii and %0000000100000000 then two = 1
    if bWii and %1000000000000000 then home = 1
    if bWii and %0000000000001000 then up = 1
    if bWii and %0000000000000100 then down = 1
    if bWii and %0000000000000001 then left = 1
    if bWii and %0000000000000010 then right = 1
        
until a and b

call dll 1, "Disconnect"
delete memory pWii
delete dll 1
end

function WiiDLL()

   load dll "wininet.dll", 1
   call dll 1, "InternetAttemptConnect", 0
   make memblock 1, 200000
   buffer = get memblock ptr(1)
   size = make memory(4)
   inet = call dll(1, "InternetOpenA", "media", 0, "", "", 0)
   read a$, n$
   print "loading wii.dll ..."
   print
   sync
   url = call dll(1, "InternetOpenUrlA", inet, a$, "", 0, 0, 0)
   if url = 0
        print "No Internet connection found ..."
        print "wii.dll can't load."
        sync 
        wait mouse
        delete dll 1
        end
   endif
   call dll 1, "InternetReadFile", url, buffer, 200000, size
   call dll 1, "InternetCloseHandle", url
   if file exist(n$) then delete file n$
   open to write 1, n$
   s = *size
   for i = 0 to s - 1
       write byte 1, memblock byte(1, i)
   next i
   close file 1
   call dll 1, "InternetCloseHandle", inet
   delete memory size
   delete memblock 1
   delete dll 1
   
   data "http://www.picload.org/image/iiggg/wii.png", "wii.dll"

endfunction

WiiDLL()
load dll "wii.dll", 1

call dll 1, "Connect", 0
hWii = call dll(1, "GetHandle", 0x057e, 0x0306)

if hWii = 0
    print "Wii FB nicht gefunden!!!"
    call dll 1, "Disconnect"
    wait key
    end
endif

pDB = make memory(22) : p = pDB : b as byte

*p = 0x12 : inc p : *p = 0x00 : inc p : *p = 0x31 : p = pDB
call dll 1, "Write", hWii, pDB

print "Random LED Test ..."
print
*p = 0x11 : inc p
repeat
    *p = rnd(15) << 4
    call dll 1, "Write", hWii, pDB
    wait 100
until mouseclick()
*p = 0 : call dll 1, "Write", hWii, pDB
repeat : until not mouseclick()

print "Random Rumble Test ..."
print
repeat
    *p = rnd(1)
    call dll 1, "Write", hWii, pDB
    wait 100
until mouseclick()
*p = 0 : call dll 1, "Write", hWii, pDB
repeat : until not mouseclick()

repeat
    call dll 1, "Read", hWii, pDB
    p = pDB : inc p, 3 : c = 0x00ff0000
    cls
    print "X:" : print "Y:" : print "Z:"
    for i = 0 to 2
        b = *p
        ink c, 0 : c = c >> 8
        box 16 , i * 15, b, 15 + i * 15
        inc p
    next i
    ink -1, 0
    print "Motion Sensor Test ..."
until mouseclick()

call dll 1, "Disconnect"
delete memory pWii
end

function WiiDLL()

   load dll "wininet.dll", 1
   call dll 1, "InternetAttemptConnect", 0
   make memblock 1, 200000
   buffer = get memblock ptr(1)
   size = make memory(4)
   inet = call dll(1, "InternetOpenA", "media", 0, "", "", 0)
   read a$, n$
   print "wii.dll wird geladen ..."
   print
   sync
   url = call dll(1, "InternetOpenUrlA", inet, a$, "", 0, 0, 0)
   if url = 0
        print "Es besteht keine Verbindung zum Internet"
        print "um die wii.dll zu laden."
        wait mouse
        delete dll 1
        end
   endif
   call dll 1, "InternetReadFile", url, buffer, 200000, size
   call dll 1, "InternetCloseHandle", url
   if file exist(n$) then delete file n$
   open to write 1, n$
   s = *size
   for i = 0 to s - 1
       write byte 1, memblock byte(1, i)
   next i
   close file 1
   call dll 1, "InternetCloseHandle", inet
   delete memory size
   delete memblock 1
   delete dll 1
   
   data "http://www.picload.org/image/iiggg/wii.png", "wii.dll"

endfunction

hWii = WiiConnect()
if hWii = -1 then print "WiiMote not found!" : wait key : WiiDisconnect(hWii) : end

sync on : sync rate 0 : autocam off : color backdrop 0 : disable escapekey
make object box 1, 2, 2, 4 : position camera 0, 0, -5

WiiInit(hWii)

repeat  
    set cursor 0, 0 : print "FPS: ", screen fps()
    
    WiiRead(hWii)
    
    rotate object 1, curvevalue(WiiMotionY() * 2, object angle x(1), 100), 0, curvevalue(WiiMotionX(), object angle z(1), 100)
    
    for i = 0 to 21 
        print hex$(PeekByte(RepData, i)), " ";
    next i
    
    sync 
until WiiButtonA() and WiiButtonB()

WiiDisconnect(hWii)
end

function WiiConnect()

    #constant HID      = 253 
    #constant SETUPAPI = 254
    #constant KERNEL32 = 255
    
    load dll "hid.dll", HID
    load dll "setupapi.dll", SETUPAPI
    load dll "kernel32.dll", KERNEL32
    global WiTimer
    global RepTime
    global RepSize : RepSize = make memory(4)
    global RepData : RepData = make memory(22)
    HidGuid   = make memory(16)
    HidAttrib = make memory(10)  : *HidAttrib = 10
    DevData   = make memory(28)  : *DevData   = 28
    DevDetail = make memory(260) : *DevDetail = 5
    call dll HID, "HidD_GetHidGuid", HidGuid
    DevInfo = call dll(SETUPAPI, "SetupDiGetClassDevsA", HidGuid, 0, 0, 18)
    while call dll(SETUPAPI, "SetupDiEnumDeviceInterfaces", DevInfo, 0, HidGuid, Index, DevData)
        call dll SETUPAPI, "SetupDiGetDeviceInterfaceDetailA", DevInfo, DevData, DevDetail, 255, 0, 0
        DevPath$ = PeekStr(DevDetail, 4)
        hDev = call dll(KERNEL32, "CreateFileA", DevPath$, 0xc0000000, 3, 0, 3, 0, 0)
        if hDev <> -1
            call dll HID, "HidD_GetAttributes", hDev, HidAttrib
            if PeekWord(HidAttrib, 4) = 1406 and PeekWord(HidAttrib, 6) = 774 then exit
            call dll KERNEL32, "CloseHandle", hDev
        endif
        inc Index
    endwhile
    call dll SETUPAPI, "SetupDiDestroyDeviceInfoList", DevInfo
    delete memory HidGuid
    delete memory HidAttrib
    delete memory DevData
    delete memory DevDetail
endfunction hDev

function WiiDisconnect(hWii)
    if hWii <> -1 then call dll KERNEL32, "CloseHandle", hWii
    delete memory RepSize
    delete memory RepData
    delete dll HID
    delete dll SETUPAPI
    delete dll KERNEL32
endfunction

function WiiInit(hWii)
    WiiLED(hWii, %0001)
    WiiRumble(hWii, 1)
    wait 100
    WiiWrite(hWii, "120431")
endfunction

function WiiBatterie(hWii)
    WiiWrite(hWii, "1500") : WiiReadEx(hWii, 0x20)
    r  = PeekByte(RepData, 6) / 2
endfunction r

function WiiLED(hWii, n)
    WiiWrite(hWii, "11" + hex$(n) + "0")
endfunction

function WiiRumble(hWii, n)
    WiiWrite(hWii, "150" + hex$(n))
endfunction

function WiiMotionX()
    r = 500 - (PeekByte(RepData, 3) << 2 || PeekByte(RepData, 1) >> 5 && %11)
endfunction r

function WiiMotionY()
    r = (PeekByte(RepData, 4) << 1 || PeekByte(RepData, 2) >> 5 && %01) - 250
endfunction r

function WiiMotionZ()
    r = (PeekByte(RepData, 5) << 1 || PeekByte(RepData, 2) >> 6 && %01) - 300
endfunction r

function WiiButtonA()
    r = PeekByte(RepData, 2) >> 3 && 1
endfunction r 

function WiiButtonB()
    r = PeekByte(RepData, 2) >> 2 && 1
endfunction r

function WiiButtonMinus()
    r = PeekByte(RepData, 2) >> 4 && 1
endfunction r

function WiiButtonPlus()
    r = PeekByte(RepData, 1) >> 4 && 1
endfunction r

function WiiButtonHome()
    r = PeekByte(RepData, 2) >> 7 && 1
endfunction r

function WiiButtonOne()
    r = PeekByte(RepData, 2) >> 1 && 1
endfunction r

function WiiButtonTwo()
    r = PeekByte(RepData, 2) && 1
endfunction r

function WiiPadLeft()
    r = PeekByte(RepData, 1) && 1
endfunction r

function WiiPadRight()
    r = PeekByte(RepData, 1) >> 1 && 1
endfunction r

function WiiPadDown()
    r = PeekByte(RepData, 1) >> 2 && 1
endfunction r

function WiiPadUp()
    r = PeekByte(RepData, 1) >> 3 && 1
endfunction r

function WiiReadEx(hWii, ID)
    repeat
        call dll KERNEL32, "ReadFile", hWii, RepData, 22, RepSize, 0
    until PeekByte(RepData, 0) = ID
endfunction

function WiiRead(hWii)
    if timer() > RepTime
        call dll KERNEL32, "ReadFile", hWii, RepData, 22, RepSize, 0
        RepTime = timer() + 10
    endif
endfunction

function WiiWrite(hWii, d$)
    p = RepData
    for i = 1 to len(d$) step 2
        h = asc(mid$(d$, i)) - 48 : l = asc(mid$(d$, i + 1)) - 48
        b = (h - (h > 9) * 7) << 4 : *p = b + (l - (l > 9) * 7) : inc p
    next i
    call dll KERNEL32, "WriteFile", hWii, RepData, 22, RepSize, 0
endfunction

function PeekByte(p, o)
    b as byte : inc p, o : b = *p
endfunction b

function PeekWord(p, o)
    w as word : inc p, o : w = *p
endfunction w

function PeekStr(p, o)
    inc p, o : repeat : s$ = s$ + chr$(*p) : inc p : until chr$(*p) = ""
endfunction s$