[DBP] - Simple RPG Branching Menu

Author

Message

Mr909

11

Years of Service

User Offline

Joined: 2nd Jun 2012

Location:

Posted: 29th Oct 2012 20:32

Link

This is just a sample of how to design a very simple, text-based menu using only a few variables. One of the cooler features I implemented is the hold timer that allows you to move up/down the list more quickly. Besides that, not much going on.

//Computer Color Constants
#CONSTANT col_white RGB(255,255,255)
#CONSTANT col_black RGB(0,0,0)
#CONSTANT col_gray RGB(128,128,128)
#CONSTANT col_yellow RGB(255,255,0)
hold AS BOOLEAN
actmenu AS BYTE
choose AS BYTE
item AS BYTE

SYNC ON
SYNC RATE 60

//Variable Defaults
actmenu=1
choose=5
item=1
hold=0
//Click determines the arrow sensitivity, higher is slower
click=30
T=TIMER()

DO
CLS

//Timer Automatically unsticks the hold value
IF tleft<0
T=TIMER()
IF hold=1 THEN hold=0
ENDIF
elapse=(TIMER()-T)/10
tleft=click-elapse

//Item Control
IF hold=0
IF UPKEY()=1 THEN hold=1 : item=item-1
IF DOWNKEY()=1 THEN hold=1 : item=item+1
ENDIF
IF (UPKEY()+DOWNKEY()+SPACEKEY())<1 THEN hold=0
item=num_trim(item,1,choose)

//Menu Select
IF SPACEKEY()=1 AND hold=0
	//Main Menu
	IF actmenu=1
		//Select Attack
		IF item=1 THEN actmenu=2 : item=1 : choose=3 : hold=1
		//Select Specials
		IF item=2 THEN actmenu=3 : item=1 : choose=4 : hold=1
	ENDIF
	//Attack Menu
	IF actmenu=2
		//Go Back
		IF item=3 THEN actmenu=1 : item=1 : choose=5 : hold=1
	ENDIF
	//Specials Menu
	IF actmenu=3
		//Go Back
		IF item=4 THEN actmenu=1 : item=1 : choose=5 : hold=1
	ENDIF
ENDIF

//Main Menu-Active Menu 1
//Highlights item if selected
	IF actmenu=1
		IF item=1 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Attack"
		IF item=2 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Special"
		IF item=3 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Items"
		IF item=4 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Guard"
		IF item=5 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Escape"
	ENDIF
//Attack Menu-Active Menu 2
	IF actmenu=2
		IF item=1 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Sword"
		IF item=2 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Unarmed"
		IF item=3 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Back"
	ENDIF
//Specials Menu-Active Menu 3
	IF actmenu=3
		IF item=1 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Fire"
		IF item=2 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Ice"
		IF item=3 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Thunder"
		IF item=4 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Back"
	ENDIF

SYNC
LOOP

END

FUNCTION num_trim(value,vfloor,vceiling)
IF value>vceiling THEN value=vceiling
IF value<vfloor THEN value=vfloor
ENDFUNCTION value

+ Code Snippet

//Computer Color Constants
#CONSTANT col_white RGB(255,255,255)
#CONSTANT col_black RGB(0,0,0)
#CONSTANT col_gray RGB(128,128,128)
#CONSTANT col_yellow RGB(255,255,0)
hold AS BOOLEAN
actmenu AS BYTE
choose AS BYTE
item AS BYTE

SYNC ON
SYNC RATE 60

//Variable Defaults
actmenu=1
choose=5
item=1
hold=0
//Click determines the arrow sensitivity, higher is slower
click=30
T=TIMER()


DO
CLS


//Timer Automatically unsticks the hold value
IF tleft<0
T=TIMER()
IF hold=1 THEN hold=0
ENDIF
elapse=(TIMER()-T)/10
tleft=click-elapse

