Turning screen co-ordinates into 3D space?

Author

Message

Scraggle

Moderator

20

Years of Service

User Offline

Joined: 10th Jul 2003

Location: Yorkshire

Posted: 4th Jul 2016 10:41 Edited at: 4th Jul 2016 12:52

Link

I need a little help from a 3D maths wizard!

What I need is a function to place a 3D object in the world by specifying screen co-ordinates not 3D co-ordinates. So something like:
x# = Get3DXFromScreen( x, y, z )
y# = Get3DYFromScreen( x, y, z )
Where x and y are screen co-ordinates and z is the depth in 3D space.

No need for a Get3DZFromScreen( x, y, z ) because that is our personal choice.

The reason for this (as I'm sure you're wondering) is because I want to create 2D games using 3D objects. Think classic 8 bit games like 'Space Invaders'. It's simple enough using sprites but when you convert to 3D objects, knowing the position of objects relative to the screen is not as easy to calculate.
With trial and error I can work it out for a specific screen but I want this to work on multiple devices so trial and error is not an option.

It may be possible that this can be achieved using Get3DVectorXFromScreen(), Get3DVectorYFromScreen() and Get3DVectorZFromScreen() but since they return a directional vector I'm unsure of how to turn that into a point in 3D space at my desired depth.

Any 3D maths wizards out there?
Thanks!

[Edit] This might be easier than I thought. Using the directional vector from the above commands combined with a plane positioned at my required z depth it would be a simple ray/plain collision test. I will have a play with this after work tonight.... unless someone beats me to it

AGK V2 user - Tier 1 (mostly)

Back to top

Profile PM Email

Stab in the Dark software

Valued Member

21

Years of Service

User Offline

Joined: 12th Dec 2002

Playing: Badges, I don't need no stinkin badges

Posted: 4th Jul 2016 15:12 Edited at: 4th Jul 2016 15:14

Link

This is what I do for picking an object using ray casting with physics.
The code below is the raycasting demo I posted here.

https://forum.thegamecreators.com/thread/216683

Look at the PickJointCreateAndUpdate() function, I get the screen coordinates which are returned as a directional vector,
then turn it into a point in 3d space.

// Project: Raycasting 
// Created: 2016-05-25 by Stab In The Dark Software

// set window properties
SetWindowTitle( "Raycasting" )
SetWindowSize( GetDeviceWidth(), GetDeviceHeight(), 0 )
//Set display properties
SetVirtualResolution ( GetDeviceWidth(), GetDeviceHeight() )
SetVSync( 1 )
//Set Backdrop color
SetClearColor( 0,170,204 ) // light blue
//Set display orientation for mobile device
SetOrientationAllowed( 0, 0, 1, 0 )
SetScissor( 0, 0, 0, 0 ) 
//Set Lighting
//SetSunDirection( 0, -1, 1 )
CreatePointLight( 1, 0, 200, 0, 1000, 255, 255, 255 )
//SetAmbientColor( 60, 60, 60 )
//Set camera
SetCameraRange( 1, 1, 50000 )
SetCameraPosition( 1, 0, 100.0, -350.0 )
SetCameraLookAt( 1, 0.0, 100.0, 0.0, 0.0 )
//Set Text size and color as displayed to screen.
SetPrintSize( 22.0 )
SetPrintColor( 255, 255, 0 )
SetSkyBoxVisible( 1 )
//Set the error reporting for debugging.
//SetErrorMode( 2 )

DisplayLogo()

Create3DPhysicsWorld()

global FPS as integer
global floorBoxID as integer
global floorTexID as integer
global ballTex as integer
global crateTex as integer 
global concreteTex as integer

LoadDemoTextures()

//Make Physics floor
floorBoxID = CreateObjectBox( 1000.0, 12.0, 1000.0 )
SetObjectImage( floorBoxID, floorTexID, 0 )
//SetObjectColor( floorBoxID, 112, 100, 100, 255 )
SetObjectLightMode( floorBoxID, 1 )
SetObjectPosition( floorBoxID, 0.0, 6.0, 0.0 )
//This command creates a static physics body for the floor box with a triangle mesh collision shape.
//A static physics body has no mass and does not get moved.
Create3DPhysicsStaticBody( floorBoxID )
//This 3D Physics command changes the collision shape to a primative box shape since we do not need the accuracy of
// polygon collision for just a box. The physics body is still static.
SetObjectShapeBox( floorBoxID ) //

