Sorry your browser is not supported!

Hi, i was wondering if this was possible with darkbasic as a lot of things can be created with it.

I know at least one game that did it, but you are a tornado, and your goal is to rack up as much damage as possible and become bigger.

So my question is could i create a tornado that you control RTS mouse click style with just darbasic?

*excluding graphics for texture

http://img256.imageshack.us/img256/442/zombiesmk8.jpg

Back to top

Profile PM Email

indi

22

Years of Service

User Offline

Joined: 26th Aug 2002

Location: Earth, Brisbane, Australia

Posted: 24th Mar 2007 03:20

yes that would be possible.

the tornados texture could be see through with ghost or fade object
the tornado could be rotated with rotate object
the tornado could be increased in size with scale object

a little bit of maths would draw in objects closer to its center via a distance function and a nice sin / cos approach

the RTS style movement has already been reproduced many times as snippets in areas of this forum

For objects within that game that were to tear apart would look better if they were limbed based objects combined to make the final models layout.

Back to top

Profile PM Email

Zombie 20

18

Years of Service

User Offline

Joined: 26th Nov 2006

Location: Etters, PA

Posted: 24th Mar 2007 07:20

cool thanks indi, although this is way out of my league as i'm a newb, but now that i know it can be done. I have something to look forward to.

http://img256.imageshack.us/img256/442/zombiesmk8.jpg

Back to top

Profile PM Email

RUCCUS

20

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 25th Mar 2007 06:43

Ok, this isnt going to be helpful at all, but I just mocked this up in the last 5 minutes, to give you an idea of just how fast you can make whatever you can think of once you learn the ins and outs of a language >>

setupGame()
createMapTexture()
createTornadoTexture()
createSkyTexture()
createMap()
createTornado()
createSky()
createDebris()

TYPE tornadoT
   x#,z#
   suckRadius#
   scale#
   maxScale#
   turnSpeed#
ENDTYPE
GLOBAL tornado AS tornadoT
tornado.suckRadius# = 100
tornado.scale# = 100
tornado.maxScale# = 300
tornado.turnSpeed# = 0.5
DO

controlTornado()
   storeData()
   handleCamera()
   collectDebris()
   handleSkysphere()

SYNC

LOOP

FUNCTION setupGame()
   SYNC ON:SYNC RATE 0:AUTOCAM OFF
   POSITION CAMERA 0,600,-800
   FOG ON
ENDFUNCTION

FUNCTION createMapTexture()
   FOR x = 1 TO 64
      FOR y = 1 TO 64
          DOT x,y,RGB(150,150,RND(155))
      NEXT y
   NEXT x

GET IMAGE 2,1,1,64,64
ENDFUNCTION

FUNCTION createMap()
   MAKE MATRIX 1,4000,4000,10,10
   RANDOMIZE MATRIX 1,50
   UPDATE MATRIX 1
   PREPARE MATRIX TEXTURE 1,2,1,1
ENDFUNCTION

FUNCTION createTornadoTexture()
   FOR x = 1 TO 64
      FOR y = 1 TO 64
         transparent = RND(1)
         IF transparent
            DOT x,y,RGB(000,000,000)
         ELSE
            DOT x,y,RGB(240,240,240)
         ENDIF
      NEXT y
   NEXT x

GET IMAGE 1,1,1,64,64
ENDFUNCTION

FUNCTION createTornado()
   MAKE OBJECT CONE 1,100
   XROTATE OBJECT 1,180
   SET OBJECT CULL 1,0
   TEXTURE OBJECT 1,1
   SET OBJECT TRANSPARENCY 1,1
   FIX OBJECT PIVOT 1
   POSITION OBJECT 1,2000,0,0
ENDFUNCTION

FUNCTION createSkyTexture()
   FOR x = 1 TO 64
      FOR y = 1 TO 64
          DOT x,y,RGB(RND(155),255,255)
      NEXT y
   NEXT x

GET IMAGE 3,1,1,64,64
ENDFUNCTION

