smaller memblock image to bigger memblock image

Author

Message

pictionaryjr

15

Years of Service

User Offline

Joined: 12th Mar 2009

Location:

Posted: 29th Jun 2009 06:51 Edited at: 29th Jun 2009 06:54

Link

Alright, I have an image in a memblock that is 320x320 and I made a new memblock that is 2560x1920.

How would I be able to copy the smaller image to the larger image multiple times, without distorting how the the smaller looks when it is copied to the big one.

The problem I'm having is that in a memblock, you don't find positions by an X and Y coordinate, you find them by the position in a memblock which is just 1 number. So, the width of my small picture would be 320 and the width of my big picture would be 2560. If I try to do a simple For next loop, once the number passes 652(I have to include the 12 memblock positions storing width, height, and depth and that a word is 2 bytes each). It will be on the second row of the smaller image and the first row of the bigger image. I need a way so that when I'm copying the smaller to the bigger, the position I'm getting off the smaller stays on the same row and just keeps resetting itself to the beginning of that row until I go to the second row of the larger image. Then, get it to allow me to also go to the second row of the smaller image. And just keep repeating the process until I've got to the last memblock position on the bigger image.

If you don't understanding what I'm trying to explain then I'll try and whip up some code to show you.

Back to top

Profile PM Email

Ashingda 27

16

Years of Service

User Offline

Joined: 15th Feb 2008

Location:

Posted: 29th Jun 2009 08:55

Link

I hope this helps, if you have more specific questions feel free to ask.

`Ashingda - This example will use 32x32 and 256x192.

set display mode 640,480,32
sync on
sync rate 80

IMG32x32 = 1
IMG256x192 = 2

MEM32x32 = 1
MEM256x192 = 2

`Ashingda - Creating the 32x32 image memblock, (Cyan box with red X)
ink rgb(0,255,255),0
box 0,0,32,32
ink rgb(255,0,0),0
line 0,0,32,32
line 0,32,32,0
get image IMG32x32,0,0,32,32,1
sync
make memblock from image MEM32x32,IMG32x32
WD_Small = 32
HT_Small = 32

`Ashingda - Setting up the 256x192 memblock
make memblock MEM256x192,12+(256+192*256)*4
write memblock dword MEM256x192,0,256
write memblock dword MEM256x192,4,192
write memblock dword MEM256x192,8,32
WD_Large = 256
HT_Large = 192

`Ashingda - Memblock data transfer
for Y_Large = 0 to HT_Large - 1 step HT_Small
for X_Large = 0 to WD_Large - 1 step WD_Small

for Y_Small = 0 to HT_Small - 1
	for X_Small = 0 to WD_Small - 1

`Ashingda - Reading from the small 32x32
		Pos_Small = 12 + (X_Small + Y_Small * WD_Small) * 4
		Color = memblock dword(MEM32x32,Pos_Small)

`Ashingda - Writing to the large 256x192
		Pos_Large = 12 + ( (X_Large+X_Small) + (Y_Large+Y_Small) * WD_Large)*4
		write memblock dword MEM256x192,Pos_Large,Color

next X_Small
	next Y_Small

next X_Large
next Y_Large

`Ashingda - Creating the 256x192 image.
make image from memblock IMG256x192,MEM256x192

`Ashingda - Displaying the image.
do
	paste image IMG256x192,100,100
	sync
	cls
loop

+ Code Snippet

`Ashingda - This example will use 32x32 and 256x192. 

set display mode 640,480,32
sync on
sync rate 80

IMG32x32 = 1
IMG256x192 = 2

MEM32x32 = 1
MEM256x192 = 2

`Ashingda - Creating the 32x32 image memblock, (Cyan box with red X)
ink rgb(0,255,255),0
box 0,0,32,32
ink rgb(255,0,0),0
line 0,0,32,32
line 0,32,32,0
get image IMG32x32,0,0,32,32,1
sync
make memblock from image MEM32x32,IMG32x32
WD_Small = 32
HT_Small = 32

