Sorry your browser is not supported!

`====INH's Golf course====
`=========================
ink rgb(250,250,250),1
center text 320,220,"Welcome to INH's Golf Course."
center text 320,240,"White balls represent holes."
center text 320,260,"Press any key to start."
suspend for key
cls
ink rgb(0,60,0),1
box 0,0,250,250
get image 1,0,0,250,250
make matrix 1,1000,1000,11,11
prepare matrix texture 1,1,2,2
fill matrix 1,0.0,1
for x=0 to 10
for y=0 to 10
if rnd(2)=0 then set matrix tile 1,x,y,2
set matrix tile 1,0,y,3
set matrix tile 1,10,y,3
set matrix tile 1,x,0,3
set matrix tile 1,x,10,3
set matrix tile 1,x,5,4
set matrix tile 1,x,5,4
next y
next x
update matrix 1

position matrix 1,-500,5,-150


make object cube 2,50
color backdrop rgb(100,100,250)
make object cube 3,50
make object cube 4,50
make object cube 5,50
make object cube 6,50
position object 2,x,y-25,z-50
position object 3,x,y-25,z-2
position object 4,x,y-25,z+48
position object 5,x,y-25,z+96
position object 6,x,y-25,z+140
color object 2,rgb(100,80,50)
color object 3,rgb(100,80,50)
color object 4,rgb(100,80,50)
color object 5,rgb(100,80,50)
color object 6,rgb(100,80,50)

make object cylinder 1,90
position object 1,x,y-45,z+200
color object 1,rgb(100,80,50)
position camera x1,y+20,z1
make object sphere 7,5

make object cube 8,50
position object 8,x+50,y-25.1,z+205
color object 8,rgb(100,80,50)
make object cube 9,50
position object 9,x+75,y-25.1,z+215.5
yrotate object 9,45
color object 9,rgb(100,80,50)
position object 7,x,y,z+205
make object cone 10,50
position object 10,x+115,y-10,z+248
zrotate object 10,90
yrotate object 10,140
color object 10,rgb(0,0,0)

make object cone 11,50
position object 11,x+130,y-10,z+238
zrotate object 11,90
yrotate object 11,60
color object 11,rgb(0,0,0)
make object cube 12,50
position object 12,x+145,y-25.1,z+205
color object 12,rgb(100,80,50)
make object cube 13,50
position object 13,x+145,y-25.1,z+176
xrotate object 13,45
color object 13,rgb(100,80,50)
make object sphere 14,5
position object 14,x+145,y-1,z+205
make object cube 15,50
position object 15,x+145,y-25.1,z+156
color object 15,rgb(100,80,50)
make object cube 16,50
position object 16,x+145,y-25.1,z+106
color object 16,rgb(100,80,50)
make object sphere 17,5
position object 17,x+145,y-1,z+106
position camera x1,y+20,z1
do
if upkey()=1 then z1=z1+10 : position camera x1,y+20,z1 : fhm=fhm+1
if downkey()=1 then z1=z1-10 : position camera x1,y+20,z1 : fhm=fhm-1
if leftkey()=1 then x1=x1-10 : position camera x1,y+20,z1 : lhm=lhm-1
if rightkey()=1 then x1=x1+10 : position camera x1,y+20,z1 : lhm=lhm+1
if fhm<0 then z1=z1+10 : position camera x1,y+20,z1 : fhm=0
if fhm>17 then z1=z1-10 : position camera x1,y+20,z1 : fhm=17
if lhm<0 then lhm=0 : x1=x1+10 : position camera x1,y+20,z1
if lhm>20 then lhm=20 : x1=x1-10 : position camera x1,y+20,z1
loop

Rem Dark Basic Classic Project: Golf Hole Number 1
Rem Created: 11/06/2007 18:06:21
Rem Author: TDK_Man

Gosub Setup

Do
  CX# = Camera Angle X(): CY# = Camera Angle Y(): CZ# = Camera Angle Z()
  CY# = Wrapvalue(CY#+mousemovex())
  CX# = Wrapvalue(CX#+mousemovey())
  Rotate Camera CX#,CY#,CZ#
  If MouseClick()=1 Then Move Camera 50
  If MouseClick()=2 Then Move Camera -50
  CHeight# = Get Ground Height(1,Camera Position X(),Camera Position Z())
  If Camera Position Y() < CHeight#+40.0 Then Position Camera Camera Position X(), CHeight#+40.0, Camera Position Z()
  YRotate Object 4,Wrapvalue(Object Angle Y(4)+1)
  Gosub SizeNumber
  Sync
Loop

SizeNumber:
  X1 = Camera Position X()
  Y1 = Camera Position Y()
  Z1 = Camera Position Z()
  X2 = Object Position X(1)
  Y2 = Object Position Y(1)
  Z2 = Object Position Z(1)
  Dist# = sqrt((x1-x2)^2+(y1-y2)^2+(z1-z2)^2)
  Size = Dist# / 50
  If Size < 100 Then Size = 100
  Scale Object 4,Size,Size,100
Return