//Create a stack of dynamic boxes
CreateBoxStack( 17.0, 6, 20, -10.0, 0.0 )
CreateBoxStack( 17.0, 3, 20, -10.0, -100.0 )

PickJointSetup()

do
	//This function casts a ray, then creates a pick joint at that the contact point.
    PickJointCreateAndUpdate()

FPS = ScreenFPS()
    PrintC( "Fame Rate: " ) : Print( FPS )
    PrintC( "Total Physics Objects: " ) : Print( Get3DPhysicsTotalObjects()  )
    PrintC( "Active Physics Objects: " ) : Print( Get3DPhysicsActiveObjects()  )
    Print( "Click or tap on screen to cast ray and pick object" )
    Step3DPhysicsWorld() //required for updating physics.
    Sync()
loop

function DisplayLogo()
	bulletLogo = LoadImage("/media/agk2_logokit/bullet_logo_small.png")
	SetImageWrapU( bulletLogo,1 )
	SetImageWrapV( bulletLogo,1 )
	bulletSprite = CreateSprite( bulletLogo )
	SetSpritePosition( bulletSprite, GetScreenBoundsRight() -310.0, GetScreenBoundsTop() )
	agkLogo = LoadImage("/media/agk2_logokit/Made-With-AGK-128px.png")
	SetImageWrapU( agkLogo,1 )
	SetImageWrapV( agkLogo,1 )
	agkSprite = CreateSprite( agkLogo )
	SetSpritePosition( agkSprite, GetScreenBoundsRight() -128.0, GetScreenBoundsTop() )
endfunction

function LoadDemoTextures()
	floorTexID = LoadImage( "/media/steelPanelTiled.png" )
	SetImageWrapU( floorTexID, 0 )
	SetImageWrapV( floorTexID, 0 )
	ballTex = LoadImage( "/media/soccerball2.jpg" )
	SetImageWrapU( ballTex, 1 )
	SetImageWrapV( ballTex, 1 )
	crateTex = LoadImage( "/media/Crate_color.png" )
	SetImageWrapU( crateTex, 1 )
	SetImageWrapV( crateTex, 1 )
	concreteTex = LoadImage( "/media/Concrete.png" )
	SetImageWrapU( concreteTex, 1 )
	SetImageWrapV( concreteTex, 1 )
endfunction

Function CreateBoxStack( boxSize as float, rows as integer, columns as integer , yPosition as float, zPosition as float)
	objID as integer
	for h = 1 to rows
		for i = 1 to columns
			objID = CreateObjectBox( boxSize, boxSize, boxSize )
			SetObjectImage( objID, crateTex, 0 )
			SetObjectPosition( objID, ( boxSize * columns / 2.0 - boxSize / 2.0 ) * -1.0 + ( boxSize * i ), boxSize / 2.0 + ( boxSize * h ) + yPosition, zPosition )
			Create3DPhysicsDynamicBody( objID ) //This command by default gives the body a box collision shape so no need to change it.
			SetObject3DPhysicsMass( objID, 10.0 )
			SetObject3DPhysicsFriction( objID, 0.3 )
		next i
	next h
endfunction

function PickJointCreateAndUpdate()
	//Left mouse btn pressed creates pick joint
	if GetPointerPressed() 
		SetVector3( toVecID, Get3DVectorXFromScreen( GetPointerX(), GetPointerY() ),
														Get3DVectorYFromScreen( GetPointerX(), GetPointerY() ),
																Get3DVectorZFromScreen( GetPointerX(), GetPointerY() ) )
		GetVector3Multiply( toVecID, 1500.0 )
		SetVector3( origPosCamVecID, GetCameraX(1), GetCameraY(1), GetCameraZ(1) )