`Ashingda - Setting up the 256x192 memblock
make memblock MEM256x192,12+(256+192*256)*4
write memblock dword MEM256x192,0,256
write memblock dword MEM256x192,4,192
write memblock dword MEM256x192,8,32
WD_Large = 256
HT_Large = 192

`Ashingda - Memblock data transfer
for Y_Large = 0 to HT_Large - 1 step HT_Small
for X_Large = 0 to WD_Large - 1 step WD_Small

	for Y_Small = 0 to HT_Small - 1
	for X_Small = 0 to WD_Small - 1

		`Ashingda - Reading from the small 32x32
		Pos_Small = 12 + (X_Small + Y_Small * WD_Small) * 4
		Color = memblock dword(MEM32x32,Pos_Small)

		`Ashingda - Writing to the large 256x192
		Pos_Large = 12 + ( (X_Large+X_Small) + (Y_Large+Y_Small) * WD_Large)*4
		write memblock dword MEM256x192,Pos_Large,Color

	next X_Small
	next Y_Small

next X_Large
next Y_Large

`Ashingda - Creating the 256x192 image.
make image from memblock IMG256x192,MEM256x192


`Ashingda - Displaying the image.
do
	paste image IMG256x192,100,100
	sync
	cls
loop

Back to top

Profile PM Email

That1Smart Guy

15

Years of Service

User Offline

Joined: 26th Feb 2009

Location: Somewhere...... yep

Posted: 29th Jun 2009 16:02 Edited at: 29th Jun 2009 16:03

Link

not sure its possible to make that without distortion, since the x and y scales are different

and I havent read ashingdas post but you can use a pair of for-next loops with x and y to find the position:

+ Code Snippet

for y = 0 to memblock dword(m,4) rem the height
   for x = 0 to memblock dword(m,0) rem the width

      rem the formula to get the color at x,y is:
      rem      4*(y * width + x)+12

   next x
next y

There are only 10 kinds of people in the world, those who understand binary and those who dont

Back to top

Profile PM Email

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 29th Jun 2009 22:33

Link

You have to convert the number into [X,Y] values, it'll be much easier. Now are you wanting to tile this image throughout the larger one? Or just copy it once to a specific location in the bigger image? Either way it's quite simple. There would be no distortion unless you're enlarging the image, in which case it would just get a fuzzy or blurred.

[url="http://dbcc.zimnox.com"]

[/url]

Back to top

Profile PM Email Website

Libervurto

17

Years of Service

User Offline

Joined: 30th Jun 2006

Location: On Toast

Posted: 30th Jun 2009 03:10

Link

I would do something like spread the pixels from the small image to cover the large image

Small Image (3x3)
a a a
a a a
a a a

Large Image (5x5)
a b a b a
b c b c b
a b a b a
b c b c b
a b a b a

The {a} values are the original pixel colours, the {b} values are the average of the adjacent {a}'s, and the {c}'s are the average of the adjacent {b}'s.

TGC Forum - converting error messages into sarcasm since 2002.

Back to top

Profile PM Email

pictionaryjr

15

Years of Service

User Offline

Joined: 12th Mar 2009

Location:

Posted: 30th Jun 2009 03:38 Edited at: 30th Jun 2009 03:41

Link

@Phaelax
I want to tile it.

BTW I'm using a depth of 16 for the images not 32

Back to top

Profile PM Email

Ashingda 27

16

Years of Service

User Offline

Joined: 15th Feb 2008

Location:

Posted: 30th Jun 2009 07:31

Link

16 bit means you'll use word instead of dword. I've modify this to work in that mode.

`Ashingda - This example will use 32x32 and 256x192.

set display mode 640,480,16
sync on
sync rate 80

IMG32x32 = 1
IMG256x192 = 2

MEM32x32 = 1
MEM256x192 = 2

`Ashingda - Creating the 32x32 image memblock, (Cyan box with red X)
ink rgb(0,155,155),0
box 0,0,32,32
ink rgb(0,255,255),0
box 1,1,31,31
ink rgb(255,0,0),0
line 0,0,32,32
line 0,32,32,0
get image IMG32x32,0,0,32,32,1
sync
make memblock from image MEM32x32,IMG32x32
WD_Small = 32
HT_Small = 32

`Ashingda - Setting up the 256x192 memblock
make memblock MEM256x192,12+(256+192*256)*2
write memblock dword MEM256x192,0,256
write memblock dword MEM256x192,4,192
write memblock dword MEM256x192,8,16
WD_Large = 256
HT_Large = 192

`Ashingda - Memblock data transfer
for Y_Large = 0 to HT_Large - 1 step HT_Small
for X_Large = 0 to WD_Large - 1 step WD_Small

for Y_Small = 0 to HT_Small - 1
	for X_Small = 0 to WD_Small - 1

