Line Creation - GameCreators Forum

Author

Message

vorconan

17

Years of Service

User Offline

Joined: 4th Nov 2006

Location: Wales

Posted: 11th May 2007 00:31 Edited at: 11th May 2007 00:32

Link

Hi,

I'm creating an art program (my first major program

) except I have immediately run into a problem, I have 2 tools working, but my line tool isn't, I'm afraid to say.

Here is the code

+ Code Snippet

function linetool()
   if mousex()>30
      if mouseclick()=1
         mousex()=omxp
         mousey()=omyp
         if mouseclick()=1
            line omxp,omyp,mousex(),mousey()
         endif
      endif
   endif
endfunction

I assumed that when the mouse was first clicked it would store the positions in variables which would be used as x1 and y1.Then the second mouse click would use the current mouse position as the x2 and y2 co-ordinates. But with this code, the line always starts at the position 0,0. It ends in the current mouse position fine, just that starting problem.

Any help would be greatly appreciated, thanks.

Edit - The mousex()>30 is only there because I have a toolbar on the left side of the screen.

Back to top

Profile PM Email

Soldier X1

18

Years of Service

User Offline

Joined: 10th Oct 2005

Location:

Posted: 11th May 2007 00:36 Edited at: 11th May 2007 00:37

Link

Looks to me like you are assigning values to functions...

+ Code Snippet

 mousex()=omxp
         mousey()=omyp

should be...

+ Code Snippet

 omxp = mousex()
         omyp = mousey()

Let me know if that helped.

Back to top

Profile PM

vorconan

17

Years of Service

User Offline

Joined: 4th Nov 2006

Location: Wales

Posted: 11th May 2007 00:40

Link

Thanks for the effort but unfortunately the line doesn't even appear now.

Back to top

Profile PM Email

Soldier X1

18

Years of Service

User Offline

Joined: 10th Oct 2005

Location:

Posted: 11th May 2007 00:58 Edited at: 11th May 2007 01:03

Link

Perhaps the problem is that you aren't getting two different mouse clicks... I say loop it and then after you have two mouse clicks then have the code that draws the line.

Ya see what happend first is that omxp and omyp is zero so that is why it started at 0,0... now with the modified code I gave you are now just getting like a dot because omxp and the other is the same as mousex() and y so you need to get a second mouse click and it should work.

Back to top

Profile PM

Zergei

19

Years of Service

User Offline

Joined: 9th Feb 2005

Location: Everywhere

Posted: 11th May 2007 01:17

Link

Try something like this...

+ Code Snippet


global drawing as logic
global omxp
global omyp

function linetool()
   if mousex()>30
      if mouseclick()=1
        if drawing=false
         mousex()=omxp
         mousey()=omyp
         drawing=true
        else
         line omxp,omyp,mousex(),mousey()
         drawing=false
         omxp=0
         omyp=0
        endif
      endif
   endif
endfunction

This is untested code, i'll try it out once arrived at home, and update accordingly.
The main problem might be that omxp and omyp are local variables, so they lose the value after exiting the function. The second reason is that it enters the second "if mouseclick()" as the program continues on without waiting for another instruction, such as the click of the mouse.

If you need a better explanaition of it, just ask. Hope it helps...

Further on my stuff at...

Back to top

Profile PM Email Website

vorconan

17

Years of Service

User Offline

Joined: 4th Nov 2006

Location: Wales

Posted: 11th May 2007 01:29

Link

No, it didn't work. Thanks for the try though. I really don't see how this isn't working, just wondering as well Zergei, why do you suggest that omxp and omyp have to be global variables? They are called within the function, I don't seem to grasp the idea. Thanks again.

Back to top

Profile PM Email

Soldier X1

18

Years of Service

User Offline

Joined: 10th Oct 2005

Location:

Posted: 11th May 2007 02:05 Edited at: 11th May 2007 02:06

Link

I haven't tested this but try it anyway...

+ Code Snippet

