Sorry your browser is not supported!

` this work is based on a method created by Dave Bollinger (apparently)
` http://www.davebollinger.com/works/pixelspaceships/
` all the code is mine, but it is based on his descriptions.

set display mode 1024,768,32
sync on
sync rate 0
sync
set window on
set window position 0,0

randomize timer()
ink rgb(255,222,128),0
set text font "lucida console"
set text size 14

Dim Col(9) as DWORD

dim ship(13,13)
` MIRRORING: 1,12 ; 2,11 ; 3,10 ; 4,9 ; 5,8 ; 6,7
dim Temp(13,13)
 ` this is the TEMPLATE for ship building, and should be LOADED and STORED.

Global Size
Global Ysize

col(0)=0
col(1)=rgb(33,33,33)
col(2)=rgb(77,77,77)
col(3)=rgb(111,111,111)
col(4)=rgb(155,155,155)
col(5)=rgb(200,200,200)
col(6)=rgb(255,255,255)

Initialize_Ship_Template()

size=8
Ysize=12

Do

Generate_Ship()

draw_ship()

manipulate_Ship()

loop

END


Function Initialize_Ship_Template()

Restore Ship_Square_CASE_Data
for y=1 to 12
 for x=1 to 6
  read C
  Temp(x,y)=c
 next x
next y

Endfunction


Function Generate_Ship()

CLS

SOLID=rnd(1)

for x=1 to 12
 for y=1 to 12
  ship(x,y)=0
 next y
next x

Restore Ship_Square_CASE_Data
for y=1 to 12
 for x=1 to 6

 C = Temp(x,y)

      SELECT C

      Case 0 : ` - always BLACK, NOT part of the spaceship.
       ship(x,y)=0
      endcase

         Case 1 : `  - the ALWAYS SOLID bit (which should really be allowed to be either WHITE or DARK GREY
          if SOLID=1
           ship(x,y)=2
          else
           ship(x,y)=6
          endif
         endcase

      Case 2 : `  - BODY
       ` this is the body. 50% chance of being ON, or BLACK (totally off)
        if rnd(1)=0
         ship(x,y)=3
        else
         ship(x,y)=0
        endif
      endcase

         Case 3 : `  - COCKPIT
          if rnd(1)=0 : ` 50% on or off. if it's ON, the color is the OPPOSITE of the "always on" color. if it's OFF, its BLACK.
             if SOLID=0
              ship(x,y)=4
             else
              ship(x,y)=5
             endif
          else
           ship(x,y)=0
          endif
         endcase

            Case 4 : `  - nothing here.
            endcase

         Case 5 : `  - allowed to be SKIN.
          ` SKIN is done LAST , and EVERY 'ON' PART creates SKIN. done elsewhere.
         endcase

      ENDSELECT

`DRAW_SHIP()

 next x
next y

` NOW, generate the "SKIN"
 ` SKIN applies ONLY to EMPTY BLACK squares.
 ` it will be MUCH EASIER AND FASTER to look at EMPTY BLACK SQUARES
  ` and find if they get turned on, than to look at turner-on'ers.

for y=1 to 12
 for x=1 to 12
  if ship(x,y)=0
   if ship(x-1,y)>1 or  ship(x+1,y)>1 or  ship(x,y-1)>1 or  ship(x,y+1)>1
   if TEMP(x,y)>0
    ` IF this square is black, and an adjacent square is ON, and it's not beyond the outer skin
     ship(x,y)=1
   endif
   endif
  endif
 next x
next y

` NOW, MIRROR the ship.
  ` 1,12 ; 2,11 ; 3,10 ; 4,9 ; 5,8 ; 6,7
for y=1 to 12
 for x=1 to 6
  z=13-x
  ship(z,y)=ship(x,y)
 next x
next y

DRAW_SHIP()

sync

Endfunction


Function DRAW_SHIP()

cls

for y=1 to 12
 for x=1 to 12
  box x*size,y*Ysize,x*size+size,y*Ysize+Ysize,col(ship(x,y)),col(ship(x,y)),col(ship(x,y)),col(ship(x,y))
  box x*size,y*Ysize+350,x*size+size,y*Ysize+Ysize+350,col(ship(x,y)),col(ship(x,y)),col(ship(x,y)),col(ship(x,y))
 next x
next y

Endfunction

Ship_Square_CASE_Data:
data 0,0,0,0,5,5
data 0,0,0,5,2,2
data 0,0,0,5,2,1
data 0,0,5,2,2,1
data 0,0,5,2,2,1
data 0,5,2,2,2,1
data 5,2,2,2,3,3
data 5,2,2,2,3,3
data 5,2,2,2,3,3
data 5,2,2,2,2,1
data 0,5,5,2,2,2
data 0,0,0,5,5,5

Function manipulate_Ship()

do
cls
draw_ship()

box 300,300,600,600,rgb(255,0,0),rgb(0,0,0),rgb(0,255,0),rgb(0,0,255)
box 600,300,900,600,rgb(255,0,255),rgb(255,255,0),rgb(255,128,0),rgb(255,255,255)
box 300,600,900,800,rgb(0,0,0),rgb(0,0,0),rgb(255,255,255),rgb(255,255,255)