Setup:
  Set Display Mode 800,600,32
  Hide Mouse
  Sync On: Sync Rate 60: CLS 0
  AutoCam Off
  Backdrop On: Color Backdrop RGB(100,100,255)
  Randomize 65535

  Wire=1: Trans=0: Cull=1: Filter=1: Light=0: Fog=0: Ambient=0
  TilesX=70: TilesZ=70: Tilesize#=2048.0: MatZPos#=0.0
  MatWidth#=50000: MatHeight#=50000
  MatCentreX#=MatWidth#/2.0: MatCentreZ#=MatHeight#/2.0
  Dim MatX#(TilesX)
  Dim MatZ#(TilesZ)
  Dim MHeight#(70,70)

  Create Bitmap 1,800,600
  Set camera view 0,0,1,1
  Make Matrix 1,MatWidth#,MatHeight#,TilesX,TilesZ
  Set Matrix 1, Wireframe, Transparency, Cull, Filter, Light, Fog, Ambient

  Randomize Matrix 1,3000
  Gosub Smooth
  For N = 1 To 80
    X=Rnd(TilesX-2)+1: Z=Rnd(TilesZ-2)+1
    Set Matrix Height 1,x,z,14000
    Set Matrix Height 1,x-1,z-1,12000
    Set Matrix Height 1,x+1,z+1,11000
    Set Matrix Height 1,x+1,z-1,1800
    Set Matrix Height 1,x-1,z+1,1600
  Next N
  For N = 0 To TilesX
    Set Matrix Height 1,N,0,Get Matrix Height(1,N,TilesZ): Rem Match edges for scrolling
  Next N
  For N=1 To 14
    Gosub Smooth
  Next N

  CLS 0
  Set Text Font "Wingdings",2
  Set Text Size 32
  Ink RGB(5,0,5),0
  Text 0,0,Chr$(140)
  Blur Bitmap 1,2
  Get Image 4,0,0,24,32
  Set Text Font "Verdana",1
  Set Text Size 16

  CLS 0
  SpreadGap = MatWidth#/512
  High=0
  Low=100000
  For Tz=0 To 512
    For Tx=0 To 512
      Mh = Get Ground Height(1,Tx*SpreadGap,Tz*SpreadGap)
      If Mh>High Then High=Mh
      If Mh<Low Then Low=Mh
    Next Tx
  Next Tz
  ColourRange = High-Low
  Gradient# = ColourRange/255.0
  For Tz=512 To 0 Step -1
    For Tx=0 To 512
      Mh = Get Ground Height(1,Tx*SpreadGap,Tz*SpreadGap)
      M = (Mh-Low)/ Gradient# : Rem Number between 1 and 255
      Grass = 20
      Mud = 12
      Sand = 2
      Water = -10
      Rem ************ WATER ************
      If M <= Water
        For N=1 To 4
          R = Rnd(6)-3
          EdgeDist = Water-M
          If EdgeDist<2
            Speckle = Rnd(EdgeDist)
          Else
            Speckle = 1
          Endif
          If Speckle = 0
            Ink Rgb(80,80,255),0: Rem Foam
          Else
            Ink Rgb(0,0,M+140+Rnd(10)),0: Rem Water
          Endif
          Dot Tx,511-Tz
          Dot Tx+R,511-Tz+R
        Next N
      Endif
      Rem ************ SAND ************
      If M > Water and M<= Sand
        For N=1 To 4
          R = Rnd(10)-5
          EdgeDist = Sand-M
          If EdgeDist<2
            Speckle = Rnd(EdgeDist)
          Else
            Speckle = 1
          Endif
          If Speckle = 0
            Ink Rgb(M+140,M+80,0),0: Rem Mud
          Else
            Ink Rgb(M+180+Rnd(20),M+140+Rnd(20),0),0: Rem Sand
          Endif
          Dot Tx,511-Tz
          Dot Tx+R,511-Tz+R
        Next N
      Endif
      Rem ************ MUD ************
      If M > Sand and M < Mud
        For N=1 To 2
          R = Rnd(6)-3
          EdgeDist = Mud-M
          If EdgeDist<2
            Speckle = Rnd(EdgeDist)
          Else
            Speckle = 1
          Endif
          If Speckle = 0
            Ink Rgb(140,M,0),0: Rem Grass
          Else
            Ink Rgb(M+180+Rnd(20),M+160+Rnd(20),0),0: Rem Sand
          Endif
          Dot Tx,511-Tz
          Dot Tx+R,511-Tz+R
        Next N
      Endif
      Rem ************ GRASS ************
      If M > Mud
        For N=1 To 2
          R = Rnd(6)-3
          EdgeDist = M-Mud
          If EdgeDist<5
            Speckle = Rnd(EdgeDist)
          Else
            Speckle = 1
          Endif
          If Speckle = 0
            Ink Rgb(M+180+Rnd(20),M+140+Rnd(20),0),0: Rem Sand
          Else
            Ink Rgb(30,M,30),0: Rem Grass
          Endif
          Dot Tx,511-Tz
          Dot Tx+R,511-Tz+R
        Next N
      Endif
    Next Tx
  Next Tz
  Sync

  For Nc=1 To 5
    Blur Bitmap 1,8
  Next Nc

  Ink RGB(20,180,20),0
  For N=1 To 32
    Circle 120,150,N
    Circle 120,151,N
  Next N
  Ink RGB(255,0,0),0: Box 410,410,450,440
  Ink RGB(200,255,200),0: Box 412,412,448,438
  Blur Bitmap 1,4

  Get Image 1,0,0,512,512
  If File Exist("Golf1.bmp") Then Delete File "Golf1.bmp"
  Save Image "Golf1.bmp",1
  Sleep 1

  Delete Bitmap 1
  Prepare Matrix Texture 1,1,TilesX,TilesZ
  Set Matrix Texture 1,2,1

  t=1
  For z=TilesZ-1 to 0 Step -1
    For x=0 to TilesX-1
      Set Matrix Tile 1,x,z,t
      Inc t
    Next x
  Next z
  Normalise(1)

  Fog Distance 60000.0
  FOG COLOR RGB(50,30,0)
  Fog On
  Set Camera Range 20.0, 100000.0

  Ratio# = MatWidth#/512.0
  Make Object Cylinder 1,10
  Scale Object 1,100,8500,100
  Position Object 1,120*Ratio#,Get Ground Height(1,120*Ratio#,150*Ratio#),(512-150)*Ratio#

  Make Object Cylinder 2,60
  Color Object 2,0
  Scale Object 2,100,60,100
  Position Object 2,120*Ratio#, Get Ground Height(1,120*Ratio#,150*Ratio#)-245, (512-150)*Ratio#

  Make Object Triangle 3,0.0,0.0,0.0,   0.0,60.0,0.0,  180.0,30.0,0.0
  Color Object 3,RGB(255,0,0)
  Position Object 3,120*Ratio#, Get Ground Height(1,120*Ratio#,150*Ratio#)+340, (512-150)*Ratio#

  Make Object Plain 4,150,150
  Texture Object 4,4
  Position Object 4,120*Ratio#, Get Ground Height(1,120*Ratio#,150*Ratio#)+1200, (512-150)*Ratio#
  Set Object 4,1,0,0
  Scale Object 4,1000,1000,100

  Height# = Get Ground Height(1,45270,5791)
  Position Camera 45270,Height#+3500,5791
  Point Camera Object Position X(1),Object Position Y(1),Object Position Z(1)
  Set MipMap Mode 2
  Set camera view 0,0,800,600

  Ink RGB(255,255,255),0
Return

Rem **************************************************
Rem                  Smooth Matrix
Rem **************************************************
Smooth:
  Rem Averages matrix heights to remove jagged edges
  For Z=0 to TilesZ
    For X=0 to TilesX
      P0#=Get Matrix Height(1,X,Z):     Rem Current point height
      Rem Get 4 adjoining points heights (if they exist)
      If Z-1 > 0
        P1#=Get Matrix Height(1,X,Z-1)
      Else
        P1#=P0#
      Endif
      If X+1 < TilesX
        P2#=Get Matrix Height(1,X+1,Z)
      Else
        P2#=P0#
      Endif
      If Z+1 < TilesZ
        P3#=Get Matrix Height(1,X,Z+1)
      Else
        P3#=P0#
      Endif
      If X-1 > 0
        P4#=Get Matrix Height(1,X-1,Z)
      Else
        P4#=P0#
      Endif
      Average#=(P0#+P1#+P2#+P3#+P4#)/5: Rem Av height of other points
      Set Matrix Height 1,x,z,Average#
      MHeight#(X,Z)=Average#
    Next x
  Next z
Return

Function Normalise(MatNum)
  Rem By Lee Bamber From DB Example - Adds shaded areas to matrix to give depth
  For z=1 to 70
    For x=1 to 70
      h8#=MHeight#(X,Z-1)
      h4#=MHeight#(X-1,Z)
      h#=MHeight#(X,Z)
      h2#=MHeight#(X,Z)
      x1#=(x-1)*25.0
      y1#=h#
      x2#=(x+0)*25.0
      y2#=h4#
      dx#=x2#-x1#
      dy#=y2#-y1#
      ax#=atanfull(dx#,dy#)
      ax#=wrapvalue(90-ax#)
      z1#=(z-1)*25.0
      y1#=h2#
      z2#=(z+0)*25.0
      y2#=h8#
      dz#=z2#-z1#
      dy#=y2#-y1#
      az#=atanfull(dz#,dy#)
      az#=wrapvalue(90-az#)
      nx#=sin(ax#)
      ny#=cos(ax#)
      nz#=sin(az#)
      Set matrix normal MatNum,x,z,nx#,ny#,nz#
    next x
  next z
  Update Matrix MatNum
EndFunction