//Item Control
IF hold=0
IF UPKEY()=1 THEN hold=1 : item=item-1
IF DOWNKEY()=1 THEN hold=1 : item=item+1
ENDIF
IF (UPKEY()+DOWNKEY()+SPACEKEY())<1 THEN hold=0
item=num_trim(item,1,choose)

//Menu Select
IF SPACEKEY()=1 AND hold=0
	//Main Menu
	IF actmenu=1
		//Select Attack
		IF item=1 THEN actmenu=2 : item=1 : choose=3 : hold=1
		//Select Specials
		IF item=2 THEN actmenu=3 : item=1 : choose=4 : hold=1
	ENDIF
	//Attack Menu
	IF actmenu=2
		//Go Back
		IF item=3 THEN actmenu=1 : item=1 : choose=5 : hold=1
	ENDIF
	//Specials Menu
	IF actmenu=3
		//Go Back
		IF item=4 THEN actmenu=1 : item=1 : choose=5 : hold=1
	ENDIF
ENDIF

//Main Menu-Active Menu 1
//Highlights item if selected
	IF actmenu=1
		IF item=1 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Attack"
		IF item=2 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Special"
		IF item=3 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Items"
		IF item=4 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Guard"
		IF item=5 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Escape"
	ENDIF
//Attack Menu-Active Menu 2
	IF actmenu=2
		IF item=1 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Sword"
		IF item=2 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Unarmed"
		IF item=3 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Back"
	ENDIF
//Specials Menu-Active Menu 3
	IF actmenu=3
		IF item=1 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Fire"
		IF item=2 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Ice"
		IF item=3 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Thunder"
		IF item=4 THEN INK col_yellow,col_black ELSE INK col_white,col_black
		PRINT "Back"
	ENDIF

SYNC
LOOP

END

FUNCTION num_trim(value,vfloor,vceiling)
IF value>vceiling THEN value=vceiling
IF value<vfloor THEN value=vfloor
ENDFUNCTION value

Back to top

Profile PM Email

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 30th Oct 2012 12:34 Edited at: 30th Oct 2012 14:21

Link

You need a flag that prevents it from detecting the spacekey multiple times before it's released. Whenever I tried to go back to a previous menu, it'd just clicked right back.

A large problem with your system is that it's not very flexible. You'd have to make another IF block every time you wanted to add a new menu or submenu.

I wrote this up for you. It's not intended to show up your code, but hopefully demonstrate another, more flexible, method for a similar type of menu system by using arrays. It might look like a lot of complex code at first but it really isn't.

REM ********************************************
REM Title: Menu System
REM Author: Phaelax
REM Created: Tuesday, October 30, 2012
REM ********************************************

Type MenuItem
    parentId as integer
    name as string
    isSelected as integer
EndType

dim menuItems() as MenuItem

Global currentMenu = 0
Global lastMenu = 0

rootId = insertMenuItem("root", -1)
insertMenuItem("New", rootId)
insertMenuItem("Open", rootId)
insertMenuItem("Save", rootId)
settingsId = insertMenuItem("Settings", rootId)
insertMenuItem("Exit", rootId)

insertMenuItem("Customize", settingsId)
insertMenuItem("Options", settingsId)
insertMenuItem("Plugins", settingsId)

currentMenu = rootId
selectFirstItem(currentMenu)
selectedItem = -1

do
    cls

if upkey() = 1 and vkFlag = 0
        vkFlag = 1
        selectPrevious(currentMenu)
    endif
    
    if downkey() = 1 and vkFlag = 0
        vkFlag = 1
        selectNext(currentMenu)
    endif
    
    if rightkey() and vkFlag = 0
        currentMenu = openSubMenu(currentMenu)
        vkFlag = 1
    endif
    
    if leftkey() and vkFlag = 0
        vkFlag = 1
        currentMenu = openParentMenu(currentMenu)
    endif
    
    if returnkey() and vkFlag = 0
        vkFlag = 1
        selectedItem = getSelectedItem(currentMenu)
    endif
    
    rem reset key flag
    if upkey() + downkey() + rightkey() + leftkey() + returnkey() = 0 then vkFlag = 0
    
    
    rem display menu
    displayMenu(currentMenu, 100, 120)
    
    
    print "'",getMenuItemName$(selectedItem), "' is currently active."