GetVector3Add( toVecID, origPosCamVecID )
		RayCast3DPhysics( pickObjectRayID, origPosCamVecID, toVecID, 1 )
		HitObjID = Get3DPhysicsRayCastObjectHit( pickObjectRayID, 0 )
		if HitObjID > 0 
			Get3DPhysicsRayCastContactPosition( pickObjectRayID, 0.0, PickVecID )
			pickJointID = Create3DPhysicsPickJoint( HitObjID, PickVecID )
		endif
	endif
	
	//Left Mouse btn held down holds pick joint
	if GetPointerState() and pickJointID > 0 
		SetVector3( updatedPickVecID, Get3DVectorXFromScreen( GetPointerX(), GetPointerY() ),
															Get3DVectorYFromScreen( GetPointerX(), GetPointerY() ),
																	Get3DVectorZFromScreen( GetPointerX(), GetPointerY() ) )											
		origDistance = GetVector3Distance( origPosCamVecID, PickVecID )
		GetVector3Multiply( updatedPickVecID, origDistance )
		SetVector3( currPosCamVecID, GetCameraX(1), GetCameraY(1), GetCameraZ(1) )
		GetVector3Add( updatedPickVecID, currPosCamVecID )
		Update3DPhysicsPickJoint( pickJointID, updatedPickVecID )
	elseif pickJointID > 0 
		Delete3DPhysicsPickJoint( pickJointID )
		if HitObjID > 0 
			SetVector3( updatedPickVecID, Get3DVectorXFromScreen( GetPointerX(), GetPointerY() ),
																Get3DVectorYFromScreen( GetPointerX(), GetPointerY() ),
																	Get3DVectorZFromScreen( GetPointerX(), GetPointerY() ) )
			SetObject3DPhysicsLinearVelocity( HitObjID, updatedPickVecID, 5000.0)
			pickJointID = 0
		endif
	endif
endfunction

function PickJointSetup()
	
	global pickObjectRayID as integer
	global currPosCamVecID as integer
	global origPosCamVecID as integer 
	global toVecID as integer 
	global updatedPickVecID as integer 
	global PickVecID as integer 
	global HitObjID as integer
	global pickJointID as integer
	
	pickObjectRayID = Create3DPhysicsRay()
	currPosCamVecID = CreateVector3()
	origPosCamVecID  = CreateVector3()
	toVecID = CreateVector3()
	PickVecID = CreateVector3()
	updatedPickVecID = CreateVector3()
	
endfunction

+ Code Snippet


// Project: Raycasting 
// Created: 2016-05-25 by Stab In The Dark Software

// set window properties
SetWindowTitle( "Raycasting" )
SetWindowSize( GetDeviceWidth(), GetDeviceHeight(), 0 )
//Set display properties
SetVirtualResolution ( GetDeviceWidth(), GetDeviceHeight() )
SetVSync( 1 )
//Set Backdrop color
SetClearColor( 0,170,204 ) // light blue
//Set display orientation for mobile device
SetOrientationAllowed( 0, 0, 1, 0 )
SetScissor( 0, 0, 0, 0 ) 
//Set Lighting
//SetSunDirection( 0, -1, 1 )
CreatePointLight( 1, 0, 200, 0, 1000, 255, 255, 255 )
//SetAmbientColor( 60, 60, 60 )
//Set camera
SetCameraRange( 1, 1, 50000 )
SetCameraPosition( 1, 0, 100.0, -350.0 )
SetCameraLookAt( 1, 0.0, 100.0, 0.0, 0.0 )
//Set Text size and color as displayed to screen.
SetPrintSize( 22.0 )
SetPrintColor( 255, 255, 0 )
SetSkyBoxVisible( 1 )
//Set the error reporting for debugging.
//SetErrorMode( 2 )

DisplayLogo()

Create3DPhysicsWorld()

global FPS as integer
global floorBoxID as integer
global floorTexID as integer
global ballTex as integer
global crateTex as integer 
global concreteTex as integer


LoadDemoTextures()


//Make Physics floor
floorBoxID = CreateObjectBox( 1000.0, 12.0, 1000.0 )
SetObjectImage( floorBoxID, floorTexID, 0 )
//SetObjectColor( floorBoxID, 112, 100, 100, 255 )
SetObjectLightMode( floorBoxID, 1 )
SetObjectPosition( floorBoxID, 0.0, 6.0, 0.0 )
//This command creates a static physics body for the floor box with a triangle mesh collision shape.
//A static physics body has no mass and does not get moved.
Create3DPhysicsStaticBody( floorBoxID )
//This 3D Physics command changes the collision shape to a primative box shape since we do not need the accuracy of
// polygon collision for just a box. The physics body is still static.
SetObjectShapeBox( floorBoxID ) //

