dont know 2d - GameCreators Forum

Author

Message

redeye

20

Years of Service

User Offline

Joined: 30th Oct 2003

Location:

Posted: 2nd Nov 2003 13:53

Link

im new to dark basic i can do things in 3d but dont have a clue in 2d so could any one help me make a simple 2d game like pong or snake or something plz

im new to games creation so plz help if you can

Back to top

Profile PM

Pincho Paxton

21

Years of Service

User Offline

Joined: 8th Dec 2002

Location:

Posted: 2nd Nov 2003 15:47 Edited at: 2nd Nov 2003 15:50

Link

If you know 3D then it's best to stick with it even for 2D games like pong. Just use plains with textures on them to get the flat pictures that you need for the game. Then face the camera towards them. The collision for 2D games has nearly always been array collision. This is where you make a collision engine from a map containing zero's and 1's. Zero's are ignored, and 1's are a collision. This works in 3D just as well as 2D.

Pseudo Code......

Dim Map(800,600) for perfect pixel collision on 800*600 screen.
Dim Map(800/32,600/32) for Pacman type collision.

Fill the map with Data

Loop Y
Loop X
Read Map(X,Y)
End Loop X
End Loop Y

Data 1,1,1,1,1,1,1,1,0,0,0,0,0,0,0,0,0,1,1,1,1,1,1,1,1

How do you make the collision Data.

Make a mask in black for collision areas by drawing over your screen pics. Make a proggy to check the screen for black areas that stores a 1 in the Dim(X,Y) positions.

If it's pong then you make an array for the bat. Or use sprite collision. The walls could just be....

Pseudo code...
If BallSpriteX > 790 Then rebound
If BallSpriteX < 10 Then rebound
If BallSpriteY > 590 Then rebound
If BallSpriteY < 10 Then rebound

If you really want to try 2D then most things are drawn to Bitmaps. Images are often Pasted to the screen, and sprites are used a lot. Arrays are often used for collision, and two screens are often swapped between, one temporary/Invisible screen like a Clipboard. The other visible screen being screen 0, and being the main game arena.

Pincho.

Back to top

Profile PM Email Website

Codger

21

Years of Service

User Offline

Joined: 23rd Nov 2002

Location:

Posted: 3rd Nov 2003 02:54

Link

Here Pong

Just Add Scoring & Sound

Rem Project: PONG
Rem Created: 11/2/2003 7:13:43 AM

Rem ***** Main Source File *****

Remstart
   The game of  pong using sprites
Remend

SET DISPLAY MODE 640,400,32

Sync OFF
Sync rate 0

#CONSTANT TopWall  1
#CONSTANT BottomWall  2
#CONSTANT LeftWall  3
#CONSTANT RightWall  4
#CONSTANT Paddle 5
#CONSTANT Ball 6
#CONSTANT BallSize 20

#CONSTANT SCRWD Screen Width()
#CONSTANT SCRHT Screen Height()
#CONSTANT WALLTH 25
#CONSTANT RED RGB(255,0,0)
#CONSTANT WHITE RGB(255,255,255)
#CONSTANT BLUE RGB(0,0,255)
#CONSTANT GREEN RGB(0,255,0)
#CONSTANT PDLWD 20
#CONSTANT PDLHT 60
#CONSTANT PDLX SCRWD-(WALLTH+PDLWD+5)
#CONSTANT PDLY MouseY()-(PDLHT/2)
#CONSTANT MinAngle 20

Global StartSpeed : StartSpeed = 3
Global BallSpeed : BallSpeed = StartSpeed
Global TimeChange : TimeChange = 5000
Global MyTimer : MyTimer = Timer() + TimeChange

Randomize Timer()

MakeTable()
MakePaddle()
MakeBall()
Hide Mouse

do
   MoveBall()
   CheckLimits()
   MovePaddle()
   CheckCollision()
   CheckSpeed()
   Sync
loop

Function CheckLimits()