` One Hole of Golf   6/8/07  LBFN
randomize timer()
sync on : sync rate 42
autocam off
`MAKE MATRIX 1, 1000,2000, 40, 100
make matrix 2,750,250,60,20
SET MATRIX 2, 1, 1, 1,1, 1, 1, 1
gosub MAKE_TEXTURES
gosub SET_TILES_MTX2
`make matrix 3,100,2000,40,100
POSITION CAMERA -5.3,10.0,96.7
` 439.8, 10.0, 306.1
point camera 483.2,10.0,146.6

`198.0,10.0,290.0
draw to front

` make cup, flagstick and flag
make object cylinder 22,1
make object cylinder 23,10
make object plain 24,2,2
scale object 23,2,100,2
opy = GET GROUND HEIGHT(2, 531.6, 80.4)
position object 22,531.6,(opy-.47),80.4
position object 23,531.6,(opy+5.0),80.4
position object 24,531.6,(opy+9.0),79.4
yrotate object 24,90
do
  if upkey()=1 then move camera 5
  if downkey()=1 then move camera -5
  if leftkey()=1 then  y#=wrapvalue(camera angle y()-2.5) : yrotate camera y#
  if rightkey()=1 then y#=wrapvalue(camera angle y()+2.5) : yrotate camera y#
  mc=mouseclick()
  if mc=2 then exit
  set cursor 0,0
  print "pos x=";camera position x()
  print "pos y=";camera position y()
  print "pos z=";camera position z()
  if inkey$()="d" then position camera camera position x(),camera position y()-5.0,camera position z() :point camera 483.2,10.0,146.6
  if inkey$()="u" then position camera camera position x(),camera position y()+5.0,camera position z() : point camera 483.2,10.0,146.6
  sync
loop
end


SET_TILES_MTX2:
FILL MATRIX 2, 0, 13
` make green
x=39 : y=3
set matrix tile 2,x,y+4,8
set matrix tile 2,x,y+2,12
set matrix tile 2,x,y+3,1

set matrix tile 2,x+1,y+4,1
set matrix tile 2,x+1,y+2,1
set matrix tile 2,x+2,y+2,1
SET MATRIX HEIGHT 2, x, y+3, 1.5
set matrix height 2,x+1,y+3,2.75
set matrix height 2,x,y+4,2.5
set matrix height 2,x,y+5,1.5
set matrix height 2,x+1,y+4,4.0
set matrix height 2,x+1,y+2,1.5
set matrix height 2,x+2,y+2,2.75
set matrix height 2,x+2,y+3,4.0
set matrix height 2,x+1,y+3,4.0
set matrix height 2,x+2,y+3,4.0
set matrix height 2,x+1,y+4,4.0
set matrix height 2,x+2,y+4,4.0
set matrix tile   2,x+1,y+3,1
set matrix tile 2, x+2,y+3,1
set matrix height 2,x+2,y+2,2.75
set matrix height 2,x+3,y+2,2.75
set matrix height 2,x+2,y+3,4.0
set matrix height 2,x+3,y+3,4.0
set matrix tile 2,x+2,y+4,1
set matrix height 2,x+3,y+4,2.75
set matrix height 2,x+2,y+5,4.0
set matrix height 2,x+3,y+5,4.0
set matrix tile 2,x+3,y+2,1
set matrix height 2,x+3,y+2,2.75
set matrix height 2,x+4,y+2,2.75
set matrix height 2,x+3,y+3,4.0
set matrix height 2,x+4,y+3,4.0
set matrix tile 2,x+3,y+3,1
set matrix height 2,x+3,y+4,4.0
set matrix height 2,x+4,y+4,4.0
set matrix tile 2,x+3,y+4,1
set matrix height 2,x+3,y+5,4.0
set matrix height 2,x+4,y+5,4.0
set matrix tile 2,x+3,y+4,1
set matrix height 2,x+3,y+5,4.0
set matrix height 2,x+4,y+5,4.0
set matrix tile 2,x+4,y+2,9
set matrix height 2,x+5,y+2,1.5
set matrix height 2,x+5,y+3,1.5
set matrix tile 2,x+4,y+3,1
set matrix height 2,x+5,y+4,1.5
set matrix tile 2,x+4,y+4,11
` make tee
set matrix tile 2,1,8,1
set matrix tile 2,1,7,1
set matrix tile 2,2,8,1
set matrix tile 2,2,7,1
set matrix height 2,1,7,3.0
set matrix height 2,1,8,3.0
set matrix height 2,2,7,3.0
set matrix height 2,2,8,3.0
set matrix height 2,3,7,2.0
set matrix height 2,3,8,2.0
set matrix height 2,1,9,3.0
set matrix height 2,2,9,3.0
set matrix height 2,3,9,2.0
` place rough
for i = 0 to 59
  for t = 16 to 19
    set matrix tile 2,i,t,2
  next t
next i
for i=0 to 6
  for t=11 to 15
    set matrix tile 2,i,t,2
  next t
 next i
for i=48 to 59
  for t=0 to 15
    set matrix tile 2,i,t,2
  next t
next i
for i = 0 to 59
  for t = 0 to 3
    set matrix tile 2,i,t,2
  next t
next i
for i=10 to 23
  for t=4 to 5
    set matrix tile 2,i,t,2
  next t
next i
` sand trap
` left side of the green
set matrix tile 2,37,8,3

set matrix tile 2,38,9,3

set matrix tile 2,38,8,3

set matrix tile 2,39,9,3

set matrix tile 2,37,9,20

set matrix tile 2,39,8,15
set matrix tile 2,37,7,3
set matrix tile 2,38,7,15
set matrix height 2,38,8,-5.0
set matrix height 2,38,7,-5.0
set matrix height 2,39,9,-5.0
` hand place tiles to make the transition smoother
 restore left_fairway
 read total_tiles
 for t=1 to total_tiles
   read x,y,tile
   set matrix tile 2,x,y,tile
next t
restore behind_green
read total_tiles
for t=1 to total_tiles
   read x,y,tile
   set matrix tile 2,x,y,tile
next t
restore right_fairway
read total_tiles
for t=1 to total_tiles
   read x,y,tile
   set matrix tile 2,x,y,tile
next t


 left_fairway:
 ` # of entries
  data 15
` x,y,tile #
 data 7,15,2,7,14,2,7,13,2,7,12,2,7,11,6
 data 8,15,2,8,14,2,8,13,2,8,12,6
 data 9,15,2,9,14,2,9,13,6
 data 10,15,2,10,14,6
 data 11,15,6
behind_green:
` # of entries
data 16
` x,y,tile #
data 44,4,19
data 45,15,7,45,5,19,45,4,2
data 46,15,2,46,14,7,46,6,19,46,5,2,46,4,2
data 47,15,2,47,14,2,47,13,7,47,7,19,47,6,2,47,5,2,47,4,2
right_fairway:
` # of entries
data 6
` x,y,tile #
data 8,4,19
data 9,5,19,9,4,2
data 24,5,18,24,4,2
data 25,4,18
update matrix 2
return
MAKE_TEXTURES:
` lite grass - green
ink rgb(0,255,0),0
box 0,0,63,63
box 0,96,63,127

for t=0 to 63
  line 128,64+t,191-t,64+t
  line 192+t,127-t,255,127-t

  line 64,128+t,64+t,128+t
next i
box 0,64,63,95
for t=0 to 63
  line 128+t,128-t,191,128-t
  line 192+t,127-t,255,127-t
  line 0,128+t,t,128+t
  line 64+t,128+t,127,128+t
  line 192,64+t,255,64+t
next i
` rough
ink rgb(0,128,0),0
box 0,192,31,255
box 64,0,127,63
box 96,192,127,255
for t=0 to 63
  line 128,192+t,128+t,192+t
  line 192+t,255-t,255,255-t
  line 0,64+t,63-t,64+t
  line 64+t,64+t,127,64+t
  line 256,t,319-int(t/2),t
  line 256,64+t,287-int(t/2),64+t