//Create a stack of dynamic boxes
CreateBoxStack( 17.0, 6, 20, -10.0, 0.0 )
CreateBoxStack( 17.0, 3, 20, -10.0, -100.0 )


PickJointSetup()


do
	//This function casts a ray, then creates a pick joint at that the contact point.
    PickJointCreateAndUpdate()

	FPS = ScreenFPS()
    PrintC( "Fame Rate: " ) : Print( FPS )
    PrintC( "Total Physics Objects: " ) : Print( Get3DPhysicsTotalObjects()  )
    PrintC( "Active Physics Objects: " ) : Print( Get3DPhysicsActiveObjects()  )
    Print( "Click or tap on screen to cast ray and pick object" )
    Step3DPhysicsWorld() //required for updating physics.
    Sync()
loop

function DisplayLogo()
	bulletLogo = LoadImage("/media/agk2_logokit/bullet_logo_small.png")
	SetImageWrapU( bulletLogo,1 )
	SetImageWrapV( bulletLogo,1 )
	bulletSprite = CreateSprite( bulletLogo )
	SetSpritePosition( bulletSprite, GetScreenBoundsRight() -310.0, GetScreenBoundsTop() )
	agkLogo = LoadImage("/media/agk2_logokit/Made-With-AGK-128px.png")
	SetImageWrapU( agkLogo,1 )
	SetImageWrapV( agkLogo,1 )
	agkSprite = CreateSprite( agkLogo )
	SetSpritePosition( agkSprite, GetScreenBoundsRight() -128.0, GetScreenBoundsTop() )
endfunction

function LoadDemoTextures()
	floorTexID = LoadImage( "/media/steelPanelTiled.png" )
	SetImageWrapU( floorTexID, 0 )
	SetImageWrapV( floorTexID, 0 )
	ballTex = LoadImage( "/media/soccerball2.jpg" )
	SetImageWrapU( ballTex, 1 )
	SetImageWrapV( ballTex, 1 )
	crateTex = LoadImage( "/media/Crate_color.png" )
	SetImageWrapU( crateTex, 1 )
	SetImageWrapV( crateTex, 1 )
	concreteTex = LoadImage( "/media/Concrete.png" )
	SetImageWrapU( concreteTex, 1 )
	SetImageWrapV( concreteTex, 1 )
endfunction

Function CreateBoxStack( boxSize as float, rows as integer, columns as integer , yPosition as float, zPosition as float)
	objID as integer
	for h = 1 to rows
		for i = 1 to columns
			objID = CreateObjectBox( boxSize, boxSize, boxSize )
			SetObjectImage( objID, crateTex, 0 )
			SetObjectPosition( objID, ( boxSize * columns / 2.0 - boxSize / 2.0 ) * -1.0 + ( boxSize * i ), boxSize / 2.0 + ( boxSize * h ) + yPosition, zPosition )
			Create3DPhysicsDynamicBody( objID ) //This command by default gives the body a box collision shape so no need to change it.
			SetObject3DPhysicsMass( objID, 10.0 )
			SetObject3DPhysicsFriction( objID, 0.3 )
		next i
	next h
endfunction