If Sprite x(Ball) > SCRWD-WALLTH
      MakeBall()
   Endif
   If Sprite x(Ball) < WALLTH
      Move Sprite Ball, -BallSpeed
      Rotate Sprite Ball, Bounce(0, Sprite Angle(Ball))
   Endif
   If Sprite Y(Ball) > SCRHT-WALLTH
      Move Sprite Ball, -BallSpeed
      Rotate Sprite Ball, Bounce(180, Sprite Angle(Ball))
   Endif
   If Sprite Y(Ball) < WALLTH
      Move Sprite Ball, -BallSpeed
      Rotate Sprite Ball, Bounce(180,Sprite Angle(Ball))
   Endif
EndFunction

Function Bounce(WallAng,N)
   ExitAngle = (WallAng-N) Mod 360
EndFunction ExitAngle

Function CheckSpeed()
   If MyTimer < Timer()
      inc BallSpeed
      MyTimer = Timer() + TimeChange
   EndIf
EndFunction

Function CheckCollision()
   Select Sprite hit(Ball,0)
   CASE Paddle : Rotate Sprite Ball,270-(Sprite Y(Ball)- (Sprite Y(Paddle)+PDLHT/2))  :ENDCASE
   EndSelect
EndFunction

Function MoveBall()
   Move Sprite Ball, BallSpeed
EndFunction

Function MakeTable()
   MakeSprite(TopWall,SCRWD,WALLTH,RED): Sprite TopWall,0,0,TopWall
   MakeSprite(BottomWall,SCRWD,WALLTH,RED):Sprite BottomWall,0,SCRHT-WALLTH,BottomWall
   MakeSprite(LeftWall,WALLTH,SCRHT,RED):Sprite LeftWall,0,0,LeftWall
   MakeSprite(RightWall,WALLTH,SCRHT,RED): Sprite RightWall,SCRWD-WALLTH,0,RightWall
EndFunction

Function MakePaddle()
   MakeSprite(Paddle,PDLWD,PDLHT,BLUE)
EndFunction

Function MakeBall():
   If Sprite Exist (Ball) Then Delete Sprite Ball
   MakeSprite(Ball,BallSize,BallSize,GREEN)
   Sprite Ball,50,50,Ball
   Offset Sprite Ball, BallSize/2,BallSize/2
   rotate sprite ball, rnd(60)+90
   BallSpeed = StartSpeed
EndFunction

Function MovePaddle()
   Sprite Paddle,SCRWD-(WALLTH+PDLWD+1),MouseY()-(PDLHT/2),Paddle
EndFunction

Function MakeSprite(SP,WD,HT,CL)
    If Bitmap Exist (1) then Delete Bitmap 1
    create Bitmap 1, WD,HT
    INK CL,0
    BOX 0,0,WD,HT
    Get Image SP,0,0,WD,HT
    Sprite SP,0,0,SP
    Delete Bitmap 1
    Set Current Bitmap 0
EndFunction

+ Code Snippet

Rem Project: PONG
Rem Created: 11/2/2003 7:13:43 AM

Rem ***** Main Source File *****

Remstart
   The game of  pong using sprites
Remend

SET DISPLAY MODE 640,400,32

Sync OFF
Sync rate 0

#CONSTANT TopWall  1
#CONSTANT BottomWall  2
#CONSTANT LeftWall  3
#CONSTANT RightWall  4
#CONSTANT Paddle 5
#CONSTANT Ball 6
#CONSTANT BallSize 20

#CONSTANT SCRWD Screen Width()
#CONSTANT SCRHT Screen Height()
#CONSTANT WALLTH 25
#CONSTANT RED RGB(255,0,0)
#CONSTANT WHITE RGB(255,255,255)
#CONSTANT BLUE RGB(0,0,255)
#CONSTANT GREEN RGB(0,255,0)
#CONSTANT PDLWD 20
#CONSTANT PDLHT 60
#CONSTANT PDLX SCRWD-(WALLTH+PDLWD+5)
#CONSTANT PDLY MouseY()-(PDLHT/2)
#CONSTANT MinAngle 20

Global StartSpeed : StartSpeed = 3
Global BallSpeed : BallSpeed = StartSpeed
Global TimeChange : TimeChange = 5000
Global MyTimer : MyTimer = Timer() + TimeChange

