3D world - 2D Mouse - GameCreators Forum

Author

Message

jotomicron

21

Years of Service

User Offline

Joined: 17th Nov 2002

Location: Portugal

Posted: 25th Nov 2002 21:05

Link

Hi!

Does anyone has a code that let me convert 2D coordenates (in the mouse) to 3D coordenates. Some explaining would be greatfull!

Thanx

Back to top

Profile PM

TGWDNGHN

21

Years of Service

User Offline

Joined: 2nd Oct 2002

Location:

Posted: 27th Nov 2002 19:57

Link

you can use the mousey cordinate to move an object in the z

x=y or z, y-x or z, and once you have z you cvan do z-x or y

, put all your Qs in one post

If life gives you a lemon, shove it up a water gun and squirt it into someone's eyes!

Back to top

Profile PM Email

jotomicron

21

Years of Service

User Offline

Joined: 17th Nov 2002

Location: Portugal

Posted: 27th Nov 2002 20:54

Link

Ok! Some time ago i find this code:

SYNC ON
SYNC RATE 0

ScWidth# = 1024
ScHeight# = 768

SET DISPLAY MODE ScWidth#,ScHeight#,16

AUTOCAM OFF
SET CAMERA RANGE 1,100000

RED = RGB(255,0,0)
BLUE = RGB(0,0,255)

MAKE OBJECT PLAIN 2,1000,1000
XROTATE OBJECT 2,90
COLOR OBJECT 2,BLUE

`THIS MAKES AND HIDES THE CLICK POINT OBJECT
MAKE OBJECT CUBE 1,20
HIDE OBJECT 1
POSITION OBJECT 1,0,0,0

MAKE OBJECT CONE 3,30
POSITION OBJECT 3,0,0,0
XROTATE OBJECT 3,90
FIX OBJECT PIVOT 3
COLOR OBJECT 3,RED

`VARIABLES THAT NEED TO BE SET
WPX# = 0
WPZ# = 0
CamPosAdj = 1
CamRotAdj = 1
CamDistance# = 500
XcamL# = 30
YcamL# = 0
CamRotInc# = 1
ZoomInc# = 3
ZoomINmax# = 50
ZoomOUTmax# = 1500
SCROLLspeed# = 5

`Figure out Angle to Top of Screen depending on Resolution
`----------------------------------------------------------
ScRefL1# = ATAN(ScWidth# / ScHeight#)
ScRefDist1# = CamDistance# * COS(ScRefL1#)
YscreenMAXl# = ATAN(ScRefDist1# / CamDistance#)
`--------------------

POSITION MOUSE 400,300

`----------------------------------------------------------
`THIS STARTS THE MAIN LOOP
`----------------------------------------------------------
DO
`-------------------------------------
`THIS IS FOR CAMERA POSITIONING
`-------------------------------------
IF CamPosAdj = 1
SINofXcamL# = SIN(XcamL#)
CamY# = CamDistance# * SINofXcamL#
CamLEGsq# = (CamDistance# * CamDistance#) - (CamY# * CamY#)
CamLEG# = SQRT(CamLEGsq#)
Xcam# = CamLEG# * SIN(YcamL#)
Zcam# = CamLEG# * COS(YcamL#)
POSITION CAMERA WPX# - Xcam#,CamY#,WPZ# - Zcam#

CamPosAdj = 0
ENDIF

`----------------------------------------------------------
`THIS IS FOR CAMERA ROTATION
`----------------------------------------------------------
IF CamRotAdj = 1
XROTATE CAMERA XcamL#
YROTATE CAMERA YcamL#
CamRotAdj = 0
ENDIF