function PickJointCreateAndUpdate()
	//Left mouse btn pressed creates pick joint
	if GetPointerPressed() 
		SetVector3( toVecID, Get3DVectorXFromScreen( GetPointerX(), GetPointerY() ),
														Get3DVectorYFromScreen( GetPointerX(), GetPointerY() ),
																Get3DVectorZFromScreen( GetPointerX(), GetPointerY() ) )
		GetVector3Multiply( toVecID, 1500.0 )
		SetVector3( origPosCamVecID, GetCameraX(1), GetCameraY(1), GetCameraZ(1) )

		GetVector3Add( toVecID, origPosCamVecID )
		RayCast3DPhysics( pickObjectRayID, origPosCamVecID, toVecID, 1 )
		HitObjID = Get3DPhysicsRayCastObjectHit( pickObjectRayID, 0 )
		if HitObjID > 0 
			Get3DPhysicsRayCastContactPosition( pickObjectRayID, 0.0, PickVecID )
			pickJointID = Create3DPhysicsPickJoint( HitObjID, PickVecID )
		endif
	endif
	
	//Left Mouse btn held down holds pick joint
	if GetPointerState() and pickJointID > 0 
		SetVector3( updatedPickVecID, Get3DVectorXFromScreen( GetPointerX(), GetPointerY() ),
															Get3DVectorYFromScreen( GetPointerX(), GetPointerY() ),
																	Get3DVectorZFromScreen( GetPointerX(), GetPointerY() ) )											
		origDistance = GetVector3Distance( origPosCamVecID, PickVecID )
		GetVector3Multiply( updatedPickVecID, origDistance )
		SetVector3( currPosCamVecID, GetCameraX(1), GetCameraY(1), GetCameraZ(1) )
		GetVector3Add( updatedPickVecID, currPosCamVecID )
		Update3DPhysicsPickJoint( pickJointID, updatedPickVecID )
	elseif pickJointID > 0 
		Delete3DPhysicsPickJoint( pickJointID )
		if HitObjID > 0 
			SetVector3( updatedPickVecID, Get3DVectorXFromScreen( GetPointerX(), GetPointerY() ),
																Get3DVectorYFromScreen( GetPointerX(), GetPointerY() ),
																	Get3DVectorZFromScreen( GetPointerX(), GetPointerY() ) )
			SetObject3DPhysicsLinearVelocity( HitObjID, updatedPickVecID, 5000.0)
			pickJointID = 0
		endif
	endif
endfunction 

function PickJointSetup()
	
	global pickObjectRayID as integer
	global currPosCamVecID as integer
	global origPosCamVecID as integer 
	global toVecID as integer 
	global updatedPickVecID as integer 
	global PickVecID as integer 
	global HitObjID as integer
	global pickJointID as integer
	
	pickObjectRayID = Create3DPhysicsRay()
	currPosCamVecID = CreateVector3()
	origPosCamVecID  = CreateVector3()
	toVecID = CreateVector3()
	PickVecID = CreateVector3()
	updatedPickVecID = CreateVector3()
	
endfunction

The coffee is lovely dark and deep,and I have code to write before I sleep.

Back to top

Profile PM Email Website

Scraggle

Moderator

20

Years of Service

User Offline

Joined: 10th Jul 2003

Location: Yorkshire

Posted: 5th Jul 2016 09:45

Link

Thanks for the code Stab but I'm not sure it's what I'm looking for.
Maybe I'm missing something but your code seems to cast a ray from the screen and check for collision with an object from it.
What I'm trying to do is cast a ray from the screen and establish the 3D point that the ray intersect a particular zdepth or distance from the camera (but since my camera is fixed they are both essentially the same thing) so that I can place an object there.

My edited suggestion about it being easier than I thought is wrong. I still need to calculate the size of the view frustum at the desired depth in order to create a plain for collision tests, then I need to know the position within the plain that the ray intersected.

I'm reading "Real-Time Collision Detection" by Christer Ericson (great book!) which I'm sure has all the info I need but it's heavy reading!

AGK V2 user - Tier 1 (mostly)

Back to top

Profile PM Email

Scraggle

Moderator

20

Years of Service

User Offline

Joined: 10th Jul 2003

Location: Yorkshire

Posted: 5th Jul 2016 21:00 Edited at: 5th Jul 2016 21:17

Link

I've solved it - sort of!
Since I wanted a one off job for a fixed camera position I decided to use brute force.
I created a one unit sphere, positioned at in the centre of the view port then moved it left/right/up/down until it left the screen and stored each dimension.
Id still prefer a mathematical solution that would be suitable for any situation if anyone would care to take up the challenge but this will do for now.

If anyone is interested in my brute force method, its below.
It presumes a camera at 0, 0, -175 looking back at 0, 0, 0 but it works for any screen size and dimension

+ Code Snippet