loop

REM ***********************************************
REM Returns the name of the menu item
REM ***********************************************
function getMenuItemName$(menuItemId)
    if menuItemId > -1
        s$ = menuItems(menuItemId).name
    else
        s$ = "Invalid Menu Item ID"
    endif
endfunction s$

REM ***********************************************
REM Go up one level in the menu hierarchy
REM ***********************************************
function openParentMenu(menuItemId)
    pid = getParentId(menuItemId)
    if pid = -1
        pid = menuItemId
    else
        id = getSelectedItem(menuItemId)
        if id > -1 then menuItems(id).isSelected = 0
    endif
endfunction pid

REM ***********************************************
REM Go one level deeper in the menu hierarchy
REM ***********************************************
function openSubMenu(menuItemId)
    count = getChildCount(getSelectedItem(menuItemId))
    if count > 0
        lastMenu = menuItemId
        menuItemId = getSelectedItem(menuItemId)
        selectFirstItem(menuItemId)
    endif
endfunction menuItemId

REM ***********************************************
REM Return the menu item ID to which this item
REM belongs to
REM ***********************************************
function getParentId(menuItemId)
    pid = menuItems(menuItemId).parentId
endfunction pid

REM ***********************************************
REM Returns number of menu items that belong to
REM this one
REM ***********************************************
function getChildCount(menuItemId)
    c = 0
    for i = 0 to array count(menuItems())
        if menuItems(i).parentId = menuItemId then inc c
    next i
endfunction c

REM ***********************************************
REM Selects/highlights first item in the current
REM menu
REM ***********************************************
function selectFirstItem(menuItemId)
    for i = 0 to array count(menuItems())
        if menuItems(i).parentId = menuItemId then menuItems(i).isSelected = 1 : exitfunction
    next i
endfunction

REM ***********************************************
REM Selects/highlights the previous menu item. If  
REM the currently selected item is the first one,
REM if will wrap around to the end.
REM ***********************************************
function selectPrevious(menuItemId)
    if getChildCount(menuItemId) = 0 then exitfunction
    
    previousId = -1
    currentlySelected = -1
    for i = 0 to array count(menuItems())
        if menuItems(i).parentId = menuItemId
            if menuItems(i).isSelected = 0
                previousId = i
            else
                if previousId > -1
                    menuItems(i).isSelected = 0
                    menuItems(previousId).isSelected = 1
                    exitfunction previousId
                endif
                currentlySelected = i
            endif
        endif
    next i
    
    if previousId > -1
        menuItems(previousId).isSelected = 1
        menuItems(currentlySelected).isSelected = 0
    endif
endfunction previousId

REM ***********************************************
REM Selects/highlights the next menu item. If the 
REM currently selected item is the last one, it
REM will wrap around to the beginning.
REM ***********************************************
function selectNext(menuItemId)
    if getChildCount(menuItemId) = 0 then exitfunction
    
    firstItemId = -1
    currentlySelected = -1
    newSelectedId = -1
    for i = 0 to array count(menuItems())
        if menuItems(i).parentId = menuItemId
            if firstItemId = -1 then firstItemId = i
            if currentlySelected > -1
                newSelectedId = i
                menuItems(currentlySelected).isSelected = 0
                menuItems(newSelectedId).isSelected = 1
                exitfunction newSelectedId
            endif
            if menuItems(i).isSelected then currentlySelected = i
        endif
    next i
    if newSelectedId = -1
        menuItems(currentlySelected).isSelected = 0
        menuItems(firstItemId).isSelected = 1
    endif
endfunction firstItemId

