I am using Qt Creator as my primary IDE and have hard time using anything else. Luckily it is not too hard convincing Qt Creator it to work with AGK.
If you are interested here are the steps (on Windows system):
1) Make new project -> Non-Qt project -> Plain c++ Application .
2) Copy code files (template.h, template.cpp, Core.cpp, resource.h) from your "AGK/Tier 2/apps/..." template directory to your project directory. Of course, the VS compiler version must match the one set in QT Creator. Delete "main.cpp" which was automatically added by Qt Creator.
3)) In Qt Creator open the project ".pro" file. Clear everything and paste this code:
CONFIG -= qt
CONFIG(release, debug|release) {
#release build
DEFINES += NDEBUG
} else {
#debug build
DEFINES += _DEBUG
}
win32 {
DEFINES += _WINDOWS AGK_WINDOWS
LIBS += -lopengl32
LIBS += -luser32
LIBS += -lkernel32
LIBS += -lgdi32
LIBS += -lwinspool
LIBS += -lcomdlg32
LIBS += -ladvapi32
LIBS += -lshell32
LIBS += -lole32
LIBS += -loleaut32
LIBS += -luuid
LIBS += -lodbc32
LIBS += -lodbccp32
CONFIG(release, debug|release) {
#release build
LIBS += "C:/Development/AGK/Tier 2/platform/windows/Lib/VS2017/Release64/AGKWindows64.lib"
INCLUDEPATH += "C:/Development/AGK/Tier 2/platform/windows/Lib/VS2017/Release64"
DEPENDPATH += "C:/Development/AGK/Tier 2/platform/windows/Lib/VS2017/Release64"
QMAKE_CXXFLAGS_RELEASE -= -MD
QMAKE_CXXFLAGS_RELEASE += -MT
} else {
#debug build
LIBS += "C:/Development/AGK/Tier 2/platform/windows/Lib/VS2017/Debug64/AGKWindows64.lib"
INCLUDEPATH += "C:/Development/AGK/Tier 2/platform/windows/Lib/VS2017/Debug64"
DEPENDPATH += "C:/Development/AGK/Tier 2/platform/windows/Lib/VS2017/Debug64"
QMAKE_CXXFLAGS_DEBUG -= -MDd
QMAKE_CXXFLAGS_DEBUG += -MTd
}
}
INCLUDEPATH += "C:/Development/AGK/Tier 2/common"
INCLUDEPATH += "C:/Development/AGK/Tier 2/common/include"
INCLUDEPATH += "C:/Development/AGK/Tier 2/bullet"
INCLUDEPATH += "C:/Development/AGK/Tier 2/bullet/BulletCollision/CollisionShapes"
SOURCES += \
template.cpp \
Core.cpp
HEADERS += \
template.h \
resource.h
Change the paths to match your AppGameKit paths!
Run qmake (Build->Run qmake), rebuild the project and it should compile.
