Sorry your browser is not supported!

SETTINGS
TextLanguage=English
TextLanguage-Charset=1
HelpLanguage=English
HelpLanguage-Charset=1
HelpFontSize=0
ExternalEditor=None
blitoverdraw=0
blitflipmode=1
vbcreate=0
vbusage=0
3doverlay=0
runtimetest=1
tracemode=0
;debugmode=0
windowmode=1
popupoff=0

set display mode 800,600,16
sync on

cls rgb(255,255,255)

ink 0,0

make memblock from bitmap 1,0
wd=memblock dword(1,0)
ht=memblock dword(1,4)
dp=memblock dword(1,8)
text 0,0,"Resolution set at "+str$(screen width())+","+str$(screen height())+","+str$(screen depth())
text 0,20,"Actual resultion is "+str$(wd)+","+str$(ht)+","+str$(dp)

rem find max 4:3 screen size on widescreen  desktop display
rem by latch
rem 10/07/2011

max43_on_widescreen(0,0,0)
cls 128
text 0,0,"screen width = "+str$(screen width())
text 0,20,"screen height = "+str$(screen height())


end
function max43_on_widescreen(todesktop,desiredwidth,desiredheight)
   remstart
      by latch
      10/07/2011

      Setup a 4:3 screen on a widescreen display at the maximum possible
      resolution within the desktop size to keep the view from being stretched.
      If a 4:3 resolution can't be found the default resolution will be the desktop size.

      For this function to work properly, windowmode=1 must be set under
      SETTINGS in the setup.ini file

      todesktop         ==       This will ignore the 4:3 ratio and set the resolution
                                 to the desktop size.
                                 1=to desktop size
                                 0=max 4:3 within desktop
      desiredwidth      ==       This is the screen width one wants to run the game in.  If
                                 it exists, it will be displayed.  Please note this function is
                                 based on running the DBC display in windowed mode so if this
                                 value is larger than the desktop, there will be areas of the screen
                                 that cannot be seen.
                                 if 0 , this parameter will be ignored
      desired height    ==       See desiredwidth above - except this applies to screen height

   remend

   rem get metrics from windows
   SM_CXSCREEN = 0
   SM_CYSCREEN = 1
   BITSPIXEL = 12
   hdc=0
   load dll "user32.dll",1
   load dll "gdi32.dll",2
   desktop_width=call dll(1,"GetSystemMetrics",SM_CXSCREEN)
   desktop_height=call dll(1,"GetSystemMetrics",SM_CYSCREEN)
   hdc=call dll(1, "GetDC", 0)
   desktop_depth=call dll(2, "GetDeviceCaps", hdc, BITSPIXEL)
   call dll 1, "ReleaseDC", 0, hdc

   rem check desiredwidth and height
   if desiredwidth > 0 and desiredheight > 0
      set display mode desiredwidth,desiredheight,desktop_depth
      delete dll 2
      delete dll 1
      exitfunction
   endif

   rem compare the metrics to the possible resolutions - lowest common denominator is screen height
   perform checklist for display modes
   maxvalue=0
   for n=1 to checklist quantity()
      rem check screen height possibilities
      if checklist value b(n) <= desktop_height
         if ((checklist value b(n)+0.0)/(checklist value a(n)+0.0))=.75
            maxvalue=n
         endif
      endif
      if checklist value b(n) > desktop_height
         rem we're at a larger value than our desktop height so get out of loop
         exit
      endif
   next n

   rem if the todesktop flag is set then make the screen the size of the desktop
   rem this may be widescreen and therefore not function properly in DBC
   if todesktop or maxvalue=0
      set display mode desktop_width,desktop_height,desktop_depth
   else
      set display mode checklist value a(maxvalue),checklist value b(maxvalue),desktop_depth
   endif

   empty checklist
   delete dll 2
   delete dll 1
endfunction