Randomize Timer()

MakeTable()
MakePaddle()
MakeBall()
Hide Mouse

do
   MoveBall()
   CheckLimits()
   MovePaddle()
   CheckCollision()
   CheckSpeed()
   Sync
loop

Function CheckLimits()

   If Sprite x(Ball) > SCRWD-WALLTH
      MakeBall()
   Endif
   If Sprite x(Ball) < WALLTH
      Move Sprite Ball, -BallSpeed
      Rotate Sprite Ball, Bounce(0, Sprite Angle(Ball))
   Endif
   If Sprite Y(Ball) > SCRHT-WALLTH
      Move Sprite Ball, -BallSpeed
      Rotate Sprite Ball, Bounce(180, Sprite Angle(Ball))
   Endif
   If Sprite Y(Ball) < WALLTH
      Move Sprite Ball, -BallSpeed
      Rotate Sprite Ball, Bounce(180,Sprite Angle(Ball))
   Endif
EndFunction

Function Bounce(WallAng,N)
   ExitAngle = (WallAng-N) Mod 360
EndFunction ExitAngle

Function CheckSpeed()
   If MyTimer < Timer()
      inc BallSpeed
      MyTimer = Timer() + TimeChange
   EndIf
EndFunction

Function CheckCollision()
   Select Sprite hit(Ball,0)
   CASE Paddle : Rotate Sprite Ball,270-(Sprite Y(Ball)- (Sprite Y(Paddle)+PDLHT/2))  :ENDCASE
   EndSelect
EndFunction

Function MoveBall()
   Move Sprite Ball, BallSpeed
EndFunction

Function MakeTable()
   MakeSprite(TopWall,SCRWD,WALLTH,RED): Sprite TopWall,0,0,TopWall
   MakeSprite(BottomWall,SCRWD,WALLTH,RED):Sprite BottomWall,0,SCRHT-WALLTH,BottomWall
   MakeSprite(LeftWall,WALLTH,SCRHT,RED):Sprite LeftWall,0,0,LeftWall
   MakeSprite(RightWall,WALLTH,SCRHT,RED): Sprite RightWall,SCRWD-WALLTH,0,RightWall
EndFunction

Function MakePaddle()
   MakeSprite(Paddle,PDLWD,PDLHT,BLUE)
EndFunction

Function MakeBall():
   If Sprite Exist (Ball) Then Delete Sprite Ball
   MakeSprite(Ball,BallSize,BallSize,GREEN)
   Sprite Ball,50,50,Ball
   Offset Sprite Ball, BallSize/2,BallSize/2
   rotate sprite ball, rnd(60)+90
   BallSpeed = StartSpeed
EndFunction

Function MovePaddle()
   Sprite Paddle,SCRWD-(WALLTH+PDLWD+1),MouseY()-(PDLHT/2),Paddle
EndFunction

Function MakeSprite(SP,WD,HT,CL)
    If Bitmap Exist (1) then Delete Bitmap 1
    create Bitmap 1, WD,HT
    INK CL,0
    BOX 0,0,WD,HT
    Get Image SP,0,0,WD,HT
    Sprite SP,0,0,SP
    Delete Bitmap 1
    Set Current Bitmap 0
EndFunction

System
PIII 650 MZ H.P. Pavillion
394 Mem GeForce 4 400MX

Back to top

Profile PM Email

CloseToPerfect

21

Years of Service

User Offline

Joined: 20th Dec 2002

Location: United States

Posted: 3rd Nov 2003 06:51

Link

codger, that is really nice coding, vary simple amd easy to fallow. I wish my code would be that neat, seems I start off neat and end up with spagetti code everytime.

CTP

Back to top

Profile PM Email

redeye

20

Years of Service

User Offline

Joined: 30th Oct 2003

Location:

Posted: 3rd Nov 2003 13:03

Link

thanx for the code im going to try it now

im new to games creation so plz help if you can

Back to top

Profile PM

Sorry your browser is not supported!

2D All the way! / dont know 2d