So you are lurking around the DBC forums again!
Yes. You can link together meshes (a mesh is the structure of a 3d object. It is all the points and faces) as limbs and then use the built in limb animation commands to animate the object. Doing it "in house" seems to mean you want to do it within DBC entirely. Using the basic objects, sphere's, cubes, cylinders, etc., you can get up and running without too much trouble. But if you wanted to make sculpted 3d models of any type, it gets more complicated and it would be easier to use a 3d modeling program. It can be done in DBC, but it requires the use of memblocks and knowledge of mesh creation.
Here is an example of the basic process. The details are in the code:
set display mode 800,600,32
sync on
sync rate 60
autocam off
rem make a sphere for the shoulder. This will be the main object
make object sphere 1,25
rem make a long box that will be used as the limbs for the arm
rem the box will be longest along the x axis
make object box 2,50,10,10
remstart
to create a limb, we have to use a mesh. Let's make a mesh out
of the box. The problem though is, the box rotates around it's
center. We want it to rotate around it's end like a baseball bat
or like an arm does at the shoulder or elbow
To do that, we have to offset the box from it's center along the
long axis, which in this case is the x axis. Since it's 50 units
long on the x axis, and we want to move the point from the center,
that's an offset of 25 units
The base limb of an object is LIMB 0 . That is what we have to offset
for the box
remend
offset limb 2,0,25,0,0
`now make a mesh out of the offset object
make mesh from object 2,2
rem we're done with the box because we have our mesh. We can delete
rem the box
delete object 2
rem now we need to add the box as a limb to the sphere
rem this will be the upper arm
add limb 1,1,2
rem add another one for the lower arm
add limb 1,2,2
remstart
the lower arm is linked to the sphere by default. We want it linked
to the upper arm. This is called parent child relationships. The
main parent is the shoulder. It's first child is the upper arm.
The upper arm is the parent of the lower arm, so we have to make
the lower arm the child of the upper arm by using the LINK LIMB
command
remend
link limb 1,2,1
rem we need to offset the lower arm so that it is end to end
rem with the upper arm
offset limb 1,2,50,0,0
rem now we are ready to animate. We position and rotate the limbs
rem and set keyframes. A keyframe is a pose at a certain period
rem of time or frame. We can set the keyframes far apart and the
rem computer will figure out all the little poses in between.
set object keyframe 1,1
rem rotate the lower arm 90 degrees on the z axis
rotate limb 1,2,0,0,90
rem set this rotation for 10 frames later than the previous
set object keyframe 1,11
rem rotate the lower arm back to the starting point
rotate limb 1,2,0,0,0
rem set this keyframe for 10 frames later than the previous
set object keyframe 1,21
position camera 50,0,-100
rem loop the animation
loop object 1
rem wait for a key
wait key
Enjoy your day.