function linetool()
   numClicks = 0
   while numClicks < 2
      if mousex()>30
         if mouseclick()=1 and numClicks = 0
            xPos = mousex()
            yPos = mousey()
            inc numClicks
         endif
         if mouseclick()=1 and numClicks = 1
            xPos2 = mousex()
            yPos2 = mousey()
            inc numClicks
         endif
      endif
   endwhile
   line xPos, yPos, xPos2, yPos2
endfunction

Let me know if that works.

Back to top

Profile PM

LBFN

17

Years of Service

User Offline

Joined: 7th Apr 2007

Location: USA

Posted: 11th May 2007 02:35

Link

@ vorconan

Try this code, I have tested it and it works:

+ Code Snippet

` draw lines to the mouse  LBFN 5/10/07
sync on
sync rate 100
randomize timer()
do
 if mouseclick()=1 then mx=mousex() : my=mousey() : linetool(mx,my)
 if returnkey()=1 then exit
 sync
loop
end

function linetool(mx,my)
` wait for the user to let go of the button
  repeat
    mc=mouseclick()
  until mc=0
` wait for use to click the left mouse button again
  repeat
    mc=mouseclick()
    omxp=mousex()
    omyp=mousey()
  until mc=1
    if omxp>30
      ink rgb(rnd(200)+55,rnd(200)+55,rnd(200)+55),0
      line mx,my,omxp,omyp
   endif

   ` take the next three lines out in order to draw from the last line
  repeat
   mc=mouseclick()
  until mc=0
endfunction

The error checking for only drawing a line if oxmp>30 does not work correctly all the time and will need some revision.

The program will draw lines between two points that you click with the mouse. If you rem out the last three lines of the linetool function, the program will draw from the end point of the last line you drew.

Good luck on your project.

LB

Back to top

Profile PM Email

TDK

Retired Moderator

21

Years of Service

User Offline

Joined: 19th Nov 2002

Location: UK

Posted: 11th May 2007 02:36

Link

+ Code Snippet

Set Display Mode 800,600,32
Sync On: Sync Rate 0
Get Image 1001,0,0,800,600,1: Rem Full Screen
Do
  Mx=MouseX(): My=MouseY(): Mc=MouseClick()
  If MC=1
  StartX=Mx: StartY=My
  Repeat
    Mx=MouseX(): My=MouseY(): Mc=MouseClick()
    Paste Image 1001,0,0
    Line StartX,StartY,Mx,My
    Sync
  Until MouseClick() = 0
  Get Image 1001,0,0,800,600,1: Rem Full Screen
  Endif
  Sync
Loop

TDK_Man

* TDK's Game Programming Forums - Open To All - DB & Team Request Boards *

Back to top

Profile PM Email Website

Zergei

19

Years of Service

User Offline

Joined: 9th Feb 2005

Location: Everywhere

Posted: 11th May 2007 03:02 Edited at: 11th May 2007 05:55

Link

Sorry about that, i just copied your code and forgot to correct one part of it.

+ Code Snippet


global drawing as logic
global omxp
global omyp

do

 if mouseclick()=1 then linetool()

loop

function linetool()
   
      
        if drawing=false
         omxp=mousex()
         omyp=mousey()
         drawing=true
        else
         line omxp,omyp,mousex(),mousey()
         drawing=false
         omxp=0
         omyp=0
        endif
     
   
endfunction

Some of the other ones code seem possible, however they all sugest to stop the program from continuing on.
Again, once i reach home, i'll open dbpro and test it, as i already done a line drawing program.

Further on my stuff at...

Back to top

Profile PM Email Website

aluseus GOD

17

Years of Service

User Offline

Joined: 19th Mar 2007

Location: I\'m here. Now I\'m there. I keep moving

Posted: 11th May 2007 04:23

Link

In case you want to know why your code didn't work, its because it will only make a line from a mouseclick if you are all ready pressing the mouse, which creates a dot line.

I will Learn to rule 2d. Someday...

Back to top

Profile PM Email Website

Zergei

19

Years of Service

User Offline

Joined: 9th Feb 2005

Location: Everywhere

Posted: 11th May 2007 06:00

Link