next t
` sand
ink rgb(255,255,128),0
box 128,0,191,63
for t=0 to 63
  line 256+t,128,256+t,191-t
  line 256+t,255-t,319,255-t
next t
` water
ink rgb(0,64,190),0
box 192,0,255,63
` fairway grass
ink rgb(0,192,43),0
box 128,128,191,191
box 32,192,95,255

for t=0 to 63
  line 0+t,128-t,63,128-t
  line 128,64+t,191-t,64+t
  line 192+t,127-t,255,127-t
  line 0+t,128+t,63,128+t
  line 64,128+t,64+t,128+t
  line 128+t,192+t,191,192+t
  line 192+t,192,192+t,255-t
  line 64,64+t,64+t,64+t
  line 288+int(t/2),63-t,319,63-t
  line 256+int(t/2),127-t,319,127-t
  line 256+t,191-t,319,191-t
  line 256+t,192,256+t,255-t
next t
` really dark green
ink rgb(0,96,0),0
box 192,128,255,191
get image 1,0,0,320,320
PREPARE MATRIX TEXTURE 2, 1, 5, 5
`backdrop off
`sync
`wait key
return

  If MouseClick()=1 Then Move Camera Camera Position Y()/15
  If MouseClick()=2 Then Move Camera 0-Camera Position Y()/15

for i=0 to 128
   for j=0 to 128
      ink rgb(10,100+rnd(30),25),0
      dot i,j
   next j
next i
get image 1,0,0,256,128
cls
set current bitmap 0
delete bitmap 1
make object cube 1,0
texture backdrop 1

for i=0 to 128

for i=0 to 255

Gosub Setup
Do
  CX#=Camera Angle X(): CY#=Camera Angle Y(): CZ#=Camera Angle Z()
  CY#=Wrapvalue(CY#+mousemovex())
  CX#=Wrapvalue(CX#+mousemovey())
  Rotate Camera CX#,CY#,CZ#
  If MouseClick()=1 Then Move Camera 10
  If MouseClick()=2 Then Move Camera -10
  If Scancode() Then Normalise(1)
  Sync
  Center Text 400,5,"Press Any Key To Apply Normalization"
Loop

Rem **************************************************
Rem                  Smooth Matrix
Rem **************************************************
Smooth:
  Rem Averages matrix heights to remove jagged edges
  for Z=0 to 70
    for X=0 to 70
      P0#=Get Matrix Height(1,X,Z):     Rem Current point height
      Rem Get 4 adjoining points heights (if they exist)
      If Z-1>=0
        P1#=Get Matrix Height(1,X,Z-1)
      Else
        P1#=P0#
      Endif
      If X+1<=TilesX
        P2#=Get Matrix Height(1,X+1,Z)
      Else
        P2#=P0#
      Endif
      If Z+1<=TilesZ
        P3#=Get Matrix Height(1,X,Z+1)
      Else
        P3#=P0#
      Endif
      If X-1>=0
        P4#=Get Matrix Height(1,X-1,Z)
      Else
        P4#=P0#
      Endif
      Average#=(P0#+P1#+P2#+P3#+P4#)/5: Rem Av height of other points
      RHeight#=Average#
      Set Matrix Height 1,x,z,RHeight#
    Next x
  Next z
  Update Matrix 1
Return

Setup:
  Set Display Mode 800,600,32
  Sync On: Sync Rate 0: CLS 0: Sync
  AutoCam Off
  Set Camera Range 1.0, 100000.0
  Hide Mouse
  Create Bitmap 1,1024,1024
  Rem ********************
  Rem    Matrix Texture
  Rem ********************
  Ink RGB(0,110,0),0
  Box 0,0,1023,1023
  For N=1 To 15000
    Ink RGB(0,Rnd(150)+50,0),0
    Dot Rnd(512),Rnd(512)
  Next N
  Blur Bitmap 1,1
  Sync
  Get Image 100,0,0,512,512,1
  Sync
  Rem ********************
  Rem       Matrix
  Rem ********************
  Make Matrix 1,7000,7000,70,70: Rem 1 Tile = 100
  Prepare Matrix Texture 1,100,70,70
  Randomize Matrix 1,2000.0
  For N=1 To 40
    X=Rnd(66)+2: Z=Rnd(66)+2
    Set Matrix Height 1,X,Z,7000.0
  Next N
  For N=1 To 15
    Gosub Smooth
  Next N
  t=1
  For z=69 to 0 Step -1
    For x=0 to 69
      Set Matrix Tile 1,x,z,t
      Inc t
    Next x
  Next z
  Update Matrix 1
  Set Current Bitmap 0
  Delete Bitmap 1
  Position Camera 0,3000,0
  Point Camera 3500,0,3500
  Ink RGB(255,255,255),0
Return


Rem *********************************************************
Rem ***                   FUNCTIONS                       ***
Rem *********************************************************


Function Normalise(MatNum)
  Rem By Lee Bamber From DB Example - Adds shaded areas to matrix to give depth
  For z=1 to 70
    For x=1 to 70
      h8#=get matrix height(MatNum,x,z-1)
      h4#=get matrix height(MatNum,x-1,z)
      h#=get matrix height(MatNum,x,z)
      h2#=get matrix height(MatNum,x,z)
      x1#=(x-1)*25.0
      y1#=h#
      x2#=(x+0)*25.0
      y2#=h4#
      dx#=x2#-x1#
      dy#=y2#-y1#
      ax#=atanfull(dx#,dy#)
      ax#=wrapvalue(90-ax#)
      z1#=(z-1)*25.0
      y1#=h2#
      z2#=(z+0)*25.0
      y2#=h8#
      dz#=z2#-z1#
      dy#=y2#-y1#
      az#=atanfull(dz#,dy#)
      az#=wrapvalue(90-az#)
      nx#=sin(ax#)
      ny#=cos(ax#)
      nz#=sin(az#)
      Set matrix normal MatNum,x,z,nx#,ny#,nz#
    next x
  next z
  Update Matrix MatNum
EndFunction

` One Hole of Golf   6/8/07  LBFN
randomize 128649
sync on : sync rate 42
autocam off
draw to front
TilesX=60
TilesZ=20
Dim MatX#(TilesX)
Dim MatZ#(TilesZ)
Dim MHeight#(60,20)
make matrix 2,750,250,60,20
SET MATRIX 2, 1, 0, 1, 1, 0, 0, 0
`SET MATRIX Matrix Number, Wireframe, Transparency, Cull, Filter, Light, Fog, Ambient
set ambient light 60
set directional light 0,-1.0,0.0,0.0
gosub MAKE_TEXTURES
gosub normalise
gosub SET_TILES_MTX2
POSITION CAMERA -5.3,10.0,96.7
point camera 483.2,10.0,146.6

` make cup, flagstick and flag
make object cylinder 22,1
make object cylinder 23,10
texture object 23,101
make object plain 24,2,2
texture object 24,100
scale object 23,2,100,2
opy = GET GROUND HEIGHT(2, 531.6, 80.4)
position object 22,531.6,2.98,80.4
position object 23,531.6,(opy+5.0),80.4
position object 24,531.6,(opy+9.0),79.4
yrotate object 24,90
` make tee markers
` men's
make object sphere 25,1.5
th#=get ground height(2,25,111)+.15
position object 25,25,th#,111
color object 25,rgb(0,64,128)
make object sphere 26,1.5
th#=get ground height(2,25,89)+.15
position object 26,25,th#,89
color object 26,rgb(0,64,128)
` womens
make object sphere 27,1.5
th#=get ground height(2,150,161)+.15
position object 27,150,th#,161
color object 27,rgb(192,34,0)
make object sphere 28,1.5
th#=get ground height(2,150,139)+.15
position object 28,150,th#,139
color object 28,rgb(192,34,0)
` sign, sign everywhere's a sign
make object plain 29,10.0,7.0
position object 29,23,10,120
yrotate object 29,75
SET OBJECT TEXTURE 29, 2, 0
texture object 29,102
make object cylinder 30,7
scale object 30,7,100,7
position object 30,22.71,3.2,122
color object 30,rgb(128,64,0)
make object cylinder 31,7
scale object 31,7,100,7
position object 31,23.75,3.2,118
color object 31,rgb(128,64,0)