function GetBruteForce3DscreenSize(z#)
	s = CreateObjectSphere(1, 1, 1)
	x# = 0
	y# = 0
	repeat
		dec x#, 1
		SetObjectPosition(s, x#, y#, z#)
	until GetObjectInScreen(s) = FALSE
	screen3D.x = x#

	x# = 0
	y# = 0
	repeat
		inc x#, 1
		SetObjectPosition(s, x#, y#, z#)
	until GetObjectInScreen(s) = FALSE
	screen3D.w =  x#

	x# = 0
	y# = 0
	repeat
		dec y#, 1
		SetObjectPosition(s, x#, y#, z#)
	until GetObjectInScreen(s) = FALSE
	screen3D.y = y#

	x# = 0
	y# = 0
	repeat
		inc y#, 1
		SetObjectPosition(s, x#, y#, z#)
	until GetObjectInScreen(s) = FALSE
	screen3D.h = y#
	DeleteObject(s)
endfunction

Obviously that's not exactly what I asked for in the initial post but knowing the size of the view frustrum at the desired depth and knowing the size of the display is enough to calculate the required coordinates

AGK V2 user - Tier 1 (mostly)

Back to top

Profile PM Email

Markus

Valued Member

20

Years of Service

User Offline

Joined: 10th Apr 2004

Location: Germany

Posted: 5th Jul 2016 21:51 Edited at: 5th Jul 2016 21:55

Link

there is also
GetScreenXFrom3D ( x, y, z )
GetScreenYFrom3D ( x, y, z )

GetVirtualHeight ()
GetVirtualWidth ()
GetScreenBoundsBottom ()
GetScreenBoundsLeft ()
GetScreenBoundsRight ()
GetScreenBoundsTop ()

AGK (Steam) V2.0.19 : Windows 10 Pro 64 Bit : AMD (16.3.2) Radeon R7 265 : Mac mini OS X 10.10 (Yosemite)

Back to top

Profile PM Email

Scraggle

Moderator

20

Years of Service

User Offline

Joined: 10th Jul 2003

Location: Yorkshire

Posted: 6th Jul 2016 08:08 Edited at: 6th Jul 2016 08:09

Link

Thanks Markus but all those commands do the opposite of what I am trying to achieve.
Ideally I would like the commands:
Get3DXFromScreen(x, y, z)
Get3DYFromScreen(x, y, z)
Where x & y are screen co-ordinates and z is the distance from the camera.

AGK V2 user - Tier 1 (mostly)

Back to top

Profile PM Email

Mobiius

Valued Member

21

Years of Service

User Offline

Joined: 27th Feb 2003

Location: The Cold North

Posted: 6th Jul 2016 09:18

Link

I know that 2dX = 3dX / 3dZ, and 2dY = 3dY / 3dZ. So maybe 3dX = 2dX * 3dZ & 3dY = 2dY * 3dZ. (Which only works with the camera at 0, 0, 0 and 0, 0, 0 rotation.

Now Visit My Website

Back to top

Profile PM Email Website

Paul Johnston

TGC Developer

21

Years of Service

User Offline

Joined: 16th Nov 2002

Location: United Kingdom

Posted: 6th Jul 2016 14:25

Link

Would this work?

+ Code Snippet

WorldX# = Get3DVectorXFromScreen( GetPointerX(), GetPointerY() ) * Depth# + GetCameraX(1)
WorldY# = Get3DVectorYFromScreen( GetPointerX(), GetPointerY() ) * Depth# + GetCameraY(1)
WorldZ# = Get3DVectorZFromScreen( GetPointerX(), GetPointerY() ) * Depth# + GetCameraZ(1)

although that would produce a series of points that form a sphere around the camera. If you need the points to lie on a plane then the following should work

+ Code Snippet

VectorX# = Get3DVectorXFromScreen( GetPointerX(), GetPointerY() )
VectorY# = Get3DVectorYFromScreen( GetPointerX(), GetPointerY() )
VectorZ# = Get3DVectorZFromScreen( GetPointerX(), GetPointerY() )

// get a vector that points in the direction the camera is looking
VectorX2# = Get3DVectorXFromScreen( GetVirtualWidth()/2.0, GetVirtualHeight()/2.0 )
VectorY2# = Get3DVectorYFromScreen( GetVirtualWidth()/2.0, GetVirtualHeight()/2.0 )
VectorZ2# = Get3DVectorZFromScreen( GetVirtualWidth()/2.0, GetVirtualHeight()/2.0 )

// normalise Vector in the direction of Vector2
Dot# = VectorX#*VectorX2# + VectorY#*VectorY2# + VectorZ#*VectorZ2#
if ( Dot# > 0 )
	VectorX# = VectorX# / Dot#
	VectorY# = VectorY# / Dot#
	VectorZ# = VectorZ# / Dot#
endif

WorldX# = VectorX# * Depth# + GetCameraX(1)
WorldY# = VectorY# * Depth# + GetCameraY(1)
WorldZ# = VectorZ# * Depth# + GetCameraZ(1)

Back to top

Profile PM Email

Markus

Valued Member

20

Years of Service

User Offline

Joined: 10th Apr 2004

Location: Germany

Posted: 6th Jul 2016 18:25

Link

Quote: "those commands do the opposite"

it belongs your code snippet / GetBruteForce3DscreenSize
instead of moving a 3d object you can also use GetScreenXFrom3D there and look if the x,y result is inside your "screen", so your get a border.

Quote: "
Ideally I would like the commands:
Get3DXFromScreen(x, y, z)
Get3DYFromScreen(x, y, z)
Where x & y are screen co-ordinates and z is the distance from the camera.
"

yes, z should be the plane you will see in the screen.
z its more the front of the 3d object you will fit into the screen if you think in tiles.

may you can use orthographic view for 3d, see SetCameraOrthoWidth
there you will have no room warp.

AGK (Steam) V2.0.19 : Windows 10 Pro 64 Bit : AMD (16.3.2) Radeon R7 265 : Mac mini OS X 10.10 (Yosemite)

Back to top

Profile PM Email

Scraggle

Moderator

20

Years of Service

User Offline

Joined: 10th Jul 2003

Location: Yorkshire

Posted: 7th Jul 2016 08:31

Link

Thanks Paul,
That 2nd example is perfect! Exactly what I was looking for, you're are a star!

I turned it into a function so that it can be called easier, in case anyone else wants it:

+ Code Snippet

function Get3DPointFromScreen( x, y, z as float)
	VectorX# = Get3DVectorXFromScreen( x, y )
	VectorY# = Get3DVectorYFromScreen( x, y )
	VectorZ# = Get3DVectorZFromScreen( x, y )
	 
	// get a vector that points in the direction the camera is looking
	VectorX2# = Get3DVectorXFromScreen( GetVirtualWidth()/2.0, GetVirtualHeight()/2.0 )
	VectorY2# = Get3DVectorYFromScreen( GetVirtualWidth()/2.0, GetVirtualHeight()/2.0 )
	VectorZ2# = Get3DVectorZFromScreen( GetVirtualWidth()/2.0, GetVirtualHeight()/2.0 )
	 
	// normalise Vector in the direction of Vector2
	Dot# = VectorX#*VectorX2# + VectorY#*VectorY2# + VectorZ#*VectorZ2#
	if ( Dot# > 0 )
		VectorX# = VectorX# / Dot#
		VectorY# = VectorY# / Dot#
		VectorZ# = VectorZ# / Dot#
	endif
	
	point3D as tPoint3D 
	point3D.x = VectorX# * z + GetCameraX(1)
	point3D.y = VectorY# * z + GetCameraY(1)
	point3D.z = VectorZ# * z + GetCameraZ(1)
endfunction point3D

AGK V2 user - Tier 1 (mostly)

Back to top

Profile PM Email

Ortu

DBPro Master

16

Years of Service

User Offline

Joined: 21st Nov 2007

Location: Austin, TX

Posted: 8th Jul 2016 02:53

Link

Quote: "

although that would produce a series of points that form a sphere around the camera. If you need the points to lie on a plane then the following should work"

Nice! I've been using the equivalent of the top method, but have been wanting it to work like the bottom this is handy

Back to top

Profile PM Email Website

Sorry your browser is not supported!

AppGameKit Classic Chat / Turning screen co-ordinates into 3D space?