Ok, this is the code i just tested, and it works fine, thought it can be better, at least its a start.

+ Code Snippet

global drawing as boolean
global omxp
global omyp

sync on

do
 
 if mouseclick()=1 and mouse_hold=0 then mouse_hold=1 : linetool()
 if mouseclick()=0 then mouse_hold=0
 
 sync

loop

function linetool()
   
      
        if drawing=0
         omxp=mousex()
         omyp=mousey()
         drawing=1
        else
         line omxp,omyp,mousex(),mousey()
         drawing=0
         omxp=0
         omyp=0
        endif
     
   
endfunction

Further on my stuff at...

Back to top

Profile PM Email Website

TDK

Retired Moderator

21

Years of Service

User Offline

Joined: 19th Nov 2002

Location: UK

Posted: 11th May 2007 07:46

Link

I know the routine I posted wasn't a function, but it was only to demonstrate the method. It could very easily have been converted.

It also has the advantage that it's called only once, is self contained - and probably a little faster.

But, you have either not noticed I posted it or have chosen to completely ignore it.

TDK_Man

* TDK's Game Programming Forums - Open To All - DB & Team Request Boards *

Back to top

Profile PM Email Website

Zergei

19

Years of Service

User Offline

Joined: 9th Feb 2005

Location: Everywhere

Posted: 11th May 2007 13:49

Link

Quote: "But, you have either not noticed I posted it or have chosen to completely ignore it."

The 2nd one. Sorry, it was 2 am and i had to be quick on what i read.
But what i see as a problem there, is that it is self contained, thus if i'd needed to work outside of it on everyloop, say to refresh something else, it would be bothersome. It can be worked around, thought.

Further on my stuff at...

Back to top

Profile PM Email Website

RUCCUS

19

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 11th May 2007 15:35

Link

:/ you'd just call it every loop...

>> Gibble Blops - free, online, playable!

Back to top

Profile PM Email Website

vorconan

17

Years of Service

User Offline

Joined: 4th Nov 2006

Location: Wales

Posted: 11th May 2007 18:23 Edited at: 11th May 2007 18:47

Link

Thanks everybody, I didn't expect such a large response

.

@Zergei - Can I ask why you put drawing as boolean at the beginning?

@TDK - That was helpful code man, thanks alot.

@LBFM - Thanks for that code too, that last extra you put in will help.

I'm going to try these different methods out and see which one will run the best. Thanks a lot everyone.

Edit - Just tested Zergei's Method, nice one. The only problem I found is that the first line you draw starts by the top left, not 0,0, more like 0,30. I'll try and fix it.

Edit 2 - TDK, just tested the code, it's a brilliant line dragging code, I think I may go with it. The only problems I've found, are that the toolbar disappears every time I try to draw a line, then comes back again. And if I clear the screen while using a different tool, then use the linetool again, the lines reappear that I made before, bit weird, despite all that, good code man.

Back to top

Profile PM Email

TDK

Retired Moderator

21

Years of Service

User Offline

Joined: 19th Nov 2002

Location: UK

Posted: 11th May 2007 20:55 Edited at: 11th May 2007 21:00

Link

Quote: "The only problems I've found, are that the toolbar disappears every time I try to draw a line, then comes back again."

That's only down to where you grab the background image. Just move it to a point after where the toolbar is visible so it gets grabbed too.

The down side is that doing this you could draw over the toolbar, so it might be better to hide it and put it back after drawing.

You also get full screen drawing that way - as an added bonus!

The trick is to have one image that always contains the background image - use a variable to do this:

BackGroundImg = 1000

Then, in every drawing routine, as soon as you have put something on the screen, use:

Get Image BackGroundImg,0,0,ScrnWidth,ScrnHeight

In every routine where you are using 'rubber-band' drawing tools - like the circle or the line example I posted, you would use:

Paste Image BackGroundImg,0,0

Copying this image at any time gives you the ability to add an Undo function by simply pasting the backup image and grabbing it as the new background image.

TDK_Man

* TDK's Game Programming Forums - Open To All - DB & Team Request Boards *

Back to top