`----------------------------------------------------------
`THIS IS FOR MOUSE SCROLLING
`----------------------------------------------------------
IF MouseY() < 20 OR MouseY() > (ScHeight# - 20) OR MouseX() < 20 OR MouseX() > (ScWidth# - 20)
Xscroll# = ScrollSpeed# * SIN(YcamL#)
Zscroll# = ScrollSpeed# * COS(YcamL#)

IF MouseY() < 20
WPX# = WPX# + Xscroll#
WPZ# = WPZ# + Zscroll#
ENDIF

IF MouseY() > 580
WPX# = WPX# - Xscroll#
WPZ# = WPZ# - Zscroll#
ENDIF

IF MouseX() < 20
WPX# = WPX# - Zscroll#
WPZ# = WPZ# + Xscroll#
ENDIF

IF MouseX() > 780
WPX# = WPX# + Zscroll#
WPZ# = WPZ# - Xscroll#
ENDIF

CamPosAdj = 1
CamRotAdj = 1
ENDIF

`----------------------------------------------------------
`THIS MONITORS FOR DIFFERENT KEYPRESSES
`----------------------------------------------------------
KEYPRESS$ = INKEY$()

`----------------------------------------------------------
`THIS USES THE UPKEY TO REDUCE THE CAMERAS X ROTATION
`----------------------------------------------------------
IF UPKEY() = 1
XcamL# = XcamL# - CamRotInc#
IF XcamL# < 1
XcamL# = 1
ENDIF
CamPosAdj = 1
CamRotAdj = 1
ENDIF

`----------------------------------------------------------
`THIS USES THE DOWNKEY TO INCREASE THE CAMERAS X ROTATION
`----------------------------------------------------------
IF DOWNKEY() = 1
XcamL# = XcamL# + CamRotInc#
IF XcamL# > 90
XcamL# = 90
ENDIF
CamPosAdj = 1
CamRotAdj = 1
ENDIF

`----------------------------------------------------------
`THIS USES THE LEFTKEY TO DECREASE THE CAMERAS Y ROTATION
`----------------------------------------------------------
IF LEFTKEY() = 1
YcamL# = YcamL# - CamRotInc#
IF YcamL# < 0
YcamL# = 359
ENDIF
CamPosAdj = 1
CamRotAdj = 1
ENDIF

`----------------------------------------------------------
`THIS USES THE RIGHTKEY TO DECREASE THE CAMERAS Y ROTATION
`----------------------------------------------------------
IF RIGHTKEY() = 1
YcamL# = YcamL# + CamRotInc#
IF YcamL# > 359
YcamL# = 0
ENDIF
CamPosAdj = 1
CamRotAdj = 1
ENDIF

`----------------------------------------------------------
`THIS USES THE "+" KEY TO ZOOM IN
`----------------------------------------------------------
IF KEYPRESS$ = "+"
CamDistance# = CamDistance# - ZoomInc#
IF CamDistance# < ZoomINmax#
CamDistance# = ZoomINmax#
ENDIF
CamPosAdj = 1
CamRotAdj = 1
ENDIF

`----------------------------------------------------------
`THIS USES THE "-" KEY TO ZOOM OUT
`----------------------------------------------------------
IF KEYPRESS$ = "-"
CamDistance# = CamDistance# + ZoomInc#
IF CamDistance# > ZoomOUTmax#
CamDistance# = ZoomOUTmax#
ENDIF
CamPosAdj = 1
CamRotAdj = 1
ENDIF
`----------------------------------------------------------

`TO CONVERT 2D MOUSECLICKS INTO 3D SPACE

IF MOUSECLICK() = 1

MoX = MOUSEX()
MoY = MOUSEY()

ViewLowLegL# = 90 - XcamL# - YscreenMAXl#
COSvLLL# = COS(ViewLowLegL#)
ViewLegDist# = CamY# / COSvLLL#
SINyScreenMaxL# = SIN(YscreenMAXl#)
ScreenHeight# = ViewLegDist# * SINyScreenMaxL#
ScreenDistSQ# = (ViewLegDist# * ViewLegDist#) - (ScreenHeight# * ScreenHeight#)
ScreenDist# = SQRT(ScreenDistSQ#)
YScreenFactor# = ScreenHeight# / (ScHeight# / 2)