REM ***********************************************
REM Returns the menu item id of the currently
REM selected menu item
REM ***********************************************
function getSelectedItem(menuItemId)
    for i = 0 to array count(menuItems())
        if menuItems(i).parentId = menuItemId
            if menuItems(i).isSelected then exitfunction i
        endif
    next i
endfunction -1

REM ***********************************************
REM Draws the menu, one level deep at a time.
REM
REM Improvements:
REM Ideally, the system should keep track to number
REM of children upon insertion and not have to 
REM recalculate that number each time it is needed.
REM On a large, extensively complex menu array, 
REM this could cause a performance hit and is quite
REM inefficient.
REM ***********************************************
function displayMenu(menuItemId, x, y)
    c = 0
    for i = 0 to array count(menuItems())
        if menuItems(i).parentId = menuItemId
            if menuItems(i).isSelected
                ink rgb(255,255,0),0
            else
                ink rgb(255,255,255),0
            endif
            text x, y+c*18, menuItems(i).name
            if getChildCount(i) > 0 then text x+text width(menuItems(i).name), y+c*18, "  >"
            inc c
        endif
    next i
    `ink rgb(255,255,0),0
    `if c = 0 then text x, y, "<empty list>"
endfunction

REM ***********************************************
REM Add menu items into the menu system
REM 'name' menu item name (this is what gets displayed)
REM 'parentId' what
REM ***********************************************
function insertMenuItem(name as string, parentId as integer)
    array insert at bottom menuItems()
    n = array count(menuItems())
    menuItems(n).name = name
    menuItems(n).parentId = parentId
endfunction n

+ Code Snippet

REM ********************************************
REM Title: Menu System
REM Author: Phaelax
REM Created: Tuesday, October 30, 2012
REM ********************************************

Type MenuItem
    parentId as integer
    name as string
    isSelected as integer
EndType

dim menuItems() as MenuItem

Global currentMenu = 0
Global lastMenu = 0


rootId = insertMenuItem("root", -1)
insertMenuItem("New", rootId)
insertMenuItem("Open", rootId)
insertMenuItem("Save", rootId)
settingsId = insertMenuItem("Settings", rootId)
insertMenuItem("Exit", rootId)

insertMenuItem("Customize", settingsId)
insertMenuItem("Options", settingsId)
insertMenuItem("Plugins", settingsId)


currentMenu = rootId
selectFirstItem(currentMenu)
selectedItem = -1


do
    cls

    if upkey() = 1 and vkFlag = 0
        vkFlag = 1
        selectPrevious(currentMenu)
    endif
    
    if downkey() = 1 and vkFlag = 0
        vkFlag = 1
        selectNext(currentMenu)
    endif
    
    if rightkey() and vkFlag = 0
        currentMenu = openSubMenu(currentMenu)
        vkFlag = 1
    endif
    
    if leftkey() and vkFlag = 0
        vkFlag = 1
        currentMenu = openParentMenu(currentMenu)
    endif
    
    if returnkey() and vkFlag = 0
        vkFlag = 1
        selectedItem = getSelectedItem(currentMenu)
    endif
    
    rem reset key flag
    if upkey() + downkey() + rightkey() + leftkey() + returnkey() = 0 then vkFlag = 0
    
    
    rem display menu
    displayMenu(currentMenu, 100, 120)
    
    
    print "'",getMenuItemName$(selectedItem), "' is currently active."
loop


REM ***********************************************
REM Returns the name of the menu item
REM ***********************************************
function getMenuItemName$(menuItemId)
    if menuItemId > -1
        s$ = menuItems(menuItemId).name
    else
        s$ = "Invalid Menu Item ID"
    endif
endfunction s$


REM ***********************************************
REM Go up one level in the menu hierarchy
REM ***********************************************
function openParentMenu(menuItemId)
    pid = getParentId(menuItemId)
    if pid = -1
        pid = menuItemId
    else
        id = getSelectedItem(menuItemId)
        if id > -1 then menuItems(id).isSelected = 0
    endif
endfunction pid


