Sorry your browser is not supported!

rem collision on a matrix
rem by TheComet

rem setup screen
sync on
sync rate 60
backdrop on
color backdrop 0
hide mouse

rem make a simple texture for the matrix
create bitmap 1,64,64
for x=0 to 63
   for y=0 to 63
      ink rgb(rnd(128),rnd(128)+120,0),0
      dot x,y
   next y
next x
get image 1,0,0,64,64
delete bitmap 1

rem create a landscape using a matrix
make matrix 1,1000,1000,20,20
prepare matrix texture 1,1,2,2
fill matrix 1,0,1
randomize matrix 1,25

rem sky
make object sphere 1,1000
position object 1,500,0,500
scale object 1,-100,100,100
color object 1,rgb(0,255,255)

rem set start positions for player
x#=500
z#=500

rem set speed for player
speed#=2.5

rem how far player is off ground
ground#=16

rem main loop
do

   rem rotate camera
   ay#=wrapvalue(ay#+mousemovex()/2)
   ax#=wrapvalue(ax#+mousemovey()/2)

   rem boundaries for looking up and down
   if ax#>180
      if ax#<270 then ax#=270
   else
      if ax#>90 then ax#=90
   endif

   rem get movement input
   success=0
   if leftkey()=1 then a#=ay#-90:success=1
   if rightkey()=1 then a#=ay#+90:success=1
   if upkey()=1 then a#=ay#:success=1
   if downkey()=1 then a#=ay#+180:success=1
   if leftkey()=1 and downkey()=1 then a#=ay#-135
   if downkey()=1 and rightkey()=1 then a#=ay#+135
   if rightkey()=1 and upkey()=1 then a#=ay#+45
   if upkey()=1 and leftkey()=1 then a#=ay#-45

   rem calculate new positions
   if success=1
      x#=newxvalue(x#,a#,speed#)
      z#=newzvalue(z#,a#,speed#)
   endif

   rem get current height of matrix
   y#=get ground height(1,x#,z#)

   rem update camera position and rotation
   position camera x#,y#+ground#,z#
   rotate camera ax#,ay#,0

   rem refresh screen
   sync

rem end of main loop
loop

rem end
end

autocam off
sync on
ink rgb(220,50,0),1:box 0,0,60,60
ink rgb(250,100,0),1:box 10,10,50,50
ink rgb(255,255,0),0:set cursor 0,0
print
print "CHAFARI"
print "CHAFARI"
print "CHAFARI"
get image 1,0,0,60,60,1
make light 1
position light 1,300,200,300
color light 1,rgb(255,0,0)
set light range 1,30000
`We make the terrain
`_______________________
make matrix 1,2000,2000,50,50
prepare matrix texture 1,1,1,1
randomize matrix 1,40
for i= 10 to 40
set matrix height 1,i+rnd(10),i+rnd(10),rnd(300)
next i
update matrix 1
 `starting position
x#=300
z#=300
`________________________

do
rem prepare matrix texture 1,1,rnd(3),rnd(3)
oldx#=x#
oldz#=z#
//camera controls
if upkey()=1 then x#=newxvalue(x#,a#,0.3) : z#=newzvalue(z#,a#,0.3)
if downkey()=1 then x#=newxvalue(x#,a#,-0.3) : z#=newzvalue(z#,a#,-0.3)

if leftkey()=1 THEN x#=NEWXVALUE(x#,a#-90,0.3):z#=NEWZVALUE(z#,a#-90,0.3)
if rightkey()=1 THEN x#=NEWXVALUE(x#,a#-90,-0.3):z#=NEWZVALUE(z#,a#-90,-0.3)

a#=wrapvalue(a#+mousemovex()/2)
cam#=wrapvalue(cam#+mousemovey()/2)
y#=get ground height(1,x#,z#)