`THIS GETS A 2D Y-DISTANCE FROM CENTER
IF MoY < (ScHeight# / 2)
YmoDist# = (ScHeight# / 2) - MoY
ENDIF
IF MoY >= (ScHeight# / 2)
YmoDist# = ((ScHeight# / 2) - 1) - MoY
ENDIF

IF YmoDist# > 0
SceenViewDistY# = YmoDist# * YScreenFactor#
YPointL2# = ATAN(SceenViewDistY# / ScreenDist#)
YPointL# = ViewLowLegL# + YscreenMAXl# + YPointL2#
YPosLEG# = CamY# * TAN(YPointL#)
ENDIF

IF YmoDist# < 0
SceenViewDistY# = YmoDist# * YScreenFactor# * -1
YPointL2# = ATAN(SceenViewDistY# / ScreenDist#)
YPointL# = ViewLowLegL# + YscreenMAXl# - YPointL2#
YPosLEG# = CamY# * TAN(YPointL#)
ENDIF

`THIS GETS A 2D X-DISTANCE FROM CENTER
IF MoX < (ScWidth# / 2)
XmoDist# = ((ScWidth# / 2) * -1) + MoX
ENDIF

IF MoX >= (ScWidth# / 2)
XmoDist# = (((ScWidth# / 2) - 1) * -1) + MoX
ENDIF

`HANDLE MoY FIRST
threeDYdist# = YmoDist# * YScreenFactor#
SINofvLLL# = SIN(ViewLowLegL#)
ViewBotLeg# = ViewLegDist# * SINofvLLL#
Ydist1L# = 90 - XcamL#
YposLEG# = YposLEG# - CamLEG#

`HANDLE MoX
ScreenWidth# = ScreenHeight# / (ScHeight# / ScWidth#)
DistTOScreen# = ScreenDist# / COS(YPointL2#)
XAngle# = ATAN(ScreenWidth# / DistTOScreen#)
ViewLegY_c# = CamY# / COS(YPointL#)
ViewXwidth# = ViewLegY_c# * TAN(XAngle#)
XScreenFactor# = ViewXwidth# / (ScWidth# / 2)
XposLEG# = XmoDist# * XScreenFactor#

ClickPosL2# = ATAN(XposLEG# / YposLEG#)
ClickPosL# = WRAPVALUE(YcamL# + ClickPosL2#)
ClickPos_c# = YposLEG# / COS(ClickPosL2#)
ZclickPos# = ClickPos_c# * COS(ClickPosL#)
XclickPos# = ClickPos_c# * SIN(ClickPosL#)

Xclick# = XclickPos# + WPX#
Zclick# = ZclickPos# + WPZ#

POSITION OBJECT 1,Xclick#,0,Zclick#
CamPosAdj = 1
CamRotAdj = 1

`MOVE SELECTED OBJECT
POINT OBJECT 3,Xclick#,0,Zclick#
ObjPosX# = OBJECT POSITION X(3)
ObjPosZ# = OBJECT POSITION Z(3)
IF ObjPosX# <> Xclick# OR ObjPosZ# <> Zclick#
DBX# = Xclick# - ObjPosX#
DBZ# = Zclick# - ObjPosZ#
DistanceBetween# = SQRT(DBX# * DBX# + DBZ# * DBZ#)
IF DistanceBetween# <= 5
MOVE OBJECT 3,DistanceBetween#
ENDIF
IF DistanceBetween# > 5
MOVE OBJECT 3,5
ENDIF
ENDIF
ENDIF

`----------------------------------------------------------

FPS=SCREEN FPS()
SET CURSOR 0,0
PRINT FPS

SYNC
LOOP

+ Code Snippet

SYNC ON
SYNC RATE 0

ScWidth# = 1024
ScHeight# = 768

SET DISPLAY MODE ScWidth#,ScHeight#,16

AUTOCAM OFF
SET CAMERA RANGE 1,100000

RED = RGB(255,0,0)
BLUE = RGB(0,0,255)

MAKE OBJECT PLAIN 2,1000,1000
XROTATE OBJECT 2,90
COLOR OBJECT 2,BLUE

`THIS MAKES AND HIDES THE CLICK POINT OBJECT
MAKE OBJECT CUBE 1,20
HIDE OBJECT 1
POSITION OBJECT 1,0,0,0

MAKE OBJECT CONE 3,30
POSITION OBJECT 3,0,0,0
XROTATE OBJECT 3,90
FIX OBJECT PIVOT 3
COLOR OBJECT 3,RED

`VARIABLES THAT NEED TO BE SET
WPX# = 0
WPZ# = 0
CamPosAdj = 1
CamRotAdj = 1
CamDistance# = 500
XcamL# = 30
YcamL# = 0
CamRotInc# = 1
ZoomInc# = 3
ZoomINmax# = 50
ZoomOUTmax# = 1500
SCROLLspeed# = 5


`Figure out Angle to Top of Screen depending on Resolution
`----------------------------------------------------------
ScRefL1# = ATAN(ScWidth# / ScHeight#)
ScRefDist1# = CamDistance# * COS(ScRefL1#)
YscreenMAXl# = ATAN(ScRefDist1# / CamDistance#)
`--------------------

POSITION MOUSE 400,300

`----------------------------------------------------------
`THIS STARTS THE MAIN LOOP
`----------------------------------------------------------
DO
`-------------------------------------
`THIS IS FOR CAMERA POSITIONING
`-------------------------------------
IF CamPosAdj = 1
SINofXcamL# = SIN(XcamL#)
CamY# = CamDistance# * SINofXcamL#
CamLEGsq# = (CamDistance# * CamDistance#) - (CamY# * CamY#)
CamLEG# = SQRT(CamLEGsq#)
Xcam# = CamLEG# * SIN(YcamL#)
Zcam# = CamLEG# * COS(YcamL#)
POSITION CAMERA WPX# - Xcam#,CamY#,WPZ# - Zcam#

CamPosAdj = 0
ENDIF

`----------------------------------------------------------
`THIS IS FOR CAMERA ROTATION
`----------------------------------------------------------
IF CamRotAdj = 1
XROTATE CAMERA XcamL#
YROTATE CAMERA YcamL#
CamRotAdj = 0
ENDIF

`----------------------------------------------------------
`THIS IS FOR MOUSE SCROLLING
`----------------------------------------------------------
IF MouseY() < 20 OR MouseY() > (ScHeight# - 20) OR MouseX() < 20 OR MouseX() > (ScWidth# - 20)
Xscroll# = ScrollSpeed# * SIN(YcamL#)
Zscroll# = ScrollSpeed# * COS(YcamL#)

IF MouseY() < 20
WPX# = WPX# + Xscroll#
WPZ# = WPZ# + Zscroll#
ENDIF

IF MouseY() > 580
WPX# = WPX# - Xscroll#
WPZ# = WPZ# - Zscroll#
ENDIF

IF MouseX() < 20
WPX# = WPX# - Zscroll#
WPZ# = WPZ# + Xscroll#
ENDIF

IF MouseX() > 780
WPX# = WPX# + Zscroll#
WPZ# = WPZ# - Xscroll#
ENDIF

CamPosAdj = 1
CamRotAdj = 1
ENDIF

`----------------------------------------------------------
`THIS MONITORS FOR DIFFERENT KEYPRESSES
`----------------------------------------------------------
KEYPRESS$ = INKEY$()

`----------------------------------------------------------
`THIS USES THE UPKEY TO REDUCE THE CAMERAS X ROTATION
`----------------------------------------------------------
IF UPKEY() = 1
XcamL# = XcamL# - CamRotInc#
IF XcamL# < 1
XcamL# = 1
ENDIF
CamPosAdj = 1
CamRotAdj = 1
ENDIF

`----------------------------------------------------------
`THIS USES THE DOWNKEY TO INCREASE THE CAMERAS X ROTATION
`----------------------------------------------------------
IF DOWNKEY() = 1
XcamL# = XcamL# + CamRotInc#
IF XcamL# > 90
XcamL# = 90
ENDIF
CamPosAdj = 1
CamRotAdj = 1
ENDIF

`----------------------------------------------------------
`THIS USES THE LEFTKEY TO DECREASE THE CAMERAS Y ROTATION
`----------------------------------------------------------
IF LEFTKEY() = 1
YcamL# = YcamL# - CamRotInc#
IF YcamL# < 0
YcamL# = 359
ENDIF
CamPosAdj = 1
CamRotAdj = 1
ENDIF

`----------------------------------------------------------
`THIS USES THE RIGHTKEY TO DECREASE THE CAMERAS Y ROTATION
`----------------------------------------------------------
IF RIGHTKEY() = 1
YcamL# = YcamL# + CamRotInc#
IF YcamL# > 359
YcamL# = 0
ENDIF
CamPosAdj = 1
CamRotAdj = 1
ENDIF

`----------------------------------------------------------
`THIS USES THE "+" KEY TO ZOOM IN
`----------------------------------------------------------
IF KEYPRESS$ = "+"
CamDistance# = CamDistance# - ZoomInc#
IF CamDistance# < ZoomINmax#
CamDistance# = ZoomINmax#
ENDIF
CamPosAdj = 1
CamRotAdj = 1
ENDIF

`----------------------------------------------------------
`THIS USES THE "-" KEY TO ZOOM OUT
`----------------------------------------------------------
IF KEYPRESS$ = "-"
CamDistance# = CamDistance# + ZoomInc#
IF CamDistance# > ZoomOUTmax#
CamDistance# = ZoomOUTmax#
ENDIF
CamPosAdj = 1
CamRotAdj = 1
ENDIF
`----------------------------------------------------------

`TO CONVERT 2D MOUSECLICKS INTO 3D SPACE

IF MOUSECLICK() = 1

MoX = MOUSEX()
MoY = MOUSEY()

ViewLowLegL# = 90 - XcamL# - YscreenMAXl#
COSvLLL# = COS(ViewLowLegL#)
ViewLegDist# = CamY# / COSvLLL#
SINyScreenMaxL# = SIN(YscreenMAXl#)
ScreenHeight# = ViewLegDist# * SINyScreenMaxL#
ScreenDistSQ# = (ViewLegDist# * ViewLegDist#) - (ScreenHeight# * ScreenHeight#)
ScreenDist# = SQRT(ScreenDistSQ#)
YScreenFactor# = ScreenHeight# / (ScHeight# / 2)

`THIS GETS A 2D Y-DISTANCE FROM CENTER
IF MoY < (ScHeight# / 2)
YmoDist# = (ScHeight# / 2) - MoY
ENDIF
IF MoY >= (ScHeight# / 2)
YmoDist# = ((ScHeight# / 2) - 1) - MoY
ENDIF

IF YmoDist# > 0
SceenViewDistY# = YmoDist# * YScreenFactor#
YPointL2# = ATAN(SceenViewDistY# / ScreenDist#)
YPointL# = ViewLowLegL# + YscreenMAXl# + YPointL2#
YPosLEG# = CamY# * TAN(YPointL#)
ENDIF

IF YmoDist# < 0
SceenViewDistY# = YmoDist# * YScreenFactor# * -1
YPointL2# = ATAN(SceenViewDistY# / ScreenDist#)
YPointL# = ViewLowLegL# + YscreenMAXl# - YPointL2#
YPosLEG# = CamY# * TAN(YPointL#)
ENDIF

`THIS GETS A 2D X-DISTANCE FROM CENTER
IF MoX < (ScWidth# / 2)
XmoDist# = ((ScWidth# / 2) * -1) + MoX
ENDIF

IF MoX >= (ScWidth# / 2)
XmoDist# = (((ScWidth# / 2) - 1) * -1) + MoX
ENDIF

`HANDLE MoY FIRST
threeDYdist# = YmoDist# * YScreenFactor#
SINofvLLL# = SIN(ViewLowLegL#)
ViewBotLeg# = ViewLegDist# * SINofvLLL#
Ydist1L# = 90 - XcamL#
YposLEG# = YposLEG# - CamLEG#

`HANDLE MoX
ScreenWidth# = ScreenHeight# / (ScHeight# / ScWidth#)
DistTOScreen# = ScreenDist# / COS(YPointL2#)
XAngle# = ATAN(ScreenWidth# / DistTOScreen#)
ViewLegY_c# = CamY# / COS(YPointL#)
ViewXwidth# = ViewLegY_c# * TAN(XAngle#)
XScreenFactor# = ViewXwidth# / (ScWidth# / 2)
XposLEG# = XmoDist# * XScreenFactor#

ClickPosL2# = ATAN(XposLEG# / YposLEG#)
ClickPosL# = WRAPVALUE(YcamL# + ClickPosL2#)
ClickPos_c# = YposLEG# / COS(ClickPosL2#)
ZclickPos# = ClickPos_c# * COS(ClickPosL#)
XclickPos# = ClickPos_c# * SIN(ClickPosL#)

Xclick# = XclickPos# + WPX#
Zclick# = ZclickPos# + WPZ#

POSITION OBJECT 1,Xclick#,0,Zclick#
CamPosAdj = 1
CamRotAdj = 1

`MOVE SELECTED OBJECT
POINT OBJECT 3,Xclick#,0,Zclick#
ObjPosX# = OBJECT POSITION X(3)
ObjPosZ# = OBJECT POSITION Z(3)
IF ObjPosX# <> Xclick# OR ObjPosZ# <> Zclick#
DBX# = Xclick# - ObjPosX#
DBZ# = Zclick# - ObjPosZ#
DistanceBetween# = SQRT(DBX# * DBX# + DBZ# * DBZ#)
IF DistanceBetween# <= 5
MOVE OBJECT 3,DistanceBetween#
ENDIF
IF DistanceBetween# > 5
MOVE OBJECT 3,5
ENDIF
ENDIF
ENDIF

`----------------------------------------------------------

FPS=SCREEN FPS()
SET CURSOR 0,0
PRINT FPS

SYNC
LOOP

I use it, but I can't figure out why does it work! Could somebody try to explain it to me?

Thanx!

Back to top

Profile PM

Fluffy Paul

21

Years of Service

User Offline

Joined: 16th Dec 2002

Location: United Kingdom

Posted: 26th Dec 2002 23:47

Link

OK, here we go.
The writer uses the angle the camera is pointing in as the basis for the calculation. This means that if you click in the exact centre of the screen then you'll select whatever the camera is pointing at. The maths is used to work out what happens depending how far away from the centre of the screen you clicked.

The first thing to remember is that the screen represents a field of view in the 3D world. Have you played Commando's by Pyro Studios/Eidos Interactive? Or how about Metal Gear Solid?
In those games the enemy's field of view was shown to the player as part of the game. Imagine you are a human player controlling one of those enemies. Anything in that field of view appears on your screen. Things on the left of your FOV appear on the left of your screen and things in the right of your FOV appear in the right of your screen.

The FOV is described as an angle. 90 degrees is pretty much a standard FOV. Remember that, what ever the FOV, the number of degrees describes everything you see from the left hand side of your screen to the right hand side.

Returning to the code snippet we see that the author has based their calculations on the direction of the camera.
Assuming the FOV in this case is still 90 degrees, this means that something visible on the left of the screen can be up to 45 degrees to the left of the camera. Likewise, something on the rightmost edge of the screen would be 45 degrees to the right of the camera.

What the code author does is say "OK, the field of view is 90 degrees but my screen is 1024 pixels wide. This means that each pixel is 'worth' 90/1024 degrees that's 0.0879 degrees per pixel."

So if someone clicks 100 pixels to the right from the centre of the screen then the program goes off and says "the 3D direction of the click is 100*0.0879 to the right... which is +8.79 degrees to the Y angle of the camera". If that click was the same distance away from the centre of the screen but to the left then the angle would have come out as -8.79 degrees from the camera's Y angle.

The computer then does the same calculation for the mouse's Y position to determine how high or low to pitch the new angle.

So, to summarise, the computer takes the position of the mouse, works out how far from the centre of the screen it is (in both x and y directions), then converts this to degrees remembering to factor in the FOV. The final product is an angle offset which is added to (or subtracted from) the camera's orientation.

Is that OK?

Back to top

Profile PM Email

Sorry your browser is not supported!

Newcomers DBPro Corner / 3D world - 2D Mouse