When you turned you font into a bitmap did you remember to use load image with the extra flag, for example
load image "Image Name.bmp", ImageNum, 1
This could be a reason why it didn't turn out right. Also if you used an animated sprite there is currently a bug with it which displays images a little funny (version 5.8).
Anyways to do option number 1, this is how you do it.
1. Set up your program as normal
2. Hide all your sprites.
3. Use paste image with the correct image and coordinates to draw the sprites images.
4. Use the text command to draw text to the screen.
Heres an example program that demostrates this
`Setup Screen
sync on
sync rate 60
sync
`Declare variables
iMove as integer
iScrWidth as integer
iScrHeight as integer
dim iPos(1, 1) as integer
iScrWidth = screen width()
iScrHeight = screen height()
iMove = 2
`Get a red image
cls rgb(255, 0, 0)
get image 1, 0, 0, 128, 64, 1
`Make 2 sprites and hide them
sprite 1, 0, 0, 1
set sprite 1, 0, 1
offset sprite 1, 64, 32
hide sprite 1
sprite 2, 0, 0, 1
set sprite 2, 0, 1
hide sprite 2
`Make a 3D object, just for fun
make object cube 1, 1
do
`Rotate 3D object
xrotate object 1, wrapvalue(object angle x(1) + 1)
`Update sprite 1's position values by using the mouse as those values
iPos(0, 0) = mousex()
iPos(0, 1) = mousey()
`Controls movement for sprite 2
iPos(1, 0) = iPos(1, 0) + iMove
if iPos(1, 0) < 0 then iPos(1, 0) = 0 : iMove = iMove * -1
if iPos(1, 0) > iScrWidth - 128 then iPos(1, 0) = iScrWidth - 128 : iMove = iMove * -1
`Position the sprites then draw images at there positions
sprite 1, iPos(0, 0), iPos(0, 1), 1
paste image 1, sprite x(1) - sprite offset x(1), sprite y(1) - sprite offset y(1), 1
sprite 2, iPos(1, 0), iPos(1, 1), 1
paste image 1, sprite x(2), sprite y(2), 1
`Draw text
text 0, 0, "Sprite Collision = " + str$(sprite collision(1, 2))
text iScrWidth / 2, iScrHeight / 2, "Hello"
text 0, iScrHeight - 20, "Press spacebar to exit"
sync
loop
`Delete created media
delete sprite 1
delete sprite 2
delete image 1
delete object 1
end
There is one thing I forgot to mention, if using this method your sprites cannot be rotated or scaled as your images won't reflect the sprites images. In this situation option 2 would be the best.