`camera limits
if cam#<=290 and cam#>180 then cam#=290
if cam#>=70 and cam#<180 then cam#=70
rotate camera cam#,a#,0

`we make sure the player walk around
`_____________________________________
xd#=get ground height(1,x#+30,z#)
xi#=get ground height(1,x#-30,z#)

zf#=get ground height(1,x#,z#+30)
zb#=get ground height(1,x#,z#-30)

if xd#>y#+20 then dec x#,0.3
if xi#>y#+20 then inc x#,0.3

if zf#>y#+20 then dec z#,0.3
if zb#>y#+20 then inc z#,0.3

position camera x#,y#+15,z#
`_____________________________________

sync
loop

`AJUSTE DE UN TANQUE CON EL TERRENO :EJEMPLO 2
create bitmap 1,50,50:for i= 1 to 1550:ink rgb(230,95,55),0:line rnd(60),i,i,rnd(130)
next i:blur bitmap 1,6:get image 1,10,10,50,50:delete bitmap 1

make matrix 1,10000.0,10000.0,25,25
prepare matrix texture 1,1,1,1
randomize matrix 1,350.0
rem set matrix height 1,12,12,700.0
update matrix 1
set ambient light 20

`CREAMOS LOS OBJETOS CHIVATOS, Y AL OBJETO BLINDADO
make object sphere 1,10
make object sphere 4,10
make object sphere 5,10
`------------------------------------------------------
`---OBJETO BLINDADO CON UNOS CUANTOS LIMBS-------------
make object box 2,50,5,80:color object 2,rgb(50,100,100)
make object box 3,40,20,50
make mesh from object 1,3 :delete object 3
add limb 2,1,1 :add limb 2,2,1
scale limb 2,2,10,10,120 :offset limb 2,2,0,22,30:offset limb 2,1,0,10,0
color limb 2,2,rgb(0,0,200):color limb 2,1,rgb(0,50,170)

x#=500
z#=500
sync on
do
if upkey()=1 then x#=newxvalue(x#,a#,1) : z#=newzvalue(z#,a#,1)
if downkey()=1 then x#=newxvalue(x#,a#,-1) : z#=newzvalue(z#,a#,-1)
if leftkey()=1 then a#=wrapvalue(a#-1)
if rightkey()=1 then a#=wrapvalue(a#+1)

`calculamos la coordenadas "Y" de los dos chivatos
yb#=get ground height(1,object position x(1),object position z(1))
yb2#=get ground height(1,object position x(5),object position z(5))
yb3#=get ground height(1,object position x(4),object position z(4))

`calculamos la coordenada "y" del coche
y#=get ground height(1,x#,z#)
`pocisionamos a los objetos
position object 1,x#,yb#+40,z#
position object 2,x#,y#+30,z#
position object 5,x#,yb2#,z#
position object 4,x#,yb3#,z#

`rotamos a los objetos
yrotate object 1,a#
yrotate object 2,a#
yrotate object 5,a#
yrotate object 4,a#


`desplazamos al objeto chivato que lleva el blindado, para calcular la inclinacion
move object 1,80
`desplazamos al segundo chivato, que comprobara los alaveos
move object left 5,30
move object right 4,30

`hacemos que el blindado apunte a las coordenadas del chivato
`solo con esto, hemos conseguido, el efecto que se buscaba
point object 2,object position x(1),object position y(1),object position z(1)

`hacemos que el blindado, se alavee hacia la izquierda, la algura del blindado
`menos la atura del chivato..... TACHANNN
roll object left 2,y#-yb2#
roll object right 2,y#-yb3#
`Posiciona la cámara por detrás del objeto
cx#=newxvalue(x#,wrapvalue(a#+180),300)
cz#=newzvalue(z#,wrapvalue(a#+180),300)
cy#=get ground height(1,cx#,cz#)+100.0
position camera cx#,cy#+200,cz#

`enfoca la cámara al objeto
point camera x#,y#,z#
sync
loop