gosub MAKE_UNDULATIONS
gosub smooth
` MAIN LOOP  &&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
do
  if upkey()=1 then move camera 5
  if downkey()=1 then move camera -5
  if leftkey()=1 then  y#=wrapvalue(camera angle y()-2.5) : yrotate camera y#
  if rightkey()=1 then y#=wrapvalue(camera angle y()+2.5) : yrotate camera y#
  if mouseclick()=2 then exit
  remstart
  ` debug
  set cursor 0,0
  print "pos x=";camera position x()
  print "pos y=";camera position y()
  print "pos z=";camera position z()
  remend
  cpy#=GET GROUND HEIGHT(2,camera position x(),camera position z())
  if cpy#<10.0 then position camera camera position x(),cpy#+10.0,camera position z()

  sync
loop
` MAIN LOOP  &&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&

show mouse
end


SET_TILES_MTX2:
FILL MATRIX 2, 0, 13
` make green
x=39 : y=3

SET MATRIX HEIGHT 2, x, y+3, 1.5
set matrix height 2,x+1,y+3,2.75
set matrix height 2,x,y+4,2.5
set matrix height 2,x,y+5,1.5
set matrix height 2,x+1,y+4,4.0
set matrix height 2,x+1,y+2,1.5
set matrix height 2,x+2,y+2,2.75
set matrix height 2,x+2,y+3,4.0
set matrix height 2,x+1,y+3,4.0
set matrix height 2,x+2,y+3,4.0
set matrix height 2,x+1,y+4,4.0
set matrix height 2,x+2,y+4,4.0
set matrix height 2,x+2,y+2,2.75
set matrix height 2,x+3,y+2,2.75
set matrix height 2,x+2,y+3,4.0
set matrix height 2,x+3,y+3,4.0
set matrix height 2,x+3,y+4,2.75
set matrix height 2,x+2,y+5,4.0
set matrix height 2,x+3,y+5,4.0
set matrix height 2,x+3,y+2,2.75
set matrix height 2,x+4,y+2,2.75
set matrix height 2,x+3,y+3,4.0
set matrix height 2,x+4,y+3,4.0
set matrix height 2,x+3,y+4,4.0
set matrix height 2,x+4,y+4,4.0
set matrix height 2,x+3,y+5,4.0
set matrix height 2,x+4,y+5,4.0
set matrix height 2,x+3,y+5,4.0
set matrix height 2,x+4,y+5,4.0
set matrix height 2,x+5,y+2,1.5
set matrix height 2,x+5,y+3,1.5
set matrix height 2,x+5,y+4,1.5
set matrix tile 2,x,y+4,8
set matrix tile 2,x,y+2,12
set matrix tile 2,x,y+3,1
set matrix tile 2,x+1,y+4,1
set matrix tile 2,x+1,y+2,1
set matrix tile 2,x+2,y+2,1
set matrix tile 2,x+1,y+3,1
set matrix tile 2, x+2,y+3,1
set matrix tile 2,x+2,y+4,1
set matrix tile 2,x+3,y+2,1
set matrix tile 2,x+3,y+3,1
set matrix tile 2,x+3,y+4,1
set matrix tile 2,x+3,y+4,1
set matrix tile 2,x+4,y+2,9
set matrix tile 2,x+4,y+3,1
set matrix tile 2,x+4,y+4,11
` make men's tee
set matrix height 2,1,7,3.0
set matrix height 2,1,8,3.0
set matrix height 2,2,7,3.0
set matrix height 2,2,8,3.0
set matrix height 2,3,7,2.0
set matrix height 2,3,8,2.0
set matrix height 2,1,9,3.0
set matrix height 2,2,9,3.0
set matrix height 2,3,9,2.0
set matrix tile 2,1,8,1
set matrix tile 2,1,7,1
set matrix tile 2,2,8,1
set matrix tile 2,2,7,1
` make ladies' tee
set matrix tile 2,11,12,1
set matrix tile 2,12,12,1
set matrix tile 2,11,11,1
set matrix tile 2,12,11,1

` place rough
for i = 0 to 59
  for t = 16 to 19
    set matrix tile 2,i,t,2
  next t
next i
for i=0 to 6
  for t=11 to 15
    set matrix tile 2,i,t,2
  next t
 next i
for i=48 to 59
  for t=0 to 15
    set matrix tile 2,i,t,2
  next t
next i
for i = 0 to 59
  for t = 0 to 3
    set matrix tile 2,i,t,2
  next t
next i
for i=10 to 23
  for t=4 to 5
    set matrix tile 2,i,t,2
  next t
next i
` sand trap
` left side of the green
set matrix height 2,38,8,-5.0
set matrix height 2,38,7,-5.0
set matrix height 2,39,9,-5.0
set matrix tile 2,37,8,3
set matrix tile 2,38,9,3
set matrix tile 2,38,8,3
set matrix tile 2,39,9,3
set matrix tile 2,37,9,20
set matrix tile 2,39,8,15
set matrix tile 2,37,7,3
set matrix tile 2,38,7,15
` hand place tiles to make the transition smoother
 restore left_fairway
 read total_tiles
 for t=1 to total_tiles
   read x,y,tile
   set matrix tile 2,x,y,tile
next t
restore behind_green
read total_tiles
for t=1 to total_tiles
   read x,y,tile
   set matrix tile 2,x,y,tile
next t
restore right_fairway
read total_tiles
for t=1 to total_tiles
   read x,y,tile
   set matrix tile 2,x,y,tile
next t
` water
for i= 38 to 41
  for t=2 to 3
    set matrix tile 2,i,t,4
  next t
next i
restore water
read total_tiles
for t=1 to total_tiles
  read x,y,tile
  set matrix tile 2,x,y,tile
next t

 left_fairway:
 ` # of entries
  data 15