REM ***********************************************
REM Go one level deeper in the menu hierarchy
REM ***********************************************
function openSubMenu(menuItemId)
    count = getChildCount(getSelectedItem(menuItemId))
    if count > 0
        lastMenu = menuItemId
        menuItemId = getSelectedItem(menuItemId)
        selectFirstItem(menuItemId)
    endif
endfunction menuItemId


REM ***********************************************
REM Return the menu item ID to which this item
REM belongs to
REM ***********************************************
function getParentId(menuItemId)
    pid = menuItems(menuItemId).parentId
endfunction pid


REM ***********************************************
REM Returns number of menu items that belong to
REM this one
REM ***********************************************
function getChildCount(menuItemId)
    c = 0
    for i = 0 to array count(menuItems())
        if menuItems(i).parentId = menuItemId then inc c
    next i
endfunction c


REM ***********************************************
REM Selects/highlights first item in the current
REM menu
REM ***********************************************
function selectFirstItem(menuItemId)
    for i = 0 to array count(menuItems())
        if menuItems(i).parentId = menuItemId then menuItems(i).isSelected = 1 : exitfunction
    next i
endfunction


REM ***********************************************
REM Selects/highlights the previous menu item. If  
REM the currently selected item is the first one,
REM if will wrap around to the end.
REM ***********************************************
function selectPrevious(menuItemId)
    if getChildCount(menuItemId) = 0 then exitfunction
    
    previousId = -1
    currentlySelected = -1
    for i = 0 to array count(menuItems())
        if menuItems(i).parentId = menuItemId
            if menuItems(i).isSelected = 0
                previousId = i
            else
                if previousId > -1
                    menuItems(i).isSelected = 0
                    menuItems(previousId).isSelected = 1
                    exitfunction previousId
                endif
                currentlySelected = i
            endif
        endif
    next i
    
    if previousId > -1
        menuItems(previousId).isSelected = 1
        menuItems(currentlySelected).isSelected = 0
    endif
endfunction previousId


REM ***********************************************
REM Selects/highlights the next menu item. If the 
REM currently selected item is the last one, it
REM will wrap around to the beginning.
REM ***********************************************
function selectNext(menuItemId)
    if getChildCount(menuItemId) = 0 then exitfunction
    
    firstItemId = -1
    currentlySelected = -1
    newSelectedId = -1
    for i = 0 to array count(menuItems())
        if menuItems(i).parentId = menuItemId
            if firstItemId = -1 then firstItemId = i
            if currentlySelected > -1
                newSelectedId = i
                menuItems(currentlySelected).isSelected = 0
                menuItems(newSelectedId).isSelected = 1
                exitfunction newSelectedId
            endif
            if menuItems(i).isSelected then currentlySelected = i
        endif
    next i
    if newSelectedId = -1
        menuItems(currentlySelected).isSelected = 0
        menuItems(firstItemId).isSelected = 1
    endif
endfunction firstItemId


REM ***********************************************
REM Returns the menu item id of the currently
REM selected menu item
REM ***********************************************
function getSelectedItem(menuItemId)
    for i = 0 to array count(menuItems())
        if menuItems(i).parentId = menuItemId
            if menuItems(i).isSelected then exitfunction i
        endif
    next i
endfunction -1


REM ***********************************************
REM Draws the menu, one level deep at a time.
REM
REM Improvements:
REM Ideally, the system should keep track to number
REM of children upon insertion and not have to 
REM recalculate that number each time it is needed.
REM On a large, extensively complex menu array, 
REM this could cause a performance hit and is quite
REM inefficient.
REM ***********************************************
function displayMenu(menuItemId, x, y)
    c = 0
    for i = 0 to array count(menuItems())
        if menuItems(i).parentId = menuItemId
            if menuItems(i).isSelected
                ink rgb(255,255,0),0
            else
                ink rgb(255,255,255),0
            endif
            text x, y+c*18, menuItems(i).name
            if getChildCount(i) > 0 then text x+text width(menuItems(i).name), y+c*18, "  >"
            inc c
        endif
    next i
    `ink rgb(255,255,0),0
    `if c = 0 then text x, y, "<empty list>"
