coloring a cube - GameCreators Forum

Author

Message

Phantom 2590

17

Years of Service

User Offline

Joined: 19th Apr 2007

Location: Earth...

Posted: 20th Apr 2007 09:13

Link

I've tried finding this but I can't seem to find it mentioned anywhere. Is there a way to color a cube so each of the six sides have a different color.

Back to top

Profile PM Email

TDK

Retired Moderator

21

Years of Service

User Offline

Joined: 19th Nov 2002

Location: UK

Posted: 20th Apr 2007 19:13 Edited at: 20th Apr 2007 20:47

Link

DB primitives can only be coloured/textured as a whole. As such, you can't colour each side of a cube with a different colour.

Even when you load a texture, it applies the same texture on each of the six sides.

The easiest solution is to create your cube in a modelling program, colour the six sides as required, then save it out as a .X file to load into DB - where you would see the cube coloured correctly.

[Edit] Since posting this, I've now created a function to do this, (see next post), so the modelling option is no longer the easiest option!

TDK_Man

* TDK's Game Programming Forums - Open To All - DB & Team Request Boards *

Back to top

Profile PM Email Website

TDK

Retired Moderator

21

Years of Service

User Offline

Joined: 19th Nov 2002

Location: UK

Posted: 20th Apr 2007 20:32

Link

OK, I've just done an example to demonstrate doing it the hard way.

I've made it into a function, so you can copy it into your own program.

When you call it, please note that the first parameter is the object number and is an integer, while the second is the size - which must be a float.

Once the object is created, the cube is still referred to with the specified object number, (for scaling etc), but unlike a normal DB primitive cube it now has 6 limbs (sides) which are used when colouring or texturing.

Note: This code was written in DB Classic, but I can't think of any reason why it shouldn't work exactly the same in DBPro.

Rem Cube With Coloured Faces Example By TDK_Man
Sync On: AutoCam Off

Rem Call function with object number (integer) and size (float)
MakeLimbCube(1,2.0): Rem ObjectNumber (Int), Size (Float)

Rem Cube Sides Can Now Be Coloured (Or Textured) Via The 6 Limbs
Rem (You Could Also Use Texture Limb Instead Of Color Limb)
COLOR LIMB 1,1,RGB(0,0,255)
COLOR LIMB 1,2,RGB(255,0,0)
COLOR LIMB 1,3,RGB(0,255,0)
COLOR LIMB 1,4,RGB(0,255,255)
COLOR LIMB 1,5,RGB(255,0,255)
COLOR LIMB 1,6,RGB(255,255,0)

Rem Position Camera
Position Camera 0,5,-5
Point Camera 0,0,0

Do
  Rotate Object 1,WrapValue(Object Angle X(1)+1),WrapValue(Object Angle Y(1)+1),WrapValue(Object Angle Z(1)+1)
  Sync
Loop

