IP Address Problem - GameCreators Forum

Author

Message

Bighead

21

Years of Service

User Offline

Joined: 1st Sep 2002

Location:

Posted: 4th Jan 2003 15:53

Link

Does anybody know how to get the IP Address of a server/host with DBPro using "ws2_32.dll"? (or any other dll)

Back to top

Profile PM Email

levent

21

Years of Service

User Offline

Joined: 2nd Nov 2002

Location: United States

Posted: 5th Jan 2003 03:28

Link

Here is an extract in C that might help you:

......................
#include <winsock2.h>

Link with Wsock32.lib
....................
{
WORD wVersionRequested;
WSADATA wsaData;
char name[255];
CString ip;
PHOSTENT hostinfo;
wVersionRequested = MAKEWORD( 2, 0 );

if ( WSAStartup( wVersionRequested, &wsaData ) == 0 )
{

if( gethostname ( name, sizeof(name)) == 0)
{
if((hostinfo = gethostbyname(name)) != NULL)
{
ip = inet_ntoa (*(struct in_addr *)*hostinfo->h_addr_list);
}
}

WSACleanup( );
}
}

Back to top

Profile PM

Bighead

21

Years of Service

User Offline

Joined: 1st Sep 2002

Location:

Posted: 5th Jan 2003 04:10

Link

Thx for the info, but what I want to know is whether there ia a way to use the dll commands in DBPro to directly emulate that (I mean without using C or other language) ...

Having loaded the dll, when I use a sentence like:

+ Code Snippet

Print Call Dll (1,"gethostname", ...)

, DBP displays a 16-char number that seems to be a pointer to somewhere, perhaps the HOSTENT. The number is like, in my case, say: "5340448251969366" for "127.0.0.1".

The funny thing is that when I want to store that "number" in an integer variable and then display it, the result is "-1". When I use a floating the result is "-1.#QNAN", and when I finally use a string one, DBP crashes.

Any ideas?

Back to top

Profile PM Email

MrTAToad

21

Years of Service

User Offline

Joined: 26th Aug 2002

Location: United Kingdom

Posted: 5th Jan 2003 15:32

Link

Have you tried DOUBLE INTEGER ?

Good news everyone! I really am THAT good...
http://www.nickk.nildram.co.uk/ for great plug-ins - oh my, yes!

Back to top

Profile PM Email Website

IanM

Retired Moderator

21

Years of Service

User Offline

Joined: 11th Sep 2002

Location: In my moon base

Posted: 5th Jan 2003 22:43

Link

It is actually returning an integer and not a double integer - the -1 tells you that the call failed for some reason.

I'm having a look now, and will give you a result tomorrow evening sometime ... at least I hope so

Back to top

Profile PM Email Website

IanM

Retired Moderator

21

Years of Service

User Offline

Joined: 11th Sep 2002

Location: In my moon base

Posted: 6th Jan 2003 00:13

Link

Well, it actually turned out to be not too difficult, just a bit long winded.

sync on

if WSAStartup() = 0
   print GetLocalIP(0)
   print GetLocalIP(1)
   WSACleanup()
endif

sync
sync
wait key

end

function GetLocalIP(index as integer)
   local ip as string
   local p as DWORD
   local HOSTENT as DWORD

HOSTENT=make memory(256)

if GetHostName( HOSTENT, 256 ) = 0
      HostInfo=GetHostByName( HOSTENT )
      if HostInfo <> 0
         p=HostInfo+12
         p=*p
         p=*p
         p=p+(index*4)
         ip=INET_ntoa( *p )
      endif
   endif

delete memory HOSTENT
endfunction ip

function GetHostName(memptr as DWORD, size as integer)
   local r as integer
   local a as DWORD
   local s as DWORD
   r=call dll(201, "gethostname", memptr, size)
endfunction r

function GetHostByName(memptr as DWORD)
   local r as integer
   r=call dll(201, "gethostbyname", memptr)
endfunction r

function INET_ntoa(addr as DWORD)
   local ip as string
   ip=call dll(201, "inet_ntoa", addr)
endfunction ip

function WSAStartup()
   local WSADATA as DWORD
   local r as integer
   local v as WORD

load dll "wsock32.dll",201

WSADATA=make memory(16384)

v=2
   r=call dll(201, "WSAStartup", v, WSADATA)

delete memory WSADATA
endfunction r

function WSACleanup()
   call dll 201, "WSACleanup"
   delete dll 201
endfunction

+ Code Snippet

sync on

if WSAStartup() = 0
   print GetLocalIP(0)
   print GetLocalIP(1)
   WSACleanup()
endif

sync
sync
wait key

end

function GetLocalIP(index as integer)
   local ip as string
   local p as DWORD
   local HOSTENT as DWORD

   HOSTENT=make memory(256)

   if GetHostName( HOSTENT, 256 ) = 0
      HostInfo=GetHostByName( HOSTENT )
      if HostInfo <> 0
         p=HostInfo+12
         p=*p
         p=*p
         p=p+(index*4)
         ip=INET_ntoa( *p )
      endif
   endif

   delete memory HOSTENT
endfunction ip

function GetHostName(memptr as DWORD, size as integer)
   local r as integer
   local a as DWORD
   local s as DWORD
   r=call dll(201, "gethostname", memptr, size)
endfunction r

function GetHostByName(memptr as DWORD)
   local r as integer
   r=call dll(201, "gethostbyname", memptr)
endfunction r

function INET_ntoa(addr as DWORD)
   local ip as string
   ip=call dll(201, "inet_ntoa", addr)
endfunction ip

function WSAStartup()
   local WSADATA as DWORD
   local r as integer
   local v as WORD

   load dll "wsock32.dll",201

   WSADATA=make memory(16384)

   v=2
   r=call dll(201, "WSAStartup", v, WSADATA)

   delete memory WSADATA
endfunction r

function WSACleanup()
   call dll 201, "WSACleanup"
   delete dll 201
endfunction

Back to top

Profile PM Email Website

Bighead

21

Years of Service

User Offline

Joined: 1st Sep 2002

Location:

Posted: 6th Jan 2003 09:51

Link

Nice coding! Thanks ... [img]

[/img]

Back to top

Profile PM Email

Sorry your browser is not supported!

DarkBASIC Professional Discussion / IP Address Problem