FUNCTION createSky()
   MAKE OBJECT SPHERE 1000,4000
   SCALE OBJECT 1000,-100,-100,-100
   TEXTURE OBJECT 1000,3
   SET OBJECT LIGHT 1000,0
ENDFUNCTION

FUNCTION createDebris()
   FOR x = 2 TO 100
      obj = RND(2)
      IF obj = 0
         MAKE OBJECT SPHERE x,10+RND(10)
      ENDIF
      IF obj = 1
         MAKE OBJECT CUBE x,10+RND(10)
      ENDIF
      IF obj = 2
         MAKE OBJECT CYLINDER x,10+RND(10)
      ENDIF
      SET OBJECT CULL x,0
      ROTATE OBJECT x,RND(360),RND(360),RND(360)
      x# = RND(4000)
      z# = RND(4000)
      y# = GET GROUND HEIGHT(1,x#,z#) + (OBJECT SIZE Y(x)/2)
      POSITION OBJECT x,x#,y#,z#
   NEXT x
ENDFUNCTION

FUNCTION handleSkysphere()
   POSITION OBJECT 1000,tornado.x#,0,tornado.z#
   TURN OBJECT RIGHT 1000,.01
ENDFUNCTION

FUNCTION controlTornado()
   ROTATE LIMB 1,0,0,LIMB ANGLE Y(1,0)+tornado.turnSpeed#,0
   MOVE OBJECT 1,(KEYSTATE(17)-KEYSTATE(31))*0.5
   YROTATE OBJECT 1,OBJECT ANGLE Y(1)+((KEYSTATE(30)-KEYSTATE(32))*0.5)
   POSITION OBJECT 1,OBJECT POSITION X(1),GET GROUND HEIGHT(1,OBJECT POSITION X(1),OBJECT POSITION Z(1))+((OBJECT SIZE Y(1)/2)*(tornado.scale#/100)),OBJECT POSITION Z(1)
ENDFUNCTION

FUNCTION storeData()
   tornado.x# = OBJECT POSITION X(1)
   tornado.z# = OBJECT POSITION Z(1)
ENDFUNCTION

FUNCTION handleCamera()
   POSITION CAMERA tornado.x#,CAMERA POSITION Y(),tornado.z#
   ROTATE CAMERA 0,OBJECT ANGLE Y(1)-45,0
   MOVE CAMERA -600
   POINT CAMERA tornado.x#,50,tornado.z#
ENDFUNCTION

FUNCTION collectDebris()
   FOR x = 2 TO 100
      IF OBJECT EXIST(x)
         distance# = SQRT( ((OBJECT POSITION X(x)-tornado.x#)^2)+((OBJECT POSITION Z(x)-tornado.z#)^2) )
         IF distance# <= (tornado.suckRadius# * 2) * (tornado.scale#/100) AND distance# >= (tornado.suckRadius# /2) * (tornado.scale#/100)
            POINT OBJECT x,tornado.x#,50,tornado.z#
            MOVE OBJECT x,3
            MOVE OBJECT LEFT x,2
            IF distance# <= tornado.suckRadius# * (tornado.scale#/100)
               IF tornado.scale# < tornado.maxScale#
                  INC tornado.scale#,10
                  INC tornado.turnSpeed#,0.1
               ENDIF
               SCALE OBJECT 1,tornado.scale#,tornado.scale#,tornado.scale#
               DELETE OBJECT x
            ENDIF
         ENDIF
      ENDIF
   NEXT x
ENDFUNCTION

setupGame()
createMapTexture()
createTornadoTexture()
createSkyTexture()
createMap()
createTornado()
createSky()
createDebris()

TYPE tornadoT
   x#,z#
   suckRadius#
   scale#
   maxScale#
   turnSpeed#
ENDTYPE
GLOBAL tornado AS tornadoT
tornado.suckRadius# = 100
tornado.scale# = 100
tornado.maxScale# = 300
tornado.turnSpeed# = 0.5
DO

   controlTornado()
   storeData()
   handleCamera()
   collectDebris()
   handleSkysphere()

   SYNC

LOOP

FUNCTION setupGame()
   SYNC ON:SYNC RATE 0:AUTOCAM OFF
   POSITION CAMERA 0,600,-800
   FOG ON
ENDFUNCTION

FUNCTION createMapTexture()
   FOR x = 1 TO 64
      FOR y = 1 TO 64
          DOT x,y,RGB(150,150,RND(155))
      NEXT y
   NEXT x

   GET IMAGE 2,1,1,64,64
ENDFUNCTION

FUNCTION createMap()
   MAKE MATRIX 1,4000,4000,10,10
   RANDOMIZE MATRIX 1,50
   UPDATE MATRIX 1
   PREPARE MATRIX TEXTURE 1,2,1,1
ENDFUNCTION

FUNCTION createTornadoTexture()
   FOR x = 1 TO 64
      FOR y = 1 TO 64
         transparent = RND(1)
         IF transparent
            DOT x,y,RGB(000,000,000)
         ELSE
            DOT x,y,RGB(240,240,240)
         ENDIF
      NEXT y
   NEXT x

   GET IMAGE 1,1,1,64,64
ENDFUNCTION

FUNCTION createTornado()
   MAKE OBJECT CONE 1,100
   XROTATE OBJECT 1,180
   SET OBJECT CULL 1,0
   TEXTURE OBJECT 1,1
   SET OBJECT TRANSPARENCY 1,1
   FIX OBJECT PIVOT 1
   POSITION OBJECT 1,2000,0,0
ENDFUNCTION

FUNCTION createSkyTexture()
   FOR x = 1 TO 64
      FOR y = 1 TO 64
          DOT x,y,RGB(RND(155),255,255)
      NEXT y
   NEXT x

   GET IMAGE 3,1,1,64,64
ENDFUNCTION

FUNCTION createSky()
   MAKE OBJECT SPHERE 1000,4000
   SCALE OBJECT 1000,-100,-100,-100
   TEXTURE OBJECT 1000,3
   SET OBJECT LIGHT 1000,0
ENDFUNCTION

FUNCTION createDebris()
   FOR x = 2 TO 100
      obj = RND(2)
      IF obj = 0
         MAKE OBJECT SPHERE x,10+RND(10)
      ENDIF
      IF obj = 1
         MAKE OBJECT CUBE x,10+RND(10)
      ENDIF
      IF obj = 2
         MAKE OBJECT CYLINDER x,10+RND(10)
      ENDIF
      SET OBJECT CULL x,0
      ROTATE OBJECT x,RND(360),RND(360),RND(360)
      x# = RND(4000)
      z# = RND(4000)
      y# = GET GROUND HEIGHT(1,x#,z#) + (OBJECT SIZE Y(x)/2)
      POSITION OBJECT x,x#,y#,z#
   NEXT x
ENDFUNCTION

FUNCTION handleSkysphere()
   POSITION OBJECT 1000,tornado.x#,0,tornado.z#
   TURN OBJECT RIGHT 1000,.01
ENDFUNCTION

FUNCTION controlTornado()
   ROTATE LIMB 1,0,0,LIMB ANGLE Y(1,0)+tornado.turnSpeed#,0
   MOVE OBJECT 1,(KEYSTATE(17)-KEYSTATE(31))*0.5
   YROTATE OBJECT 1,OBJECT ANGLE Y(1)+((KEYSTATE(30)-KEYSTATE(32))*0.5)
   POSITION OBJECT 1,OBJECT POSITION X(1),GET GROUND HEIGHT(1,OBJECT POSITION X(1),OBJECT POSITION Z(1))+((OBJECT SIZE Y(1)/2)*(tornado.scale#/100)),OBJECT POSITION Z(1)
ENDFUNCTION

FUNCTION storeData()
   tornado.x# = OBJECT POSITION X(1)
   tornado.z# = OBJECT POSITION Z(1)
ENDFUNCTION

FUNCTION handleCamera()
   POSITION CAMERA tornado.x#,CAMERA POSITION Y(),tornado.z#
   ROTATE CAMERA 0,OBJECT ANGLE Y(1)-45,0
   MOVE CAMERA -600
   POINT CAMERA tornado.x#,50,tornado.z#
ENDFUNCTION

FUNCTION collectDebris()
   FOR x = 2 TO 100
      IF OBJECT EXIST(x)
         distance# = SQRT( ((OBJECT POSITION X(x)-tornado.x#)^2)+((OBJECT POSITION Z(x)-tornado.z#)^2) )
         IF distance# <= (tornado.suckRadius# * 2) * (tornado.scale#/100) AND distance# >= (tornado.suckRadius# /2) * (tornado.scale#/100)
            POINT OBJECT x,tornado.x#,50,tornado.z#
            MOVE OBJECT x,3
            MOVE OBJECT LEFT x,2
            IF distance# <= tornado.suckRadius# * (tornado.scale#/100)
               IF tornado.scale# < tornado.maxScale#
                  INC tornado.scale#,10
                  INC tornado.turnSpeed#,0.1
               ENDIF
               SCALE OBJECT 1,tornado.scale#,tornado.scale#,tornado.scale#
               DELETE OBJECT x
            ENDIF
         ENDIF
      ENDIF
   NEXT x
ENDFUNCTION

I dont recommend trying to learn from it, its very badly programmed, but if I spent 5 minutes on that, imagine what you could do in 5 weeks.

Back to top

Profile PM Email Website

Zombie 20

18

Years of Service

User Offline

Joined: 26th Nov 2006

Location: Etters, PA

Posted: 25th Mar 2007 07:47

Wow ruccus, you did that in five minutes? Oh boy, i couldn't code that much in 2 hours, but i see your point. I'm being paitent and reading just about every tutorial i can find, i've gone from strings and variables to setting up a small shooter.

Currently, my problem is 2d as I was told to start there before 3d. (even though i didn't listen

) Anyway, i'm a newb and i can admit that and i'm willing to do whatever it takes to get better, so if you guys have any tutorials in the works, i'd love to read them, i'm running out of things to read here lol.

By the way ruccus, your code stopped running, it had a problem with

TYPE tornadoT

it didn't seem to like it, and i don't know how to fix it.

http://img256.imageshack.us/img256/442/zombiesmk8.jpg

Back to top

Profile PM Email

Zombie 20

18

Years of Service

User Offline

Joined: 26th Nov 2006

Location: Etters, PA

Posted: 25th Mar 2007 09:43

hey ruccus, you're using dbpro aren't you, because types are global and only arrays are global in dbc.

http://img256.imageshack.us/img256/442/zombiesmk8.jpg

Back to top

Profile PM Email

RUCCUS

20

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 25th Mar 2007 15:08 Edited at: 25th Mar 2007 15:13

Ah yes I am, sorry about that I forgot this was the DBC board.

Id post a DBC-compatible version but it really isnt worth it, the code is buggy even, nothing to learn from.

Back to top

Profile PM Email Website

Zombie 20

18

Years of Service

User Offline

Joined: 26th Nov 2006

Location: Etters, PA

Posted: 25th Mar 2007 17:14

yea, i'm better off just experimenting.

http://img256.imageshack.us/img256/442/zombiesmk8.jpg

Back to top

Profile PM Email

Zombie 20

18

Years of Service

User Offline

Joined: 26th Nov 2006

Location: Etters, PA

Posted: 25th Mar 2007 18:59

hahaha, i had a thought. Was any of that code worth looking at for examples, because it looks like it had some good things in it.

arrgghh! my sig won't show, i'm very sad, it was so cool and it was a gift too.

img256.imageshack.us/img256/442/zombiesmk8.jpg

Back to top

Profile PM Email

RUCCUS

20

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 25th Mar 2007 19:55

Use the IMG tags for the sig,

[IMG]img256.imageshack.us/img256/442/zombiesmk8.jpg[/IMG]

Heres basically whats happening in the code for the example;

1. The tornado object is a cone, flipped upside down so it looks like a tornado. The map is a matrix. And the debris is 99 objects (numbered from 2 to 100) with random meshs (sphere, cylinder, or cube).

2. To make the tornado spin, you would think simply yrotating it using the yrotate object command would do the job. But in doing that, if you were to use the move object command to move the tornado forward/backward, it would move in a circle because it's constantly turning. Instead, yrotate limb was used, with object 1, limb 0. Rotating limb 0 only rotates the mesh, not the object's actual angle. Thus, the tornado still spins, but using the move object command will move it forward/backward in a straight line, since it's y angle remains at 0.

3. The debris is randomly positioned around the matrix.

4. The tornado is moved using a very generic movement routine (not RTS style btw).

The usual movement technique would be something like this (if you're using arrow keys):

tornadoObj = 1
speed = 1
IF UPKEY() = 1 THEN MOVE OBJECT tornadoObj, speed
IF DOWNKEY() = 1 THEN MOVE OBJECT tornadoObj, -speed

Which makes sense, and works. But it can be compacted into 1 line. If you figure that when a key is pressed it returns a 1, and when it isnt it returns a 0, then if you subtract the status of the downkey from the status of the upkey, what will you get? Well, when the upkey is pressed and the downkey isnt, its 1 - 0, you get 1. When the downkey is pressed and the upkey isnt, its 0 - 1, you get 0. When both are pressed, its 1 - 1, so 0. And when none are pressed its also 0 (0 - 0).

This number from the formula upkey-downkey can be used for the speed we move our object at. Like so;

speed = UPKEY() - DOWNKEY()
MOVE OBJECT 1,speed

If you want to move the object at speeds other than 1 or -1, you multiply speed by whatever speed you want to move at. If you want to move at 0.5 units per loop, you'd do speed = ( UPKEY() - DOWNKEY() ) * 0.5.

But there really isnt any need for the speed variable, you can just put the formula right into the move object command.

MOVE OBJECT 1, UPKEY() - DOWNKEY()

5. The tornado is rotated in much the same way. It uses leftkey-rightkey, which still generates either 1, -1, or 0. With this value you can use the YROTATE OBJECT command and use the value obtained, like so;

YROTATE OBJECT 1, OBJECT ANGLE Y(1) + (UPKEY()-DOWNKEY())

Why do we add the object's current y angle? Well the yrotate command isnt like the move command, yrotate will rotate an object on the y axis TO the specified degree, not BY the specified degree. So if we didnt add the object's current angle, it'd just constantly rotate to either 1 or -1. Hope that makes sense.

6. After the tornado is moved, a for loop is used, going from 2 to 100.

FOR x = 2 TO 100
   `code
NEXT x

We let x represent a debris object number. This allows us to basically cycle through each debris object. For each cycle, we get the distance from the tornado to the debris, and if the distance is less than the tornado's "suck distance" (set in a type, tornado.suckRadius#), we move the object towards the tornado.

Moving the object towards the tornado is done by using the point object command to point an object toward the tornado, and then the move object command. At the same all of the debris strafes left using the move object left command, giving it a "being sucked into a circular motion" effect.

Finally, we check if the debris object distance is less than or equal to the tornado's suck distance / 2. If so, the debris is inside the tornado, and so we delete the debris object.

7. The camera routine is pretty basic. First its positioned at the tornado's position, then its rotated to the tornado's y angle + 45. The +45 bit allows us to see the tornado from an angle, kind of like an RTS view. Then the cam is moved backwards by 600 units, and up by 500 units. Finally the cam is pointed towards the tornado. All of this combined makes the camera follow the tornado from a distance in the sky, constantly pointing towards it.

Hope that helps a bit, but like I said its not the best way to do things.

Back to top

Profile PM Email Website

Phaelax

DBPro Master

22

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 26th Mar 2007 02:03

I swiped the textures from Ruccus to save a bit a time. This tornado is created using many particles, which use a curved value to simulate more accurate movement.

createTornadoTexture()
createMapTexture()
createMap()

type Particle
   x as float
   y as float
   z as float
   a as float
   cs as float
endtype
dim particles(160) as Particle

for i = 1 to 10
   for j = 1 to 16
      inc t
      make object cube t, rnd(5)+2
      texture object t, 1
      set object transparency t,1
      particles(t).y = (i-1)*5
      particles(t).a = rnd(360)
      particles(t).cs = (i-1)*2
   next j
next i

sync on
sync rate 40
DO

if upkey() then inc z#,3
   if downkey() then dec z#,3
   if rightkey() then inc x#,3
   if leftkey() then dec x#,3

for t = 1 to 160
      particles(t).a = particles(t).a+7
      a# = particles(t).a
      dx# = x# + sin(a#)*particles(t).y
      dz# = z# + cos(a#)*particles(t).y
      particles(t).x = curvevalue(dx#, particles(t).x,  particles(t).cs)
      particles(t).z = curvevalue(dz#, particles(t).z,  particles(t).cs)
      position object t, particles(t).x,particles(t).y,particles(t).z
   next t

position camera x#,70,z#-130
   point camera x#,0,z#

SYNC
LOOP

FUNCTION createMapTexture()
   FOR x = 1 TO 64
      FOR y = 1 TO 64
          DOT x,y,RGB(150,150,RND(155))
      NEXT y
   NEXT x

GET IMAGE 2,1,1,64,64
ENDFUNCTION

FUNCTION createMap()
   MAKE MATRIX 1,4000,4000,10,10
   UPDATE MATRIX 1
   PREPARE MATRIX TEXTURE 1,2,1,1
ENDFUNCTION

FUNCTION createTornadoTexture()
   FOR x = 1 TO 64
      FOR y = 1 TO 64
         transparent = RND(1)
         IF transparent
            DOT x,y,RGB(000,000,000)
         ELSE
            DOT x,y,RGB(240,240,240)
         ENDIF
      NEXT y
   NEXT x

GET IMAGE 1,1,1,64,64
ENDFUNCTION

createTornadoTexture()
createMapTexture()
createMap()

type Particle
   x as float
   y as float
   z as float
   a as float
   cs as float
endtype
dim particles(160) as Particle


for i = 1 to 10
   for j = 1 to 16
      inc t
      make object cube t, rnd(5)+2
      texture object t, 1
      set object transparency t,1
      particles(t).y = (i-1)*5
      particles(t).a = rnd(360)
      particles(t).cs = (i-1)*2
   next j
next i

sync on
sync rate 40
DO

   if upkey() then inc z#,3
   if downkey() then dec z#,3
   if rightkey() then inc x#,3
   if leftkey() then dec x#,3



   for t = 1 to 160
      particles(t).a = particles(t).a+7
      a# = particles(t).a
      dx# = x# + sin(a#)*particles(t).y
      dz# = z# + cos(a#)*particles(t).y
      particles(t).x = curvevalue(dx#, particles(t).x,  particles(t).cs)
      particles(t).z = curvevalue(dz#, particles(t).z,  particles(t).cs)
      position object t, particles(t).x,particles(t).y,particles(t).z
   next t

   position camera x#,70,z#-130
   point camera x#,0,z#

   SYNC
LOOP

FUNCTION createMapTexture()
   FOR x = 1 TO 64
      FOR y = 1 TO 64
          DOT x,y,RGB(150,150,RND(155))
      NEXT y
   NEXT x

   GET IMAGE 2,1,1,64,64
ENDFUNCTION


FUNCTION createMap()
   MAKE MATRIX 1,4000,4000,10,10
   UPDATE MATRIX 1
   PREPARE MATRIX TEXTURE 1,2,1,1
ENDFUNCTION


FUNCTION createTornadoTexture()
   FOR x = 1 TO 64
      FOR y = 1 TO 64
         transparent = RND(1)
         IF transparent
            DOT x,y,RGB(000,000,000)
         ELSE
            DOT x,y,RGB(240,240,240)
         ENDIF
      NEXT y
   NEXT x

   GET IMAGE 1,1,1,64,64
ENDFUNCTION

Back to top

Profile PM Email Website

RUCCUS

20

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 26th Mar 2007 02:14

Thats pretty cool, next step is to make a tornado path

.

Back to top

Profile PM Email Website

Zombie 20

18

Years of Service

User Offline

Joined: 26th Nov 2006

Location: Etters, PA

Posted: 26th Mar 2007 02:16

Phaelax- Thank you for taking the time to optimize this code, but i have some bad news for you, i can't learn from or use it. It won't run in dbc becasue of types. Sorry.

Ruccus-Thak you again for such a detailed explination, i'm glad you all take the time to explain things, you don't have to, but you choose to take the time to help, and that means a lot.

By the way, would you like to join a community project that is being formed? Xenocythe,The Crazy, and myself are creating the first TGC Smash Bros. type game. Featuring heroes from darkbasic, we could use all the help avaialable, get the word out if you're interested.

[IMG]img256.imageshack.us/img256/442/zombiesmk8.jpg[/IMG]

Back to top

Profile PM Email

RUCCUS

20

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 26th Mar 2007 02:22

Quote: "the first TGC Smash Bros"

I beg to differ

Back to top

Profile PM Email Website

Zombie 20

18

Years of Service

User Offline

Joined: 26th Nov 2006

Location: Etters, PA

Posted: 26th Mar 2007 02:30 Edited at: 26th Mar 2007 02:30

sorry ruccus, didn't know. That is really cool looking, i like the rts style health bars and the chat function is cool.

so is this just some friendly reminders that you were first or would you like to join up with us?

I personally think everyone i've talked to is funny as hell and i would enjoy working with each and every one of them, but i understand that people do have lives.

Back to top

Profile PM Email

RUCCUS

20

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 26th Mar 2007 04:09

Sorry zombie, I really dont have the time right now.

i wasnt trying to prove I was first.... ok I kind of was but... ok yeah thats all I was really doing

.

Aye its pretty ironic, this community has enough extremely talented programmers on it that if they joined together, they could create a game that would rival next-gen games coming out now. Sadly though, its been attempted many times, and usually its either nobody has time, lack of leadership, or disagreement of gameplay techniques.

Back to top

Profile PM Email Website

Phaelax

DBPro Master

22

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 27th Mar 2007 05:02

Here's the tornado in DBC code. I actually had this ready last night, but when I exited DBC my screen remained black. All I had was a mouse arrow and so I had to reboot; no saved code. Didn't really have the patience to redo it at that moment.

createTornadoTexture()
createMapTexture()
createMap()

dim particles(160,5)

for i = 1 to 10
   for j = 1 to 16
      inc t
      make object cube t, rnd(5)+2
      texture object t, 1
      set object transparency t,1
      particles(t,2) = (i-1)*5
      particles(t,4) = rnd(360)
      particles(t,5) = (i-1)*2
   next j
next i

sync on
sync rate 40
DO

if upkey() then inc z#,3
   if downkey() then dec z#,3
   if rightkey() then inc x#,3
   if leftkey() then dec x#,3

for t = 1 to 160
      particles(t,4) = particles(t,4)+7
      a# = particles(t,4)
      dx# = x# + sin(a#)*particles(t,2)
      dz# = z# + cos(a#)*particles(t,2)
      particles(t,1) = curvevalue(dx#, particles(t,1), particles(t,5))
      particles(t,3) = curvevalue(dz#, particles(t,3), particles(t,5))
      position object t, particles(t,1), particles(t,2), particles(t,3)
   next t

position camera x#,70,z#-130
   point camera x#,0,z#

SYNC
LOOP

FUNCTION createMapTexture()
   FOR x = 1 TO 16
      FOR y = 1 TO 16
         ink RGB(150,150,RND(155)),0
         DOT x,y
      NEXT y
   NEXT x

GET IMAGE 2,1,1,16,16
ENDFUNCTION

FUNCTION createMap()
   MAKE MATRIX 1,4000,4000,10,10
   UPDATE MATRIX 1
   PREPARE MATRIX TEXTURE 1,2,1,1
ENDFUNCTION

FUNCTION createTornadoTexture()
   FOR x = 1 TO 16
      FOR y = 1 TO 16
         transparent = RND(1)
         IF transparent
            ink 0,0
            DOT x,y
         ELSE
            ink RGB(240,240,240), 0
            DOT x,y
         ENDIF
      NEXT y
   NEXT x

GET IMAGE 1,1,1,16,16
ENDFUNCTION

createTornadoTexture()
createMapTexture()
createMap()


dim particles(160,5)


for i = 1 to 10
   for j = 1 to 16
      inc t
      make object cube t, rnd(5)+2
      texture object t, 1
      set object transparency t,1
      particles(t,2) = (i-1)*5
      particles(t,4) = rnd(360)
      particles(t,5) = (i-1)*2
   next j
next i

sync on
sync rate 40
DO

   if upkey() then inc z#,3
   if downkey() then dec z#,3
   if rightkey() then inc x#,3
   if leftkey() then dec x#,3



   for t = 1 to 160
      particles(t,4) = particles(t,4)+7
      a# = particles(t,4)
      dx# = x# + sin(a#)*particles(t,2)
      dz# = z# + cos(a#)*particles(t,2)
      particles(t,1) = curvevalue(dx#, particles(t,1), particles(t,5))
      particles(t,3) = curvevalue(dz#, particles(t,3), particles(t,5))
      position object t, particles(t,1), particles(t,2), particles(t,3)
   next t

   position camera x#,70,z#-130
   point camera x#,0,z#

   SYNC
LOOP

FUNCTION createMapTexture()
   FOR x = 1 TO 16
      FOR y = 1 TO 16
         ink RGB(150,150,RND(155)),0
         DOT x,y
      NEXT y
   NEXT x

   GET IMAGE 2,1,1,16,16
ENDFUNCTION


FUNCTION createMap()
   MAKE MATRIX 1,4000,4000,10,10
   UPDATE MATRIX 1
   PREPARE MATRIX TEXTURE 1,2,1,1
ENDFUNCTION


FUNCTION createTornadoTexture()
   FOR x = 1 TO 16
      FOR y = 1 TO 16
         transparent = RND(1)
         IF transparent
            ink 0,0
            DOT x,y
         ELSE
            ink RGB(240,240,240), 0
            DOT x,y
         ENDIF
      NEXT y
   NEXT x

   GET IMAGE 1,1,1,16,16
ENDFUNCTION

Back to top

Profile PM Email Website

Zombie 20

18

Years of Service

User Offline

Joined: 26th Nov 2006

Location: Etters, PA

Posted: 27th Mar 2007 19:30

thank you very much, although, i don't know if i can fix it, but its bringing up an unreconized paramater on this line.

set object transparency t,1

which is a shame, because its really nice you went through all that to make it. Is there anything i can do?

Back to top

Profile PM Email

Phaelax

DBPro Master

22

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 27th Mar 2007 21:02

just change that to "ghost object on t"

Back to top

Profile PM Email Website

Zombie 20

18

Years of Service

User Offline

Joined: 26th Nov 2006

Location: Etters, PA

Posted: 27th Mar 2007 21:30 Edited at: 28th Mar 2007 21:09

oh cool, thanks

that is really asweome, i'm going to have a lot of fun just experimenting.

one more thing, i've read the code over several times and everything makes sense to me, my only problem is that i can't figure out how to work in making objects be drawn towards the vortex and adding a cube simulating a twister.

Back to top

Profile PM Email

Zombie 20

18

Years of Service

User Offline

Joined: 26th Nov 2006

Location: Etters, PA

Posted: 29th Mar 2007 02:12

a question, to make more things be picked up and added on, would i use glue object to limb?

Back to top

Profile PM Email

Phaelax

DBPro Master

22

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 29th Mar 2007 19:36

That depends what you want to do with the object you pick up. If you just want the object to disappear, then delete or hide the object. If you want it to become part of the tornado then you'll have to add it to the array like the rest of the cubes. You can add another element to the array dimension and use that to store the object numbers instead of just defining 1-160 like I did.

Back to top

Profile PM Email Website

Zombie 20

18

Years of Service

User Offline

Joined: 26th Nov 2006

Location: Etters, PA

Posted: 12th Apr 2007 15:59