Function MakeLimbCube(ObjNum,Size#)
  Offset#=Size#/2.0: MeshNum=2000: PlainNum=2000
  Make Object Cube ObjNum,Size#
  Make Object Plain PlainNum,Size#,Size#
  Make Mesh From Object MeshNum,PlainNum
  ADD LIMB ObjNum, 1, 2000: Offset Limb ObjNum,1,0,0,0.0-Offset#: Rem Cube Side 1 (Front)
  ADD LIMB ObjNum, 2, 2000: Rotate Limb ObjNum,2,0,90,0:  Offset Limb ObjNum,2,0.0-Offset#,0,0: Rem Cube Side 2 (Left)
  ADD LIMB ObjNum, 3, 2000: Rotate Limb ObjNum,3,0,180,0: Offset Limb ObjNum,3,0,0,Offset#:  Rem Cube Side 3 (Back)
  ADD LIMB ObjNum, 4, 2000: Rotate Limb ObjNum,4,0,270,0: Offset Limb ObjNum,4,Offset#,0,0:  Rem Cube Side 4 (Right)
  ADD LIMB ObjNum, 5, 2000: Rotate Limb ObjNum,5,270,0,0:  Offset Limb ObjNum,5,0,0.0-Offset#,0: Rem Cube Side 5 (Bottom)
  ADD LIMB ObjNum, 6, 2000: Rotate Limb ObjNum,6,90,0,0:  Offset Limb ObjNum,6,0,Offset#,0: Rem Cube Side 6 (Top)
  Delete Mesh MeshNum
  Delete Object PlainNum
  Hide Limb ObjNum,0
EndFunction

+ Code Snippet

Rem Cube With Coloured Faces Example By TDK_Man
Sync On: AutoCam Off

Rem Call function with object number (integer) and size (float)
MakeLimbCube(1,2.0): Rem ObjectNumber (Int), Size (Float)

Rem Cube Sides Can Now Be Coloured (Or Textured) Via The 6 Limbs
Rem (You Could Also Use Texture Limb Instead Of Color Limb)
COLOR LIMB 1,1,RGB(0,0,255)
COLOR LIMB 1,2,RGB(255,0,0)
COLOR LIMB 1,3,RGB(0,255,0)
COLOR LIMB 1,4,RGB(0,255,255)
COLOR LIMB 1,5,RGB(255,0,255)
COLOR LIMB 1,6,RGB(255,255,0)

Rem Position Camera
Position Camera 0,5,-5
Point Camera 0,0,0

Do
  Rotate Object 1,WrapValue(Object Angle X(1)+1),WrapValue(Object Angle Y(1)+1),WrapValue(Object Angle Z(1)+1)
  Sync
Loop

Function MakeLimbCube(ObjNum,Size#)
  Offset#=Size#/2.0: MeshNum=2000: PlainNum=2000
  Make Object Cube ObjNum,Size#
  Make Object Plain PlainNum,Size#,Size#
  Make Mesh From Object MeshNum,PlainNum
  ADD LIMB ObjNum, 1, 2000: Offset Limb ObjNum,1,0,0,0.0-Offset#: Rem Cube Side 1 (Front)
  ADD LIMB ObjNum, 2, 2000: Rotate Limb ObjNum,2,0,90,0:  Offset Limb ObjNum,2,0.0-Offset#,0,0: Rem Cube Side 2 (Left)
  ADD LIMB ObjNum, 3, 2000: Rotate Limb ObjNum,3,0,180,0: Offset Limb ObjNum,3,0,0,Offset#:  Rem Cube Side 3 (Back)
  ADD LIMB ObjNum, 4, 2000: Rotate Limb ObjNum,4,0,270,0: Offset Limb ObjNum,4,Offset#,0,0:  Rem Cube Side 4 (Right)
  ADD LIMB ObjNum, 5, 2000: Rotate Limb ObjNum,5,270,0,0:  Offset Limb ObjNum,5,0,0.0-Offset#,0: Rem Cube Side 5 (Bottom)
  ADD LIMB ObjNum, 6, 2000: Rotate Limb ObjNum,6,90,0,0:  Offset Limb ObjNum,6,0,Offset#,0: Rem Cube Side 6 (Top)
  Delete Mesh MeshNum
  Delete Object PlainNum
  Hide Limb ObjNum,0
EndFunction

TDK_Man

* TDK's Game Programming Forums - Open To All - DB & Team Request Boards *

Back to top

Profile PM Email Website

Phantom 2590

17

Years of Service

User Offline

Joined: 19th Apr 2007

Location: Earth...

Posted: 20th Apr 2007 21:16

Link

your first suggestion worked fine, i made a cube with six different colors and loaded it into my program
the harder was is well harder and it would kind of ruin my doe a bit as i need the cube to rotate at certain times
and since we're on the topic i might as well ask
here is my code:

`MANUALY SET SYNC RATE AND HIDE MOUSE
SYNC ON:SYNC RATE 0:HIDE MOUSE
`DEFINE USED VARIABLES
GREEN = RGB(0,255,0)
KEYVALUE = 0
`CREATE OBJECTS
MAKE OBJECT SPHERE 1,20:COLOR OBJECT 1,GREEN
LOAD OBJECT "cube.3ds",2
`POSITION ALL
POSITION OBJECT 1,0,0,0
POSITION OBJECT 2,0,-170,0
POSITION CAMERA 0,500,-500:POINT CAMERA 0,0,80
`MAIN LOOP
DO
   `CREATE VARIABLES USED FOR MOVEMENT
   ZPOSITION = OBJECT POSITION Z(1)
   XPOSITION = OBJECT POSITION X(1)
   `MOVEMENT
   IF UPKEY()=1 THEN KEYVALUE = 1
   IF DOWNKEY()=1 THEN KEYVALUE = 2
   IF RIGHTKEY()=1 THEN KEYVALUE = 3
   IF LEFTKEY()=1 THEN KEYVALUE = 4
   IF KEYVALUE = 1 THEN MOVE OBJECT 1,5
   IF KEYVALUE = 2 THEN MOVE OBJECT 1,-5
   IF KEYVALUE = 3 THEN MOVE OBJECT RIGHT 1,5
   IF KEYVALUE = 4 THEN MOVE OBJECT LEFT 1,5
   `ROTATE CUBE
   IF ZPOSITION>160 THEN YROTATE OBJECT 2,-90
   IF ZPOSITION<-160 THEN YROTATE OBJECT 2,90
   IF ZPOSITION>160 THEN YROTATE OBJECT 2,-90
   IF ZPOSITION<-160 THEN YROTATE OBJECT 2,90
   IF XPOSITION>160 THEN ZROTATE OBJECT 2,-90
   IF XPOSITION<-160 THEN ZROTATE OBJECT 2,90
   IF XPOSITION>160 THEN ZROTATE OBJECT 2,-90
   IF XPOSITION<-160 THEN ZROTATE OBJECT 2,90
   `REPOSITION SPHERE
   ZSPOT1 = OBJECT POSITION Z(1)
   XSPOT1 = OBJECT POSITION X(1)
   IF ZPOSITION>160 THEN POSITION OBJECT 1,XSPOT1,0,-160
   IF ZPOSITION<-160 THEN POSITION OBJECT 1,XSPOT1,0,160
   IF XPOSITION>160 THEN POSITION OBJECT 1,-160,0,ZSPOT1
   IF XPOSITION<-160 THEN POSITION OBJECT 1,160,0,ZSPOT1

SYNC
LOOP

+ Code Snippet

`MANUALY SET SYNC RATE AND HIDE MOUSE
SYNC ON:SYNC RATE 0:HIDE MOUSE
`DEFINE USED VARIABLES
GREEN = RGB(0,255,0)
KEYVALUE = 0
`CREATE OBJECTS
MAKE OBJECT SPHERE 1,20:COLOR OBJECT 1,GREEN
LOAD OBJECT "cube.3ds",2
`POSITION ALL
POSITION OBJECT 1,0,0,0
POSITION OBJECT 2,0,-170,0
POSITION CAMERA 0,500,-500:POINT CAMERA 0,0,80
`MAIN LOOP
DO
   `CREATE VARIABLES USED FOR MOVEMENT
   ZPOSITION = OBJECT POSITION Z(1)
   XPOSITION = OBJECT POSITION X(1)
   `MOVEMENT
   IF UPKEY()=1 THEN KEYVALUE = 1
   IF DOWNKEY()=1 THEN KEYVALUE = 2
   IF RIGHTKEY()=1 THEN KEYVALUE = 3
   IF LEFTKEY()=1 THEN KEYVALUE = 4
   IF KEYVALUE = 1 THEN MOVE OBJECT 1,5
   IF KEYVALUE = 2 THEN MOVE OBJECT 1,-5
   IF KEYVALUE = 3 THEN MOVE OBJECT RIGHT 1,5
   IF KEYVALUE = 4 THEN MOVE OBJECT LEFT 1,5
   `ROTATE CUBE
   IF ZPOSITION>160 THEN YROTATE OBJECT 2,-90
   IF ZPOSITION<-160 THEN YROTATE OBJECT 2,90
   IF ZPOSITION>160 THEN YROTATE OBJECT 2,-90
   IF ZPOSITION<-160 THEN YROTATE OBJECT 2,90
   IF XPOSITION>160 THEN ZROTATE OBJECT 2,-90
   IF XPOSITION<-160 THEN ZROTATE OBJECT 2,90
   IF XPOSITION>160 THEN ZROTATE OBJECT 2,-90
   IF XPOSITION<-160 THEN ZROTATE OBJECT 2,90
   `REPOSITION SPHERE
   ZSPOT1 = OBJECT POSITION Z(1)
   XSPOT1 = OBJECT POSITION X(1)
   IF ZPOSITION>160 THEN POSITION OBJECT 1,XSPOT1,0,-160
   IF ZPOSITION<-160 THEN POSITION OBJECT 1,XSPOT1,0,160
   IF XPOSITION>160 THEN POSITION OBJECT 1,-160,0,ZSPOT1
   IF XPOSITION<-160 THEN POSITION OBJECT 1,160,0,ZSPOT1

SYNC
LOOP

i have a green sphere which moves on its own a soon as a direction button is pressed and its position is changed when it gets to the end of the cube. the cube is supposed to rotate at the same time to give the effect that the sphere has gone on the next side of the cube, but with this code the cube only rotates twice at certain times. ive included the cube model so you may test it out

Attachments

Login to view attachments

Back to top

Profile PM Email

Phantom 2590

17

Years of Service

User Offline

Joined: 19th Apr 2007

Location: Earth...

Posted: 20th Apr 2007 21:28

Link

i attached a picture to sort of explain more of what i mean
the green sphere is going towards the red surface of the cube
i want the cube to rotate so the sphere is now on the red face moving along it, and kind of repeat it for each face
sorry if I'm way exceeding just asking for a little help but i'm really at a lost with this

Attachments

Login to view attachments

Back to top

Profile PM Email

TDK

Retired Moderator

21

Years of Service

User Offline

Joined: 19th Nov 2002

Location: UK

Posted: 21st Apr 2007 15:23

Link

Quote: "it would kind of ruin my doe a bit as i need the cube to rotate at certain times"

Not sure what you mean. The second method creates a modified cube yes - but it's still a DB primitive cube and can be controlled with all the DB object commands. So, you can turn the rotation on and off as and when you need to.

You can also change the colours without having to load it back into the modelling program.

Quote: "i want the cube to rotate"

The X/Y/Z centre of the cube's top surface is known and the top, bottom, left and right edge X and Z positions are known. So, once the sphere reaches any of these points you can rotate the cube in the direction denoted by the sphere's position.

The problem might be what happens to the sphere when the cube is rotating.

But do you need to see it rotate?

If not, it might be a lot easier to re-colour the cube sides as though the cube had rotated and reposition the sphere at the point it would have entered the new side.

This would be easy if you created the cube with my function, but, re-colouring a model would require loading it back into the modelling program.

TDK_Man

* TDK's Game Programming Forums - Open To All - DB & Team Request Boards *

Back to top

Profile PM Email Website

Phantom 2590

17

Years of Service

User Offline

Joined: 19th Apr 2007

Location: Earth...

Posted: 22nd Apr 2007 04:56

Link

did you happen to take a look at my code
what i am looking for is when the cube goes past a certain distance which is either past 160 or under -160 either direction (x or Z) then the sphere gets repositioned at the opposite edge (so if it was at 160 then it would go to -160) and the cube rotates from one face to the next at the same time.

not sure u understand what i'm trying to say

Back to top

Profile PM Email

TDK

Retired Moderator

21

Years of Service

User Offline

Joined: 19th Nov 2002

Location: UK

Posted: 22nd Apr 2007 22:21

Link

Yes - I'm sure I understand.

It's like the sphere is 'walking' around the cube only when it gets to the edge (and would be walking down one of the vertical sides), the cube rotates so the surface being walked on is always on the top. Right?

I'll see if I can knock an example snippet together for you...

TDK_Man

* TDK's Game Programming Forums - Open To All - DB & Team Request Boards *

Back to top

Profile PM Email Website

TDK

Retired Moderator

21

Years of Service

User Offline

Joined: 19th Nov 2002

Location: UK

Posted: 22nd Apr 2007 23:44 Edited at: 23rd Apr 2007 03:08

Link

OK, here's the snippet.

As usual, it's written in DB Classic - I'm going to install DBPro now to test it out - I believe the MakeLimbCube() function needs a little tweaking fir DBPro.

Even so, it should work enough as it is to see if what I think you are trying to do is what you are trying to do...

DB Classic Version:

Rem Rotating Cube Example For Phantom 2590
Rem DBC Version By TDK_Man

Gosub Setup

Do
  If ScanCode() <> 0 then Gosub MoveSphere
  Position Object 2,SpherePosX#,SpherePosY#,SpherePosZ#
  Sync
Loop
End

Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
Rem                                     PROCEDURES
Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

MoveSphere:
  If Leftkey() = 1 Then Dec SpherePosX#,0.4: If SpherePosX# < CubeLeftEdgeX# Then Gosub CubeRotate
  If Rightkey() = 1 Then Inc SpherePosX#,0.4: If SpherePosX# > CubeRightEdgeX# Then Gosub CubeRotate
  If Upkey() = 1 Then Inc SpherePosZ#,.4: If SpherePosZ# > CubeTopEdgeZ# Then Gosub CubeRotate
  If Downkey() = 1 Then Dec SpherePosZ#,.4: If SpherePosZ# < CubeBottomEdgeZ# Then Gosub CubeRotate
Return

CubeRotate:
  If SpherePosX# < CubeLeftEdgeX#
    Rem Hit Left Edge
    Hide Object 2
    For N=1 To 30
      ZRotate Object 1,WrapValue(Object Angle Z(1)-3)
      Sync
    Next N
    Fix Object Pivot 1
    SpherePosX# = CubeRightEdgeX#: Rem Jump Sphere To Opposite Side (Right)
    Show Object 2
  Endif
  If SpherePosX# > CubeRightEdgeX#
    Rem Hit Right Edge
    Hide Object 2
    For N=1 To 30
      ZRotate Object 1,WrapValue(Object Angle Z(1)+3)
      Sync
    Next N
    Fix Object Pivot 1
    SpherePosX# = CubeLeftEdgeX#: Rem Jump Sphere To Opposite Side (Left)
    Show Object 2
  Endif
  If SpherePosZ# > CubeTopEdgeZ#
    Rem Hit Top Edge
    Hide Object 2
    For N=1 To 30
      XRotate Object 1,WrapValue(Object Angle X(1)-3)
      Sync
    Next N
    Fix Object Pivot 1
    SpherePosZ# = CubeBottomEdgeZ#: Rem Jump Sphere To Opposite Side (Bottom)
    Show Object 2
  Endif
  If SpherePosZ# < CubeBottomEdgeZ#
    Rem Hit Bottom Edge
    Hide Object 2
    For N=1 To 30
      XRotate Object 1,WrapValue(Object Angle X(1)+3)
      Sync
    Next N
    Fix Object Pivot 1
    SpherePosZ# = CubeTopEdgeZ#: Rem Jump Sphere To Opposite Side (Top)
    Show Object 2
  Endif
Return

CreateObjects:
  MakeLimbCube(1,CubeSize#): Rem Create Cube
  Rem Now Colour The Six Sides
  COLOR LIMB 1,1,RGB(0,0,255)
  COLOR LIMB 1,2,RGB(255,0,0)
  COLOR LIMB 1,3,RGB(250,100,0)
  COLOR LIMB 1,4,RGB(0,255,255)
  COLOR LIMB 1,5,RGB(255,0,255)
  COLOR LIMB 1,6,RGB(255,255,0)
  Make Object Sphere 2,SphereSize#: Color Object 2,RGB(0,255,0): Rem Create Green Sphere
Return

Setup:
  Set Display Mode 800,600,32
  Sync On: Sync Rate 0: CLS 0
  AutoCam Off
  BackDrop On: Color BackDrop 0
  CubeSize# = 20.0: SphereSize# = 1.0
  CubeLeftEdgeX# = 0-(CubeSize#/2.0)
  CubeRightEdgeX# = CubeSize#/2.0
  CubeTopEdgeZ# = CubeSize#/2.0
  CubeBottomEdgeZ# = 0-(CubeSize#/2.0)
  SpherePosX# = 0.0
  SpherePosY# = (CubeSize#/2.0)+(SphereSize#/2.0)
  SpherePosZ# = 0.0
  Gosub CreateObjects
  Position Camera 0,40,-40
  Point Camera 0,0,0
Return

Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
Rem                                      FUNCTIONS
Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

Function MakeLimbCube(ObjNum,Size#)
  Offset#=Size#/2.0: MeshNum=2000: PlainNum=2000
  Make Object Cube ObjNum,Size#
  Make Object Plain PlainNum,Size#,Size#
  Make Mesh From Object MeshNum,PlainNum
  ADD LIMB ObjNum, 1, 2000: Offset Limb ObjNum,1,0,0,0.0-Offset#: Rem Cube Side 1 (Front)
  ADD LIMB ObjNum, 2, 2000: Rotate Limb ObjNum,2,0,90,0:  Offset Limb ObjNum,2,0.0-Offset#,0,0: Rem Cube Side 2 (Left)
  ADD LIMB ObjNum, 3, 2000: Rotate Limb ObjNum,3,0,180,0: Offset Limb ObjNum,3,0,0,Offset#:     Rem Cube Side 3 (Back)
  ADD LIMB ObjNum, 4, 2000: Rotate Limb ObjNum,4,0,270,0: Offset Limb ObjNum,4,Offset#,0,0:     Rem Cube Side 4 (Right)
  ADD LIMB ObjNum, 5, 2000: Rotate Limb ObjNum,5,270,0,0: Offset Limb ObjNum,5,0,0.0-Offset#,0: Rem Cube Side 5 (Bottom)
  ADD LIMB ObjNum, 6, 2000: Rotate Limb ObjNum,6,90,0,0:  Offset Limb ObjNum,6,0,Offset#,0:     Rem Cube Side 6 (Top)
  Delete Mesh MeshNum
  Delete Object PlainNum
  Hide Limb ObjNum,0
EndFunction

+ Code Snippet

Rem Rotating Cube Example For Phantom 2590
Rem DBC Version By TDK_Man

Gosub Setup

Do
  If ScanCode() <> 0 then Gosub MoveSphere
  Position Object 2,SpherePosX#,SpherePosY#,SpherePosZ#
  Sync
Loop
End


Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
Rem                                     PROCEDURES
Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

MoveSphere:
  If Leftkey() = 1 Then Dec SpherePosX#,0.4: If SpherePosX# < CubeLeftEdgeX# Then Gosub CubeRotate
  If Rightkey() = 1 Then Inc SpherePosX#,0.4: If SpherePosX# > CubeRightEdgeX# Then Gosub CubeRotate
  If Upkey() = 1 Then Inc SpherePosZ#,.4: If SpherePosZ# > CubeTopEdgeZ# Then Gosub CubeRotate
  If Downkey() = 1 Then Dec SpherePosZ#,.4: If SpherePosZ# < CubeBottomEdgeZ# Then Gosub CubeRotate
Return

CubeRotate:
  If SpherePosX# < CubeLeftEdgeX#
    Rem Hit Left Edge
    Hide Object 2
    For N=1 To 30
      ZRotate Object 1,WrapValue(Object Angle Z(1)-3)
      Sync
    Next N
    Fix Object Pivot 1
    SpherePosX# = CubeRightEdgeX#: Rem Jump Sphere To Opposite Side (Right)
    Show Object 2
  Endif
  If SpherePosX# > CubeRightEdgeX#
    Rem Hit Right Edge
    Hide Object 2
    For N=1 To 30
      ZRotate Object 1,WrapValue(Object Angle Z(1)+3)
      Sync
    Next N
    Fix Object Pivot 1
    SpherePosX# = CubeLeftEdgeX#: Rem Jump Sphere To Opposite Side (Left)
    Show Object 2
  Endif
  If SpherePosZ# > CubeTopEdgeZ#
    Rem Hit Top Edge
    Hide Object 2
    For N=1 To 30
      XRotate Object 1,WrapValue(Object Angle X(1)-3)
      Sync
    Next N
    Fix Object Pivot 1
    SpherePosZ# = CubeBottomEdgeZ#: Rem Jump Sphere To Opposite Side (Bottom)
    Show Object 2
  Endif
  If SpherePosZ# < CubeBottomEdgeZ#
    Rem Hit Bottom Edge
    Hide Object 2
    For N=1 To 30
      XRotate Object 1,WrapValue(Object Angle X(1)+3)
      Sync
    Next N
    Fix Object Pivot 1
    SpherePosZ# = CubeTopEdgeZ#: Rem Jump Sphere To Opposite Side (Top)
    Show Object 2
  Endif
Return

CreateObjects:
  MakeLimbCube(1,CubeSize#): Rem Create Cube
  Rem Now Colour The Six Sides
  COLOR LIMB 1,1,RGB(0,0,255)
  COLOR LIMB 1,2,RGB(255,0,0)
  COLOR LIMB 1,3,RGB(250,100,0)
  COLOR LIMB 1,4,RGB(0,255,255)
  COLOR LIMB 1,5,RGB(255,0,255)
  COLOR LIMB 1,6,RGB(255,255,0)
  Make Object Sphere 2,SphereSize#: Color Object 2,RGB(0,255,0): Rem Create Green Sphere
Return

Setup:
  Set Display Mode 800,600,32
  Sync On: Sync Rate 0: CLS 0
  AutoCam Off
  BackDrop On: Color BackDrop 0
  CubeSize# = 20.0: SphereSize# = 1.0
  CubeLeftEdgeX# = 0-(CubeSize#/2.0)
  CubeRightEdgeX# = CubeSize#/2.0
  CubeTopEdgeZ# = CubeSize#/2.0
  CubeBottomEdgeZ# = 0-(CubeSize#/2.0)
  SpherePosX# = 0.0
  SpherePosY# = (CubeSize#/2.0)+(SphereSize#/2.0)
  SpherePosZ# = 0.0
  Gosub CreateObjects
  Position Camera 0,40,-40
  Point Camera 0,0,0
Return

Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
Rem                                      FUNCTIONS
Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

Function MakeLimbCube(ObjNum,Size#)
  Offset#=Size#/2.0: MeshNum=2000: PlainNum=2000
  Make Object Cube ObjNum,Size#
  Make Object Plain PlainNum,Size#,Size#
  Make Mesh From Object MeshNum,PlainNum
  ADD LIMB ObjNum, 1, 2000: Offset Limb ObjNum,1,0,0,0.0-Offset#: Rem Cube Side 1 (Front)
  ADD LIMB ObjNum, 2, 2000: Rotate Limb ObjNum,2,0,90,0:  Offset Limb ObjNum,2,0.0-Offset#,0,0: Rem Cube Side 2 (Left)
  ADD LIMB ObjNum, 3, 2000: Rotate Limb ObjNum,3,0,180,0: Offset Limb ObjNum,3,0,0,Offset#:     Rem Cube Side 3 (Back)
  ADD LIMB ObjNum, 4, 2000: Rotate Limb ObjNum,4,0,270,0: Offset Limb ObjNum,4,Offset#,0,0:     Rem Cube Side 4 (Right)
  ADD LIMB ObjNum, 5, 2000: Rotate Limb ObjNum,5,270,0,0: Offset Limb ObjNum,5,0,0.0-Offset#,0: Rem Cube Side 5 (Bottom)
  ADD LIMB ObjNum, 6, 2000: Rotate Limb ObjNum,6,90,0,0:  Offset Limb ObjNum,6,0,Offset#,0:     Rem Cube Side 6 (Top)
  Delete Mesh MeshNum
  Delete Object PlainNum
  Hide Limb ObjNum,0
EndFunction

[Edit] DB Pro Version:

Rem Rotating Cube Example For Phantom 2590
Rem DB Pro Version By TDK_Man

Gosub Setup

Do
  If ScanCode() <> 0 then Gosub MoveSphere
  Position Object 2,SpherePosX#,SpherePosY#,SpherePosZ#
  rem Text 0,0,"X: "+Str$(Object Angle X(1))+"  Y: "+Str$(Object Angle Y(1))+"  Z: "+Str$(Object Angle Z(1))+"    "
  Sync
Loop
End

Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
Rem                                     PROCEDURES
Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

MoveSphere:
  If Leftkey() = 1 Then Dec SpherePosX#,0.4: If SpherePosX# < CubeLeftEdgeX# Then Gosub CubeRotate
  If Rightkey() = 1 Then Inc SpherePosX#,0.4: If SpherePosX# > CubeRightEdgeX# Then Gosub CubeRotate
  If Upkey() = 1 Then Inc SpherePosZ#,.4: If SpherePosZ# > CubeTopEdgeZ# Then Gosub CubeRotate
  If Downkey() = 1 Then Dec SpherePosZ#,.4: If SpherePosZ# < CubeBottomEdgeZ# Then Gosub CubeRotate
Return

CubeRotate:
  If SpherePosX# < CubeLeftEdgeX#
    Rem Hit Left Edge So Rotate On Z Axis
    Hide Object 2
    For N=1 To 30
      ZRotate Object 1,WrapValue(Object Angle Z(1)-3)
      Sync
    Next N
    SpherePosX# = CubeRightEdgeX#: Rem Jump Sphere To Opposite Side (Right)
    Show Object 2
  Endif

If SpherePosX# > CubeRightEdgeX#
    Rem Hit Right Edge
    Hide Object 2
    For N=1 To 30
      ZRotate Object 1,WrapValue(Object Angle Z(1)+3)
      Sync
    Next N
    SpherePosX# = CubeLeftEdgeX#: Rem Jump Sphere To Opposite Side (Left)
    Show Object 2
  Endif

If SpherePosZ# > CubeTopEdgeZ#
    Rem Hit Top Edge
    Hide Object 2
    For N=1 To 30
      XRotate Object 1,WrapValue(Object Angle X(1)-3)
      Sync
    Next N
    SpherePosZ# = CubeBottomEdgeZ#: Rem Jump Sphere To Opposite Side (Bottom)
    Show Object 2
  Endif

If SpherePosZ# < CubeBottomEdgeZ#
    Rem Hit Bottom Edge
    Hide Object 2
    For N=1 To 30
      XRotate Object 1,WrapValue(Object Angle X(1)+3)
      Sync
    Next N
    SpherePosZ# = CubeTopEdgeZ#: Rem Jump Sphere To Opposite Side (Top)
    Show Object 2
  Endif
Return

CreateObjects:
  MakeLimbCube(1,CubeSize#): Rem Create Cube
  Rem Now Colour The Six Sides
  COLOR LIMB 1,1,RGB(0,0,255)
  COLOR LIMB 1,2,RGB(255,0,0)
  COLOR LIMB 1,3,RGB(250,100,0)
  COLOR LIMB 1,4,RGB(0,255,255)
  COLOR LIMB 1,5,RGB(255,0,255)
  COLOR LIMB 1,6,RGB(255,255,0)
  Make Object Sphere 2,SphereSize#: Color Object 2,RGB(0,255,0): Rem Create Green Sphere
Return

Setup:
  Set Display Mode 800,600,32
  Sync On: Sync Rate 60: CLS 0
  AutoCam Off
  BackDrop On: Color BackDrop 0
  CubeSize# = 20.0: SphereSize# = 1.0
  CubeLeftEdgeX# = 0-(CubeSize#/2.0)
  CubeRightEdgeX# = CubeSize#/2.0
  CubeTopEdgeZ# = CubeSize#/2.0
  CubeBottomEdgeZ# = 0-(CubeSize#/2.0)
  SpherePosX# = 0.0
  SpherePosY# = (CubeSize#/2.0)+(SphereSize#/2.0)
  SpherePosZ# = 0.0
  Gosub CreateObjects
  Position Camera 0,40,-40
  Point Camera 0,0,0
Return

Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
Rem                                      FUNCTIONS
Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

Function MakeLimbCube(ObjNum,Size#)
  Offset#=Size#/2.0: MeshNum=2000: PlainNum=2000
  Make Object Cube ObjNum,Size#
  Make Object Plain PlainNum,Size#,Size#
  Make Mesh From Object MeshNum,PlainNum
  ADD LIMB ObjNum, 1, 2000: Offset Limb ObjNum,1,0,0,0.0-Offset#: Rem Cube Side 1 (Front)
  ADD LIMB ObjNum, 2, 2000: Rotate Limb ObjNum,2,0,90,0:  Offset Limb ObjNum,2,0.0-Offset#,0,0: Rem Cube Side 2 (Left)
  ADD LIMB ObjNum, 3, 2000: Rotate Limb ObjNum,3,0,180,0: Offset Limb ObjNum,3,0,0,Offset#:     Rem Cube Side 3 (Back)
  ADD LIMB ObjNum, 4, 2000: Rotate Limb ObjNum,4,0,270,0: Offset Limb ObjNum,4,Offset#,0,0:     Rem Cube Side 4 (Right)
  ADD LIMB ObjNum, 5, 2000: Rotate Limb ObjNum,5,270,0,0: Offset Limb ObjNum,5,0,0.0-Offset#,0: Rem Cube Side 5 (Bottom)
  ADD LIMB ObjNum, 6, 2000: Rotate Limb ObjNum,6,90,0,0:  Offset Limb ObjNum,6,0,Offset#,0:     Rem Cube Side 6 (Top)
  Set Object Cull ObjNum,0
  Delete Mesh MeshNum
  Delete Object PlainNum
  Hide Limb ObjNum,0
EndFunction

+ Code Snippet

Rem Rotating Cube Example For Phantom 2590
Rem DB Pro Version By TDK_Man

Gosub Setup

Do
  If ScanCode() <> 0 then Gosub MoveSphere
  Position Object 2,SpherePosX#,SpherePosY#,SpherePosZ#
  rem Text 0,0,"X: "+Str$(Object Angle X(1))+"  Y: "+Str$(Object Angle Y(1))+"  Z: "+Str$(Object Angle Z(1))+"    "
  Sync
Loop
End


Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
Rem                                     PROCEDURES
Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

MoveSphere:
  If Leftkey() = 1 Then Dec SpherePosX#,0.4: If SpherePosX# < CubeLeftEdgeX# Then Gosub CubeRotate
  If Rightkey() = 1 Then Inc SpherePosX#,0.4: If SpherePosX# > CubeRightEdgeX# Then Gosub CubeRotate
  If Upkey() = 1 Then Inc SpherePosZ#,.4: If SpherePosZ# > CubeTopEdgeZ# Then Gosub CubeRotate
  If Downkey() = 1 Then Dec SpherePosZ#,.4: If SpherePosZ# < CubeBottomEdgeZ# Then Gosub CubeRotate
Return

CubeRotate:
  If SpherePosX# < CubeLeftEdgeX#
    Rem Hit Left Edge So Rotate On Z Axis
    Hide Object 2
    For N=1 To 30
      ZRotate Object 1,WrapValue(Object Angle Z(1)-3)
      Sync
    Next N
    SpherePosX# = CubeRightEdgeX#: Rem Jump Sphere To Opposite Side (Right)
    Show Object 2
  Endif

  If SpherePosX# > CubeRightEdgeX#
    Rem Hit Right Edge
    Hide Object 2
    For N=1 To 30
      ZRotate Object 1,WrapValue(Object Angle Z(1)+3)
      Sync
    Next N
    SpherePosX# = CubeLeftEdgeX#: Rem Jump Sphere To Opposite Side (Left)
    Show Object 2
  Endif

  If SpherePosZ# > CubeTopEdgeZ#
    Rem Hit Top Edge
    Hide Object 2
    For N=1 To 30
      XRotate Object 1,WrapValue(Object Angle X(1)-3)
      Sync
    Next N
    SpherePosZ# = CubeBottomEdgeZ#: Rem Jump Sphere To Opposite Side (Bottom)
    Show Object 2
  Endif

  If SpherePosZ# < CubeBottomEdgeZ#
    Rem Hit Bottom Edge
    Hide Object 2
    For N=1 To 30
      XRotate Object 1,WrapValue(Object Angle X(1)+3)
      Sync
    Next N
    SpherePosZ# = CubeTopEdgeZ#: Rem Jump Sphere To Opposite Side (Top)
    Show Object 2
  Endif
Return

CreateObjects:
  MakeLimbCube(1,CubeSize#): Rem Create Cube
  Rem Now Colour The Six Sides
  COLOR LIMB 1,1,RGB(0,0,255)
  COLOR LIMB 1,2,RGB(255,0,0)
  COLOR LIMB 1,3,RGB(250,100,0)
  COLOR LIMB 1,4,RGB(0,255,255)
  COLOR LIMB 1,5,RGB(255,0,255)
  COLOR LIMB 1,6,RGB(255,255,0)
  Make Object Sphere 2,SphereSize#: Color Object 2,RGB(0,255,0): Rem Create Green Sphere
Return

Setup:
  Set Display Mode 800,600,32
  Sync On: Sync Rate 60: CLS 0
  AutoCam Off
  BackDrop On: Color BackDrop 0
  CubeSize# = 20.0: SphereSize# = 1.0
  CubeLeftEdgeX# = 0-(CubeSize#/2.0)
  CubeRightEdgeX# = CubeSize#/2.0
  CubeTopEdgeZ# = CubeSize#/2.0
  CubeBottomEdgeZ# = 0-(CubeSize#/2.0)
  SpherePosX# = 0.0
  SpherePosY# = (CubeSize#/2.0)+(SphereSize#/2.0)
  SpherePosZ# = 0.0
  Gosub CreateObjects
  Position Camera 0,40,-40
  Point Camera 0,0,0
Return

Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
Rem                                      FUNCTIONS
Rem * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *

Function MakeLimbCube(ObjNum,Size#)
  Offset#=Size#/2.0: MeshNum=2000: PlainNum=2000
  Make Object Cube ObjNum,Size#
  Make Object Plain PlainNum,Size#,Size#
  Make Mesh From Object MeshNum,PlainNum
  ADD LIMB ObjNum, 1, 2000: Offset Limb ObjNum,1,0,0,0.0-Offset#: Rem Cube Side 1 (Front)
  ADD LIMB ObjNum, 2, 2000: Rotate Limb ObjNum,2,0,90,0:  Offset Limb ObjNum,2,0.0-Offset#,0,0: Rem Cube Side 2 (Left)
  ADD LIMB ObjNum, 3, 2000: Rotate Limb ObjNum,3,0,180,0: Offset Limb ObjNum,3,0,0,Offset#:     Rem Cube Side 3 (Back)
  ADD LIMB ObjNum, 4, 2000: Rotate Limb ObjNum,4,0,270,0: Offset Limb ObjNum,4,Offset#,0,0:     Rem Cube Side 4 (Right)
  ADD LIMB ObjNum, 5, 2000: Rotate Limb ObjNum,5,270,0,0: Offset Limb ObjNum,5,0,0.0-Offset#,0: Rem Cube Side 5 (Bottom)
  ADD LIMB ObjNum, 6, 2000: Rotate Limb ObjNum,6,90,0,0:  Offset Limb ObjNum,6,0,Offset#,0:     Rem Cube Side 6 (Top)
  Set Object Cull ObjNum,0
  Delete Mesh MeshNum
  Delete Object PlainNum
  Hide Limb ObjNum,0
EndFunction

Note: At some cube angles, rotation is incorrect but I didn't have time to look into it in any great detail. It might be better to use Pitch and Roll instead of the Rotate commands, but I'll leave that for you.

TDK_Man

* TDK's Game Programming Forums - Open To All - DB & Team Request Boards *

Back to top

Profile PM Email Website

Sorry your browser is not supported!

Newcomers DBPro Corner / coloring a cube

Attachments

Attachments