endfunction


REM ***********************************************
REM Add menu items into the menu system
REM 'name' menu item name (this is what gets displayed)
REM 'parentId' what
REM ***********************************************
function insertMenuItem(name as string, parentId as integer)
    array insert at bottom menuItems()
    n = array count(menuItems())
    menuItems(n).name = name
    menuItems(n).parentId = parentId
endfunction n

"You're not going crazy. You're going sane in a crazy world!" ~Tick

Back to top

Profile PM Email Website

Mr909

11

Years of Service

User Offline

Joined: 2nd Jun 2012

Location:

Posted: 30th Oct 2012 19:16

Link

No, by all means, it's great to see someone with a better approach, and great that the snippet is publicly available.

You gonna attach a license if I use that commercially? You wanna give me some payment info? I'm scrapping my old code.

Back to top

Profile PM Email

Mr909

11

Years of Service

User Offline

Joined: 2nd Jun 2012

Location:

Posted: 31st Oct 2012 00:30

Link

Huh, after playing around with it, I did notice one thing that confused me:

Why is isSelected casted as an integer? Surely it shouldn't ever be anything other than 0 or 1?

Back to top

Profile PM Email

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 31st Oct 2012 03:06

Link

You're right, isSelected should probably be a boolean. And the code is free public domain.

Also, you might want to think about showing some kind of transition between the menus. It'll help users know whats going on better than just flipping immediately between one menu and the next.

Here's an example:
http://forum.thegamecreators.com/?m=forum_view&t=183122&b=6

Now that code would need a major rewrite to work with the code I've posted above, but you get the idea.

"You're not going crazy. You're going sane in a crazy world!" ~Tick

Back to top

Profile PM Email Website

Mr909

11

Years of Service

User Offline

Joined: 2nd Jun 2012

Location:

Posted: 31st Oct 2012 22:21

Link

Okay, I thought so. Thanks very much, and if it does come down to it and I'm in a position to turn a profit, I will definitely credit you.

Yeah, I get it. I might design something like that, but some of the best RPGs there ever was don't really have noticeable transition effects.

Back to top

Profile PM Email

Duffer

21

Years of Service

User Offline

Joined: 9th Feb 2003

Location: chair

Posted: 2nd Nov 2012 10:35 Edited at: 2nd Nov 2012 10:50

Link

@ Phaelax,

Thanks for this code - presumably much of it can be hacked out and used in a nodetree type application?

[edit]

Looking at deleting items as well (and a function for that) how then do you keep track of the various items/nodes ids?

What if you actually then go an sort the array?

a long time dabbler with DBC and DBPro with no actual talent but lots of enthusiasm...

Back to top

Profile PM Email

Mr909

11

Years of Service

User Offline

Joined: 2nd Jun 2012

Location:

Posted: 2nd Nov 2012 19:50

Link

What I did is get the name of the selected item and match it against your target. I thought that was a little iffy too. If you wanted, you could easily just add a variable ID to the type and check that for the selected ID instead.

Back to top

Profile PM Email

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 3rd Nov 2012 03:17

Link

To delete items, simply remove it from the array. First you should check if it has any child nodes. If it does, either prevent the deletion or delete the children with it.

Obviously, if you remove an element from the middle of the array, everything shifts down and suddenly the indices become meaningless. So we'll refactor the array manually before removing the element.

I believe this should work, however I have not tested it. Of the two functions the only one you need to call is removeMenuItem().