`Ashingda - Reading from the small 32x32
		Pos_Small = 12 + (X_Small + Y_Small * WD_Small) * 2
		Color = memblock word(MEM32x32,Pos_Small)

`Ashingda - Writing to the large 256x192
		Pos_Large = 12 + ( (X_Large+X_Small) + (Y_Large+Y_Small) * WD_Large)*2
		write memblock word MEM256x192,Pos_Large,Color

next X_Small
	next Y_Small

next X_Large
next Y_Large

`Ashingda - Creating the 256x192 image.
make image from memblock IMG256x192,MEM256x192

`Ashingda - Displaying the image.
do
	paste image IMG256x192,100,100
	sync
	cls
loop

+ Code Snippet

`Ashingda - This example will use 32x32 and 256x192. 

set display mode 640,480,16
sync on
sync rate 80

IMG32x32 = 1
IMG256x192 = 2

MEM32x32 = 1
MEM256x192 = 2

`Ashingda - Creating the 32x32 image memblock, (Cyan box with red X)
ink rgb(0,155,155),0
box 0,0,32,32
ink rgb(0,255,255),0
box 1,1,31,31
ink rgb(255,0,0),0
line 0,0,32,32
line 0,32,32,0
get image IMG32x32,0,0,32,32,1
sync
make memblock from image MEM32x32,IMG32x32
WD_Small = 32
HT_Small = 32

`Ashingda - Setting up the 256x192 memblock
make memblock MEM256x192,12+(256+192*256)*2
write memblock dword MEM256x192,0,256
write memblock dword MEM256x192,4,192
write memblock dword MEM256x192,8,16
WD_Large = 256
HT_Large = 192

`Ashingda - Memblock data transfer
for Y_Large = 0 to HT_Large - 1 step HT_Small
for X_Large = 0 to WD_Large - 1 step WD_Small

	for Y_Small = 0 to HT_Small - 1
	for X_Small = 0 to WD_Small - 1

		`Ashingda - Reading from the small 32x32
		Pos_Small = 12 + (X_Small + Y_Small * WD_Small) * 2
		Color = memblock word(MEM32x32,Pos_Small)

		`Ashingda - Writing to the large 256x192
		Pos_Large = 12 + ( (X_Large+X_Small) + (Y_Large+Y_Small) * WD_Large)*2
		write memblock word MEM256x192,Pos_Large,Color

	next X_Small
	next Y_Small

next X_Large
next Y_Large

`Ashingda - Creating the 256x192 image.
make image from memblock IMG256x192,MEM256x192


`Ashingda - Displaying the image.
do
	paste image IMG256x192,100,100
	sync
	cls
loop

Back to top

Profile PM Email

That1Smart Guy

15

Years of Service

User Offline

Joined: 26th Feb 2009

Location: Somewhere...... yep

Posted: 30th Jun 2009 07:36

Link

but then how to you get rgb, xcept you would need a special versio of the rgbr,rgbg,rgbb function set

ok now I get why 16 bit is less color than 32, theres half as many possible colors in it so technically every other color in 32 bit is left out of 16

There are only 10 kinds of people in the world, those who understand binary and those who dont

Back to top

Profile PM Email

Ashingda 27

16

Years of Service

User Offline

Joined: 15th Feb 2008

Location:

Posted: 30th Jun 2009 08:12

Link

To get the rgb you have to convert it from the 2 bits.

+ Code Snippet

	color = memblock word(1,pos)
	b = ((color&31)*255)/31
	g = ((color&2016)*255)/2016
	r = ((color&63488)*255)/63488

To write it back you have to convert it into 2 bits again.

+ Code Snippet

      r = ((r*63488)/255)&63488
      g = ((g*2016)/255)&2016
      b = ((b*31)/255)&31
      Color = r|g|b

Back to top

Profile PM Email

That1Smart Guy

15

Years of Service

User Offline

Joined: 26th Feb 2009

Location: Somewhere...... yep

Posted: 30th Jun 2009 17:57

Link

........wow how did u learn this stuff?

There are only 10 kinds of people in the world, those who understand binary and those who dont

Back to top

Profile PM Email

Ashingda 27

16

Years of Service

User Offline

Joined: 15th Feb 2008

Location:

Posted: 30th Jun 2009 18:26 Edited at: 30th Jun 2009 18:27

Link

Quote: "how did u learn this stuff?"

I learned it on this forum

. I had a few post out for it, Latch help a great deal.

Back to top

Profile PM Email

Sorry your browser is not supported!

DarkBASIC Discussion / smaller memblock image to bigger memblock image