Profile PM Email Website

vorconan

17

Years of Service

User Offline

Joined: 4th Nov 2006

Location: Wales

Posted: 11th May 2007 21:01

Link

The full screen drawing is good thanks.

Back to top

Profile PM Email

Zergei

19

Years of Service

User Offline

Joined: 9th Feb 2005

Location: Everywhere

Posted: 12th May 2007 02:30

Link

Again here's an updated version. This time i was awake enough to know what i was writing...

+ Code Snippet

sync
global x1 as integer
global y1 as integer
global drawing as boolean

get image 1,0,0,screen width(), screen height(),1

do

    if mouseclick()=1 or drawing=1 then linetool() 
    
    sync
    
loop


Function linetool()

    if drawing = 0 and mouseclick()=1
        x1=mousex() : y1=mousey()
        drawing = 1
    endif
    if mouseclick()=0
     drawing=0 
     get image 1,0,0,screen width(), screen height(),1
     x1=0 : y1=0
    else
     paste image 1,0,0
     line x1,y1,mousex(),mousey()     
    endif
        
endfunction

Quote: ":/ you'd just call it every loop..."

If that went on me, well, yes. But thats not what i was arguing on the otherones code. My point was that the program only stood in the line sequence without exiting and doing something else in the meantime(is meantime it written like this?).

Quote: "
@Zergei - Can I ask why you put drawing as boolean at the beginning?"

Reason is that i wanted that variable to distinguish when on is on drawing mode and when not. As only 2 states will it represent, i decided to make it a boolean.

Quote: "The only problem I found is that the first line you draw starts by the top left, not 0,0, more like 0,30. I'll try and fix it."

That was due to the "if" statement i left from your codes left over. Trying to fix something on your own will lead you to great understanding of things. Keep up that spirit and the good work of course.

Quote: "TDK, just tested the code, it's a brilliant line dragging code,"

It sure is, thats why i tried to best mine.

@TDK - Have you came up whith another method than just the "get image" and "paste image". I've been thinking of memblocks, and other things, but thought i might just ask.

Further on my stuff at...

Back to top

Profile PM Email Website

TDK

Retired Moderator

21

Years of Service

User Offline

Joined: 19th Nov 2002

Location: UK

Posted: 12th May 2007 03:43

Link

No, I've never looked at doing it with memblocks - I just wanted to keep the above example as short and simple to follow as possible.

I've also done it exactly the same way in the past, but only grabbing the screen below the line itself which is a tiny bit faster. If you are trying to grab that extra little but of speed out of it then grabbing the whole screen could be considered slow.

TDK_Man

* TDK's Game Programming Forums - Open To All - DB & Team Request Boards *

Back to top

Profile PM Email Website

Zergei

19

Years of Service

User Offline

Joined: 9th Feb 2005

Location: Everywhere

Posted: 12th May 2007 06:09 Edited at: 12th May 2007 06:18

Link

Yet another update. Taking into consideration what TDK said, this version is a bit faster than the previous one (when doing small lines, not whith screenwide lines), as it grabs a smaller portion of the screen.

sync
global x1 as integer
global y1 as integer
global xtemp as integer
global ytemp as integer
global drawing as boolean

do

if mouseclick()=1 or drawing=1 then linetool() 
    
    sync
    
loop

Function linetool()

local xr as integer
    local yr as integer
    local borders as integer
    
    borders = 5

if drawing = 0 and mouseclick()=1
        x1=mousex() : y1=mousey()
        if x1<borders then x1=borders 
        if x1>bitmap width()-borders then x1=bitmap width()-borders
        if y1<borders then y1=borders 
        if y1>bitmap height()-borders then y1=bitmap height()-borders
        xtemp=x1 : ytemp=y1 : xr=mousex() : yr=mousey()
        if xr<borders then xr=borders 
        if xr>bitmap width()-borders then xr=bitmap width()-borders
        if yr<borders then yr=borders 
        if yr>bitmap height()-borders then yr=bitmap height()-borders
        if x1>=xr then xtemp=xr : xr=x1
        if y1>=yr then ytemp=yr : yr=y1
        dec xtemp,1 : dec ytemp,1
        inc xr,1 : inc yr,1
        get image 1,xtemp,ytemp,xr, yr,1
        drawing = 1
    endif