` x,y,tile #
 data 7,15,2,7,14,2,7,13,2,7,12,2,7,11,6
 data 8,15,2,8,14,2,8,13,2,8,12,6
 data 9,15,2,9,14,2,9,13,6
 data 10,15,2,10,14,6
 data 11,15,6
behind_green:
` # of entries
data 8
` x,y,tile #
data 43,3,13,43,2,13
data 44,3,13,44,2,19
data 45,3,19
data 46,4,19
data 47,5,19,47,4,2


right_fairway:
` # of entries
data 6
` x,y,tile #
data 8,4,19
data 9,5,19,9,4,2
data 24,5,18,24,4,2
data 25,4,18
update matrix 2
return
water:
` # of entries
data 30
` x,y,tile #
data 30,19,4,30,18,4,30,17,4,30,16,4,30,15,4,30,14,4,30,13,4,30,12,23
data 31,12,22,31,11,23
data 32,11,22,32,10,23
data 33,10,22,33,9,23
data 34,9,22,34,8,4,34,7,4,34,6,4,34,5,23
data 35,6,22,35,5,4
data 36,5,4,36,4,23
data 37,5,22,37,4,4,37,3,24
data 38,4,22,38,2,24
data 42,2,21
data 42,3,22

MAKE_TEXTURES:
` fairway grass
ink rgb(0,192,43),0
box 128,128,191,191 : ` 13
for i=1 to 1800
  ink rgb(0,rnd(40)+155,rnd(23)+20),0
  dot rnd(63)+128,rnd(63)+128
next i
get image 63,128,128,192,192
restore FG_PASTE_DATA
for i=1 to 15
  read x,y
  paste image 63,x,y
next i
FG_PASTE_DATA:
` 6,7,8,9,11,12,15,16,17,18,19,20
data 0,64,64,64,128,64,192,64,0,128,64,128,256,128,0,192,64,192,128,192,192,192,256,192
` 21, 22, 23
data 0,256,64,256,128,256

` lite grass - green
ink rgb(0,215,0),0
box 0,0,63,63 : ` 1 is the loneliest
for i=1 to 1750
  ink rgb(0,rnd(20)+200,0),0
  dot rnd(63),rnd(63)
next i
ink rgb(0,215,0),0
for t=0 to 63
  line 128+t,127-t,191,127-t : ` bottom right half of 8
  line 192+t,64,192+t,127-t : ` upper left half of 9
  line 64+t,128+t,127,128+t : ` upper right half of 12
  line 0,128+t,t,128+t : ` lower left 11
next t
` texture upper left half of 8
for i=1 to 850
  ink rgb(0,rnd(20)+200,0),0
  okay=0
  repeat
    x=rnd(63) : y=rnd(63)
    if y+x>63 then okay=1
  until okay=1
  dot x+128,y+64
next i
` texture upper left half of 9
for i=1 to 850
  ink rgb(0,rnd(20)+200,0),0
  okay=0
  repeat
    x=rnd(63) : y=rnd(63)
    if y+x<63 then okay=1
  until okay=1
  dot x+192,y+64
next i
` texture lower left half on 11
for i=1 to 850
  ink rgb(0,rnd(20)+200,0),0
  okay=0
  repeat
    x=rnd(63) : y=rnd(63)
    if y>x then okay=1
  until okay=1
  dot x,y+128
next i
` texture upper right half of 12
for i=1 to 850
  ink rgb(0,rnd(20)+200,0),0
  okay=0
  repeat
    x=rnd(63) : y=rnd(63)
    if y<x then okay=1
  until okay=1
  dot x+64,y+128
next i
` rough
ink rgb(0,128,0),0
`box 0,192,31,255 : ` fill 16
box 64,0,127,63     : ` 2
for i=1 to 1750
  ink rgb(rnd(10),rnd(20)+110,rnd(10)),0 : ` fix 2
  dot rnd(63)+64,rnd(63)
next i
ink rgb(0,128,0),0
box 96,192,127,255  : ` right half of 17
box 192,256,255,319 : ` fill 24
for t=0 to 63
  line 128,192+t,128+t,192+t : ` lower left 18
  line 192+t,255-t,255,255-t : ` lower right 19
  line 0,64+t,63-t,64+t      : ` upper left 6
  line 64+t,64+t,127,64+t    : ` upper right 7
  line 256,t,319-int(t/2),t  : ` upper left 5
  line 256,64+t,287-int(t/2),64+t : ` upper left 10
next t

` texture rough on 6
for i=1 to 850
  ink rgb(rnd(10),rnd(20)+110,rnd(10)),0
  okay=0
  repeat
    x=rnd(63) : y=rnd(63)
    if y+x<63 then okay=1
  until okay=1
  dot x,y+64
next i
` texture rough on 19
for i=1 to 850
  ink rgb(rnd(10),rnd(20)+110,rnd(10)),0
  okay=0
  repeat
    x=rnd(63) : y=rnd(63)
    if y+x>63 then okay=1
  until okay=1
  dot x+192,y+192
next i

` I tried to texture the rough on image texture #18, but DBC wouldn't let me!
` It turns the entire screen blue and looks awful
`texture rough on 18
`for i=1 to 850
`  okay=0
`  repeat
`    x=rnd(63) : y=rnd(63)
`    if y<x then okay=1
`  until okay=1
`   ink rgb(rnd(10),rnd(20)+110,rnd(10)),0
`   dot (x+128),(y+192)
`next i
` really dark green
ink rgb(0,96,0),0
box 192,128,255,191 : ` 14


` sand
ink rgb(255,255,128),0
box 128,0,191,63 : ` 3
for i=1 to 2350
  ink rgb(rnd(10)+245,rnd(10)+245,rnd(20)+108),0
  dot rnd(63)+128,rnd(63)
next i
ink rgb(255,255,128),0
for t=0 to 63
  line 256+t,128,256+t,191-t : ` upper left 15
  line 256+t,255-t,319,255-t : ` lower right 20
next t
` texture upper left on 15
for i=1 to 850
   ink rgb(rnd(10)+245,rnd(10)+245,rnd(20)+108),0
  okay=0
  repeat
    x=rnd(63) : y=rnd(63)
    if y+x<63 then okay=1
  until okay=1
  dot x+256,y+128
next i
` texture lower right half of 20
for i=1 to 850
   ink rgb(rnd(10)+245,rnd(10)+245,rnd(20)+108),0
  okay=0
  repeat
    x=rnd(63) : y=rnd(63)
    if y+x>63 then okay=1
  until okay=1
  dot x+256,y+192
next i
` water
ink rgb(0,64,190),0
box 192,0,255,63 : ` 4
for t=0 to 63
  line 192+t,256+t,255,256+t   : ` upper right 24
  line 128+t,256+t,191,256+t : ` upper right 23
  line 0,319-t,t,319-t      : ` upper left 21
  line 64,319-t,127-t,319-t    : ` lower left 22
next t
` texture lower left on 24
for i=1 to 850
   ink rgb(rnd(10),rnd(20)+110,rnd(10)),0
  okay=0
  repeat
    x=rnd(63) : y=rnd(63)
    if y>x then okay=1
  until okay=1
  dot x+192,y+256
next i
get image 1,0,0,320,320
PREPARE MATRIX TEXTURE 2, 1, 5, 5
`backdrop off
`sync
`wait key