REM ***********************************************
REM Removes a menu item. The flag tells it whether 
REM it should remove children or not. If set to 1, 
REM the menu item will be delete and any child nodes
REM that belong to it. If the flag is set to 0, the
REM menu item will only be deleted if it has no 
REM children. Functions returns 1 for success, 0 if
REM no deletion occurred.
REM ***********************************************
function removeMenuItem(menuItemId, childFlag)
    `array delete element menuItems(), menuItemId
    `children = 0
    `n = array count(menuItems())
    `for i = 1 to n
    `    if menuItems(i).parentId = menuItemId then inc children
    `next i
    
    n = array count(menuItems())
    
    if getChildCount(menuItemId) = 0
        menuItemMoveBottom(menuItemId)
        array delete element menuItems(), n
        
    else
        if childFlag = 0
            rem There are children, but flag set not to delete children.
            rem Cancel function, delete failed
            exitfunction 0
        else
            rem There are children and flag set to delete all children
            rem Loop through all nodes and delete children (and their children)
            for i = 1 to array count(menuItems())
                if menuItems(i).parentId = menuItemId
                    removeMenuItem(i, 1)
                endif
            next i
        endif
    endif

endfunction 1

REM ***********************************************
REM This will move the menu item at the bottom of
REM array list to the specified index, overwriting
REM the menu item currently in place there. It will
REM refactor all other menu items to update with
REM the new index.
REM ***********************************************
function menuItemMoveBottom(menuItemId)
    n = array count(menuItems())
    
    for i = 1 to n-1
        if menuItems(i).parentId = n then menuItems(i).parentId = menuItemId
    next i
    
    menuItems(menuItemId) = menuItems(n)
endfunction

+ Code Snippet

REM ***********************************************
REM Removes a menu item. The flag tells it whether 
REM it should remove children or not. If set to 1, 
REM the menu item will be delete and any child nodes
REM that belong to it. If the flag is set to 0, the
REM menu item will only be deleted if it has no 
REM children. Functions returns 1 for success, 0 if
REM no deletion occurred.
REM ***********************************************
function removeMenuItem(menuItemId, childFlag)
    `array delete element menuItems(), menuItemId
    `children = 0
    `n = array count(menuItems())
    `for i = 1 to n
    `    if menuItems(i).parentId = menuItemId then inc children
    `next i
    
    n = array count(menuItems())
    
    if getChildCount(menuItemId) = 0
        menuItemMoveBottom(menuItemId)
        array delete element menuItems(), n
        
    else
        if childFlag = 0
            rem There are children, but flag set not to delete children.
            rem Cancel function, delete failed
            exitfunction 0
        else
            rem There are children and flag set to delete all children
            rem Loop through all nodes and delete children (and their children)
            for i = 1 to array count(menuItems())
                if menuItems(i).parentId = menuItemId
                    removeMenuItem(i, 1)
                endif
            next i
        endif
    endif

endfunction 1


REM ***********************************************
REM This will move the menu item at the bottom of
REM array list to the specified index, overwriting
REM the menu item currently in place there. It will
REM refactor all other menu items to update with
REM the new index.
REM ***********************************************
function menuItemMoveBottom(menuItemId)
    n = array count(menuItems())
    
    for i = 1 to n-1
        if menuItems(i).parentId = n then menuItems(i).parentId = menuItemId
    next i
    
    menuItems(menuItemId) = menuItems(n)
endfunction

"You're not going crazy. You're going sane in a crazy world!" ~Tick

Back to top

Profile PM Email Website

Duffer

21

Years of Service

User Offline

Joined: 9th Feb 2003

Location: chair

Posted: 11th Nov 2012 17:04

Link

@ Phaelax & Mr909,

Hope you both follow this. My solution is, I hope, simple. Put the path of the node (ie. items/weapons/swords/claymore) in the name of each node in an array and, voila, you can sort or reverse sort.

Also, you can easily parse the nodes to delete all children and grandchildren nodes etc and everything else holds it's structure - the structure is in the name of the nodes (with path) themselves...

a long time dabbler with DBC and DBPro with no actual talent but lots of enthusiasm...

Back to top

Profile PM Email

Sorry your browser is not supported!

Code Snippets / [DBP] - Simple RPG Branching Menu