if mouseclick()=0
        drawing=0 
        x1=0 : y1=0 :xtemp=0 : ytemp=0
    else
        paste image 1,xtemp,ytemp
        xtemp=x1 : ytemp=y1 : xr=mousex() : yr=mousey()
        if xr<borders then xr=borders 
        if xr>bitmap width()-borders then xr=bitmap width()-borders
        if yr<borders then yr=borders 
        if yr>bitmap height()-borders then yr=bitmap height()-borders
        if x1>=xr then xtemp=xr : xr=x1
        if y1>=yr then ytemp=yr : yr=y1
        dec xtemp,1 : dec ytemp,1
        inc xr,1 : inc yr,1
        get image 1,xtemp,ytemp,xr, yr,1
        line x1,y1,mousex(),mousey()     
    endif
        
endfunction

+ Code Snippet

sync
global x1 as integer
global y1 as integer
global xtemp as integer
global ytemp as integer
global drawing as boolean

do

    if mouseclick()=1 or drawing=1 then linetool() 
    
    sync
    
loop


Function linetool()
    

    local xr as integer
    local yr as integer
    local borders as integer
    
    borders = 5

    if drawing = 0 and mouseclick()=1
        x1=mousex() : y1=mousey()
        if x1<borders then x1=borders 
        if x1>bitmap width()-borders then x1=bitmap width()-borders
        if y1<borders then y1=borders 
        if y1>bitmap height()-borders then y1=bitmap height()-borders
        xtemp=x1 : ytemp=y1 : xr=mousex() : yr=mousey()
        if xr<borders then xr=borders 
        if xr>bitmap width()-borders then xr=bitmap width()-borders
        if yr<borders then yr=borders 
        if yr>bitmap height()-borders then yr=bitmap height()-borders
        if x1>=xr then xtemp=xr : xr=x1
        if y1>=yr then ytemp=yr : yr=y1
        dec xtemp,1 : dec ytemp,1
        inc xr,1 : inc yr,1
        get image 1,xtemp,ytemp,xr, yr,1
        drawing = 1
    endif

    if mouseclick()=0
        drawing=0 
        x1=0 : y1=0 :xtemp=0 : ytemp=0
    else
        paste image 1,xtemp,ytemp
        xtemp=x1 : ytemp=y1 : xr=mousex() : yr=mousey()
        if xr<borders then xr=borders 
        if xr>bitmap width()-borders then xr=bitmap width()-borders
        if yr<borders then yr=borders 
        if yr>bitmap height()-borders then yr=bitmap height()-borders
        if x1>=xr then xtemp=xr : xr=x1
        if y1>=yr then ytemp=yr : yr=y1
        dec xtemp,1 : dec ytemp,1
        inc xr,1 : inc yr,1
        get image 1,xtemp,ytemp,xr, yr,1
        line x1,y1,mousex(),mousey()     
    endif
        
endfunction

Quote: "I've also done it exactly the same way in the past, but only grabbing the screen below the line itself which is a tiny bit faster. If you are trying to grab that extra little but of speed out of it then grabbing the whole screen could be considered slow."

I got that idea some time ago, but didn't try it out as i was thinking on doing it whith memblocks. Also, the fact that with big lines it will be the same quite discouraged me of doing so, and thinking of another alternative.

Further on my stuff at...

Back to top

Profile PM Email Website

vorconan

17

Years of Service

User Offline

Joined: 4th Nov 2006

Location: Wales

Posted: 12th May 2007 11:09 Edited at: 12th May 2007 11:11

Link

@Zergei

That's incredible, thanks so much. I'm learning a lot from you and TDK's codes, thanks again. This project is definetely going ahead now that the line tool is working. I hope this thread will be useful to others aswell.

Thanks

Back to top

Profile PM Email

Sorry your browser is not supported!

Newcomers DBPro Corner / Line Creation