` make flag
cls
ink rgb(200,43,28),0
box 0,0,24,24
ink rgb(255,255,255),0
set text size 14
text 10,2,"1"
get image 100,0,0,24,24
` flagstick
cls
ink rgb(255,255,255),0
box 0,0,1,1
box 0,4,1,5
box 0,8,1,9
ink rgb(220,0,0),0
box 0,2,1,3
box 0,6,1,7
box 0,10,1,11
get image 101,0,0,2,12
` sign
cls
ink rgb(128,64,0),0
box 0,0,255,155
ink rgb(255,255,94),0
box 10,10,245,145
ink rgb(225,225,225),0
box 11,11,244,82
ink rgb(94,255,255),0
box 11,21,244,72
set text size 36
set text font "Tahoma"
ink rgb(0,200,45),0
text 30,25,"Hole #1   Par 4"
set text size 28
ink rgb(255,0,0),0
box 15,98,22,105
ink rgb(0,0,199),0
box 15,128,22,135
ink rgb(26,97,220),0
text 27,86,"338 Yards"
text 27,116,"422 Yards"
set text size 11
text 235,135,"LB"
get image 102,0,0,256,156
return

MAKE_UNDULATIONS:
for count=1 to 44
  xrnd=rnd(11)+16
  yrnd=rnd(11)+4
  if count>30 then xrnd=rnd(7)+47
  rhgt#=((rnd(50)+40)/10)
  if rnd(100)>10 then rhgt#=0-rhgt#
  mhgt#=rhgt#/2
  lhgt#=rhgt#/2
  for i=(xrnd-3) to (xrnd+3)
    set matrix height 2,i,(yrnd-3),lhgt#
    set matrix height 2,i,(yrnd+3),lhgt#
  next i
  for i=(yrnd-3) to (yrnd+3)
    set matrix height 2,xrnd-3,i,lhgt#
    set matrix height 2,xrnd+3,i,lhgt#
  next i
  for i=(xrnd-2) to (xrnd+2)
    set matrix height 2,i,yrnd-2,mhgt#
    set matrix height 2,i,yrnd+2,mhgt#
  next i
  for i=(yrnd-2) to (yrnd+2)
    set matrix height 2,xrnd-2,i,mhgt#
    set matrix height 2,xrnd+2,i,mhgt#
  next i
  for t=(yrnd-1) to (yrnd+1)
    for i=(xrnd-1) to (xrnd+1)
      set matrix height 2,i,t,rhgt#
    next i
  next t
next count
update matrix 2
return
Rem **************************************************
Rem                  Smooth Matrix -  Thanks to TDK
Rem **************************************************
Smooth:
  Rem Averages matrix heights to remove jagged edges
  For Z=0 to TilesZ
    For X=0 to TilesX
      P0#=Get Matrix Height(2,X,Z):     Rem Current point height
      Rem Get 4 adjoining points heights (if they exist)
      If Z-1 > 0
        P1#=Get Matrix Height(2,X,Z-1)
      Else
        P1#=P0#
      Endif
      If X+1 < TilesX
        P2#=Get Matrix Height(2,X+1,Z)
      Else
        P2#=P0#
      Endif
      If Z+1 < TilesZ
        P3#=Get Matrix Height(2,X,Z+1)
      Else
        P3#=P0#
      Endif
      If X-1 > 0
        P4#=Get Matrix Height(2,X-1,Z)
      Else
        P4#=P0#
      Endif
      Average#=(P0#+P1#+P2#+P3#+P4#)/5: Rem Av height of other points
      Set Matrix Height 2,x,z,Average#
      MHeight#(X,Z)=Average#
    Next x
  Next z
Return

Normalise:
  Rem By Lee Bamber From DB Example - Adds shaded areas to matrix to give depth
  For z=1 to 20
    For x=1 to 60
      h8#=MHeight#(X,Z-1)
      h4#=MHeight#(X-1,Z)
      h#=MHeight#(X,Z)
      h2#=MHeight#(X,Z)
      x1#=(x-1)*25.0
      y1#=h#
      x2#=(x+0)*25.0
      y2#=h4#
      dx#=x2#-x1#
      dy#=y2#-y1#
      ax#=atanfull(dx#,dy#)
      ax#=wrapvalue(90-ax#)
      z1#=(z-1)*25.0
      y1#=h2#
      z2#=(z+0)*25.0
      y2#=h8#
      dz#=z2#-z1#
      dy#=y2#-y1#
      az#=atanfull(dz#,dy#)
      az#=wrapvalue(90-az#)
      nx#=sin(ax#)
      ny#=cos(ax#)
      nz#=sin(az#)
      Set matrix normal 2,x,z,nx#,ny#,nz#
    next x
  next z
  Update Matrix 2
return

remstart
   ==============================================================
   =  Title  : Single hole Golf ?
   =  Author : Latch Grapple
   =  Date   : 06/19/2007
   =  Update :
   =  Version:
   ==============================================================
   Comments    single hole for golf?  not finished
   ==============================================================
remend

rem =============================================================
rem = SET UP DISPLAY
rem =============================================================
   autocam off
   set display mode 800,600,32
   sync on
   sync rate 60

rem =============================================================
rem = MAIN
rem =============================================================
   gosub _textures
   gosub _matrix
   gosub _lighting

   camx#=500
   camy#=150
   camz#=1000

   position camera camx#,camy#,camz#
   do
      gosub _wave_matrix
      gosub _move_camera
      gosub _blow_flag



      sync
   loop

   end

rem =============================================================
rem = SUBROUTINES - PROCEDURES
rem =============================================================
`----------------------------------------------------------------
   _move_camera:
      yang#=wrapvalue(yang#+mousemovex())
      xang#=wrapvalue(xang#+mousemovey())
      if upkey()=1 then move camera 10
      if downkey()=1 then move camera -10
      yrotate camera yang#
      xrotate camera xang#
      y#=get ground height(1,camera position x(),camera position z())
      camx#=camera position x()
      camz#=camera position z()
      if camera position x() < 5 then camx#=10
      if camera position x() > 5995 then camx#=5995
      if camera position z() < 5 then camz#=5
      if camera position z() > 5995 then camz#=5995
      position camera camx#,y#+150,camz#

   return
`----------------------------------------------------------------
   _textures:
      create bitmap 1,600,600
      grass=1
      wbasin=2
      gosub _grass
      gosub _water_basin
      blur bitmap 1,3
      get image grass,0,0,600,600

      gosub _water
      gosub _green
      delete bitmap 1
   return
`----------------------------------------------------------------
   _grass:
      CLS RGB(0,20,0)
      For N=1 To 20000
         Ink RGB(Rnd(15),Rnd(60)+20,Rnd(5)),0
         Dot Rnd(599),Rnd(599)
      Next N
      ink rgb(22,121,4),0
      box 10,450,80,550
      ink RGB(22,80,4),0
      box 460,100,570,510
      for n=1 to 90
         line 100,600-n,500,(600-n)-90
      next n

   return
`----------------------------------------------------------------
   _water_basin:
      rem water
      r#=80
      while r# > 70
         r#=r#-.3
         while ang# < 360
            inc ang#,.1
            ink RGB(rnd(32)+50,rnd(16)+32,10),0
            x#=-1*(2*r#*(cos(ang#)-(.5*cos(2*ang#))))+200
            y#=(2*r#*(sin(ang#)-(.1*sin(2*ang#))))+300
            dot x#,y#
         endwhile
         ang#=-.1
         sync
      endwhile

   return
`----------------------------------------------------------------
   _green:
      cls rgb(0,70,0)
      make object sphere 3,1200
      scale object 3,100,15,100
      CLS RGB(0,95,0)
      For N=1 To 20000
         Ink RGB(Rnd(15),Rnd(10)+80,Rnd(5)),0
         Dot Rnd(255),Rnd(255)
      Next N
      green=3
      while image exist(green)=1
         inc green
      endwhile
      get image green,0,0,256,256
      texture object 3,green
      position object 3,5000,0,5000

      rem hole and flag
      cls 0
      make object cylinder 4,20
      position object 4,5000,81,5000
      color object 4,0

      make object cylinder 5,180
      scale object 5,2,100,2
      position object 5,5000,170,5000

      make object triangle 6,0,0,0,0,25,0,25,10,0
      make mesh from object 1,6

      add limb 5,1,1
      scale limb 5,1,9800,100,9800
      offset limb 5,1,0,60,0
      color limb 5,1,RGB(255,128,0)

      set object 5,1,1,0

      rem cleanup
      delete object 6
      delete mesh 1
   return