text 300,0,"0 - BLACK - Non-ship squares"
text 300,20,"1 - Outer Skin" : box 500,20,700,30,col(1),col(1),col(1),col(1)
text 300,40,"2 - Always Solid (50%)" : box 500,40,700,50,col(2),col(2),col(2),col(2)
text 300,60,"3 - BODY" : box 500,60,700,70,col(3),col(3),col(3),col(3)
text 300,80,"4 - cockpit" : box 500,80,700,90,Col(4),Col(4),Col(4),Col(4)
text 300,100,"5 - cockpit (50%)" : box 500,100,700,110,Col(5),Col(5),Col(5),Col(5)
text 300,120,"6 - Always solid (50%)" : box 500,120,700,130,Col(6),Col(6),Col(6),Col(6)

text 300,160,"put the mouse over a color. press corresponding number to select that color "
TEXT 300,180, " PRESS +/- to change WIDTH ("+STR$(SIZE)+"), or >/< to change HEIGHT ("+STR$(YSIZE)+")"
text 300,240," PRESS SPACE BAR TO GENERATE A NEW SHIP "
text 000,730,"check out this web site :"
text 000,750," http://www.davebollinger.com/works/pixelspaceships/"
a=val(inkey$())

if a>0 and a<7
 col(a)=point(mousex(),mousey())
endif

if keystate(12) and size>2 
 dec size : wait 150
endif

if keystate(13) and size<20
 inc size : wait 150
endif

if keystate(51) and Ysize>2 
 dec Ysize : wait 150
endif

if keystate(52) and Ysize<28
 inc Ysize : wait 150
endif

sync

IF SPACEKEY() THEN wait 250 : EXIT

loop

Endfunction

col(a)=point(mousex(),mousey()) OR 0xFF000000

 do it in here, or by email, whatever.
 random planets, random ships, i can even make similar alien 'race pictures' 
 
but the real problem is, you can't even run the 'text' version of the game without huge slow-down...(this is not an insult, it's just a concern for future versions)
when it got 100's of planets, 1000's of ships, etc. , how would we handle the program?

set display mode 1024,768,32
set window on
set window position 0,0

set text font "lucida console"
set text size 18
SYNC on
sync rate 0
sync


dim pp(14,14)

dim grid(14,14)
 restore GRID_DATA_SEVEN
 
  for y=1 to 14
   for x=1 to 14
    read a
    grid(x,y)=a
   next x
  next y


dim col(10) as dword

global MegaX
global MegaY

DO

cls

for megaX=0 to 17
for megaY=0 to 7

`SHOW_PLANETS()

col(0)=rgb(0,0,0)

GG=rnd(9) : ` decide whether to make this a Gas Giant Type or not

for c=1 to 4
 repeat
  u=rnd(255)
  v=rnd(255)
  w=rnd(255)
 until (GG<>0 AND (u>30 or v>30 or v>30) ) OR (GG=0 AND u>120 and v>120 and v>120)
  col(c)=rgb(u,v,w)
next c
  
col(9)=rgb(255,255,255)

 ` set the whole thing to the WATER color.
for x=1 to 14
 for y=1 to 14
  if grid(x,y)=0
   pp(x,y)=0
  else
   pp(x,y)=1
  endif
   ` pp(x,y)=grid(x,y) : ` that's 0 for black, 1 for blue. but doesn't handle 2's
 next y
next x


IF GG=0
 ` do the GG-type planet
  for y=1 to 14
    c=rnd(3)+1
   for x=1 to 14
    if grid(x,y)>0
     pp(x,y)=c
    endif
   next x
  next y

ELSE
 ` do a normal terrestrial-type planet

 CONT=rnd(30)+20

for t=1 to CONT : ` place up to 40 continent objects (dots)
 
 repeat
   x=rnd(13)+1
   y=rnd(13)+1
 until pp(x,y)=1 and grid(x,y)=1
 
  ` we have found an unoccupied square. now make it either brown or green:
  if rnd(2)=0
   pp(x,y)=2
  else
   pp(x,y)=3
  endif
  
next t

ENDIF

SHOW_PLANETS()

next megaY
next megaX

wait key

LOOP

GRID_DATA_SEVEN:

data 0,0,0,0,2,2,2,2,2,2,0,0,0,0
data 0,0,0,2,2,1,1,1,1,2,2,0,0,0
data 0,0,2,2,1,1,2,1,1,1,2,2,0,0
data 0,2,2,1,1,2,1,1,1,1,1,2,2,0
data 2,2,1,1,1,2,1,1,1,1,1,1,2,2
data 2,1,1,2,2,1,1,1,1,1,1,1,1,2
data 2,1,2,1,1,1,1,1,1,1,1,1,1,2
data 2,1,2,1,1,1,1,1,1,2,2,1,1,2
data 2,1,1,1,1,1,1,1,2,2,1,1,2,2
data 2,2,1,1,1,1,1,2,2,2,1,2,2,2
data 0,2,2,1,1,1,1,2,1,1,2,2,2,0
data 0,0,2,2,1,1,1,1,1,2,2,2,0,0
data 0,0,0,2,2,1,1,1,2,2,2,0,0,0
data 0,0,0,0,2,2,2,2,2,2,0,0,0,0
 ` this sets the OUTER SHELL to ALWAYS WATER.


Function SHOW_PLANETS()
    for x=1 to 14
     for y=1 to 14
      dot x+megaX*30,y+megaY*22,col(pp(x,y))
      box x*3+megaX*50,y*3+200+megaY*50, x*3+3+megaX*50,y*3+203+megaY*50, col(pp(x,y)),col(pp(x,y)),col(pp(x,y)),col(pp(x,y))
     next y
    next x
     sync
Endfunction