`-------------------------------------------------------------------
   _blow_flag:
      tilt=timer()

      if timer()>=rnd(10)+tilt
         yrotate object 5, wrapvalue(rnd(30)-15)
      endif

      if object angle y(5) >= 30 then yrotate object (5),0
   return
`-------------------------------------------------------------------
   rem water
   _water:
      cls rgb(0,30,50)

      for n=1 to 2000
         color=rgb(0,rnd(20),rnd(100))
         ink color,0
         x=rnd(127)
         y=rnd(127)
         dot x,y
      next n

      water=2
      while image exist(water)=1
         inc water
      endwhile

      get image water,0,0,128,128

      cls 0

      rem debris
      for n=1 to 200
         color=rgb(0,rnd(10),rnd(40))
         ink color,0
         x=rnd(127)
         y=rnd(127)
         dot x,y
      next n

      debris=2
      while image exist(debris)=1
         inc debris
      endwhile

      get image debris,0,0,128,128
   return
`----------------------------------------------------------------
   _matrix:
      randomize 10
      make matrix 1,6000,6000,60,60
      randomize matrix 1,60
      `SET MATRIX Matrix Number, Wireframe, Transparency, Cull, Filter, Light, Fog, Ambient
      rem set for transparency and light sensitivity
      set matrix 1,1,0,1,1,1,1,1
      prepare matrix texture 1,grass,60,60
      tilenum = -1
      rem tile matrix
      for z=59 to 0 step -1
         for x=0 to 59
            inc tilenum
            set matrix tile 1,x,z,tilenum
         next x
      next z
      update matrix 1

      rem flatten green area
      for z = 5 to 15
         for x = 1 to 9
            set matrix height 1,x,z,0
         next x
      next z
      update matrix 1

      for z = 10 to 49
         for x = 46 to 57
            set matrix height 1,x,z,0
         next x
      next z
      update matrix 1

      z=3
      for n=1 to 9
         for x=10 to 50
            if x=15 or x=30 or x=45
               inc z
            endif
            set matrix height 1,x,z,-5
         next x
         dec z,2
      next n

      update matrix 1


      rem carve out lake
      r#=8
      while r# > 0
         dec r#,.1
         while ang# < 360
            inc ang#,.1
            x=-1*(1.9*r#*(cos(ang#)-(.5*cos(2*ang#))))+21
            z=(2*r#*(sin(ang#)-(.1*sin(2*ang#))))+30
            set matrix height 1,x,z,-500
         endwhile
         ang#=-.1
      endwhile

      update matrix 1

      calc_mat_normals(1,60,60,30.0,30.0)
      smooth(1,60,60)

      gosub _bottom
      gosub _waves

   return
`----------------------------------------------------------------
   _bottom:
      make object plain 1,3600,3600
      set object 1,1,0,1
      xrotate object 1,90
      position object 1,2600,-400,3000
      texture object 1,debris
      ghost object on 1

      make object plain 2,3600,3600
      xrotate object 2,90
      position object 2,2600,-450,3000
      color object 2,90
   return
`----------------------------------------------------------------
   _waves:
      make matrix 2,3600,3600,10,10
      prepare matrix texture 2,water,10,10
      tilenum=0
      for z=9 to 0 step -1
         for x=0 to 9
            inc tilenum
            set matrix tile 2,x,z,tilenum
         next x
      next z
      position matrix 2,800,-350,1200
      ghost matrix on 2
      update matrix 2
   return
`----------------------------------------------------------------
   _wave_matrix:
   amp#=50

   for z = 0 to 10
      for x = 0 to 10

         rem set y sin value for matrix heights
         y#=amp#*sin(degrees)+phase#

         rem set matrix height
         set matrix height 2,z,x,y#
      next x

      rem increment degrees to calculate sin() for y#
      inc degrees,65
      if degrees >= 360
         degrees = wrapvalue(degrees)
         `update matrix 1
      endif

   next z
   update matrix 2

   rem scroll underwater plane
   scrl#=.0002
   scroll object texture 1,scrl#,scrl#

   return

`----------------------------------------------------------------
   _lighting:
      set camera range 1,10000
      set ambient light 30
      color light 0,rgb(255,255,255)
      set directional light 0,10,-6,0
      color backdrop rgb(32,32,32)
      fog on
      fog distance 5000

   return
rem =============================================================
rem = FUNCTIONS
rem =============================================================
   Function calc_mat_normals(mat,tilex,tilez,sizex#,sizez#)
   Rem By Lee Bamber From DB Example - Adds shaded areas to matrix to give depth
   rem added tile and tile size factor for normal depth adjustment - latch
      for z=1 to tilez
         for x=1 to tilex

            rem Get matrix heights
            h8#=get matrix height(mat,x,z-1)
            h4#=get matrix height(mat,x-1,z)
            h#=get matrix height(mat,x,z)
            h2#=get matrix height(mat,x,z)

            rem Calculate projected angle X using heights
            x1#=(x-1)*sizex# : y1#=h#
            x2#=(x+0)*sizex# : y2#=h4#
            dx#=x2#-x1#
            dy#=y2#-y1#
            ax#=atanfull(dx#,dy#)
            ax#=wrapvalue(90-ax#)

            rem Calculate projected angle Z using heights
            z1#=(z-1)*sizez# : y1#=h2#
            z2#=(z+0)*sizez# : y2#=h8#
            dz#=z2#-z1#
            dy#=y2#-y1#
            az#=atanfull(dz#,dy#)
            az#=wrapvalue(90-az#)

            rem Make normal from projected angle
            nx#=sin(ax#)
            ny#=cos(ax#)
            nz#=sin(az#)

            rem Setting matrix normal for smoothness
            set matrix normal mat,x,z,nx#,ny#,nz#

         next x
      next z
      update matrix mat
   EndFunction
`----------------------------------------------------------------
   function smooth(mat,tilex,tilez)
      rem TDK's average matrix points for smoothness routine
      Rem Averages matrix heights to remove jagged edges
      for Z=0 to tilez
         for X=0 to tilex
            P0#=Get Matrix Height(mat,X,Z):     Rem Current point height
            Rem Get 4 adjoining points heights (if they exist)
            If Z-1>=0
               P1#=Get Matrix Height(mat,X,Z-1)
            Else
               P1#=P0#
            Endif
            If X+1<=TilesX
               P2#=Get Matrix Height(mat,X+1,Z)
            Else
               P2#=P0#
            Endif
            If Z+1<=TilesZ
               P3#=Get Matrix Height(mat,X,Z+1)
            Else
               P3#=P0#
            Endif
            If X-1>=0
               P4#=Get Matrix Height(mat,X-1,Z)
            Else
               P4#=P0#
            Endif
            Average#=(P0#+P1#+P2#+P3#+P4#)/5: Rem Av height of other points
            RHeight#=Average#
            Set Matrix Height mat,x,z,RHeight#
         Next x
      Next z
      Update Matrix mat
   endfunction

rem =============================================================
rem = DATA STATEMENTS
rem =============================================================

 Latch 

 TDK