Sorry your browser is not supported!

HIDE MOUSE
Set Display Mode 1024,768,32
Sync On : Sync Rate 60
Backdrop On : Color Backdrop 0
Autocam off

`===========================VARIABLE INITILIZATION===================================

`These variables affect the movement and rotation speeds of the camera:
Global CamScrollSpeed#  as float = 4.0       `The rate at which the camera scrolls.
Global CamAngle#        as float = 45.0      `This is the start angle of the camera.
Global CamRadius#       as float = 100.0     `This holds the rotation radius for the camera.
Global CamHeight#       as float = 200.0      `This holds the height of the camera from the ground, upwards.
Global Camobj           as integer           `This holds the ID of the object that the camera will be attached to.

type gData
   groundobj      as integer        `Stores the object number of the groud model
   groundtex      as integer        `Stores the image number of the ground texture
   selectedunits  as integer        `Stores the number of units the player has selected
EndType

Remstart
The next two variables store the Map Size X/Z which can then be used to keep the camera
and the 3D cursor from going off the edge of the map.

Changing these affects the size of the map, but will not cause any problems.
Remend
Global MapSizeX         as integer = 5000     `Stores the X size of the battlefield.
Global MapSizeZ         as integer = 5000     `Stores the Z size of the battlefield.

Type MouseClicked
   one            as boolean        `Left Mouse button
   two            as boolean        `Right Mouse Button
   three          as boolean        `Left + Right Mouse Buttons
   four           as boolean        `Middle Button/Scroll Wheel Click
Endtype

Dim gData(1) as gData
Dim MouseClicked(1) as MouseClicked

Type Cursor
   editortex     as integer
   attacktex     as integer
   movetex       as integer
   patroltex     as integer
   guardtex      as integer
   nogotex       as integer
   obj            as integer
EndType
Dim Cursor(1) as Cursor

`MouseMove Variables
Global mmx              as integer
Global mmz              as integer
Setup_Camera()
Create_Cursor()

Make_Level(MapSizeX,MapSizeZ)
rem object number of character
character = 15
rem speed at which character will move
speed# = 3.0
mouseFlag = 0
moveFlag = 0
`===========================VARIABLE INITILIZATION END===================================




Do
   mmx = MouseMoveX()
   mmz = MouseMoveZ()

   Move_Cursor()
   Camera_Control()

   Sync
Loop




`===========================MEDIA MANAGEMENT FUNCTIONS===================================

Function Find_Free_Object()
   for find = 1 to 5000
      If Object Exist(find)=0 then ExitFunction find
   Next find
Endfunction 0

Function Find_Free_Image()
   For find = 1 to 1000
      If Image Exist(find)=0 then ExitFunction find
   Next find
Endfunction 0

`==============================LEVEL FUNCTIONS============================================

Function Make_Level(SizeX as integer,SizeZ as integer)
   gData(1).groundobj = Find_Free_Object()
   Make Object Plain gData(1).groundobj,SizeX,SizeZ
   Rotate Object gData(1).groundobj,270,0,0
   Position Object gData(1).groundobj,0,0,0

   gData(1).groundtex = Find_free_image()
   Load Image "Media\Ground.jpg",gData(1).groundtex
   Scale Object Texture gData(1).groundobj,SizeX/58.3,SizeZ/58.3
   Texture Object gData(1).groundobj,gData(1).groundtex

   `Fade the edges of the battlefield to make the battlefield look better.
   borderimg = Find_Free_Image()
   Load Image "Media\border.png",borderimg

   leftedge = Find_Free_Object()
   Make Object Plain leftedge,SizeZ,20
   Rotate Object leftedge,270,90,0
   Position Object leftedge,-(SizeX/2)+8,0.1,0
   Texture Object leftedge,borderimg
   Set Object Transparency leftedge,1

   topedge = Find_Free_Object()
   Make Object Plain topedge,SizeX,20
   Rotate Object topedge,270+0.5,180,0
   Position Object topedge,0,0.2,(SizeZ/2)-8
   Texture Object topedge,borderimg
   Set Object Transparency topedge,1

   rightedge = Find_Free_Object()
   Make Object Plain rightedge,SizeZ,20
   Rotate Object rightedge,270,270,0
   Position Object rightedge,(SizeX/2)-8,0.3,0
   Texture Object rightedge,borderimg
   Set Object Transparency rightedge,1

   bottomedge = Find_Free_Object()
   Make Object Plain bottomedge,SizeX,20
   Rotate Object bottomedge,270-0.5,0,0
   Position Object bottomedge,0,0.4,-(SizeZ/2)+8
   Texture Object bottomedge,borderimg
   Set Object Transparency bottomedge,1
Endfunction

`======================================CAMERA FUNCTIONS===================================

Function Setup_Camera()
   position camera 0,90,0
   point camera 0,0,0
   Rotate Camera 45,Camangle#,0

   Camobj = Find_Free_Object()
   Make Object Triangle Camobj,0,0,0,0,0,0,0,0,0
   Position Object Camobj,0,-5,0

   Rotate Object Camobj,0,Camera Angle Y(),0
   Hide Object Camobj
Endfunction

Function Camera_Control()
   If MouseClicked(1).four = 0
      `Move Camera Left
      If MouseX()<10 and Check_Cam_Boundary() = 1 and Mouseclick()<>4
         Move Object Left Camobj,CamScrollSpeed#
      Else
         Repos_Cam_In_Boundary()
      Endif
      `Move Camera Right
      If MouseX()>1014 and Check_Cam_Boundary() = 1 and Mouseclick()<>4
         Move Object Right Camobj,CamScrollSpeed#
      Else
         Repos_Cam_In_Boundary()
      Endif
      `Move Camera forward
      If MouseY()<10 and Check_Cam_Boundary() = 1
         Move Object Camobj,CamScrollSpeed#
      Else
         Repos_Cam_In_Boundary()
      Endif
      If MouseY()>758 and Check_Cam_Boundary() = 1
         Move Object Camobj,-CamScrollSpeed#
      Else
         Repos_Cam_In_Boundary()
      Endif
   Endif
   `Zoom the camera in/out if the Mouse scroll wheel is used
   CamRadius# = CamRadius# - (mmz/20)
   CamHeight# = CamHeight# - (mmz/20)
   `Check to make sure camera is not zoomed in more than the maximum level
   If CamHeight# < 20
      CamHeight# = 20
   Endif
   If CamHeight# > 250
      CamHeight# = 250
   Endif
   If CamRadius# < 40
      CamRadius# = 40
   Endif
   If CamRadius# > 220
      CamRadius# = 220
   Endif
   `Rotate the camera around the point at the center of the screen.
   If Mouseclick()=4 and Check_Cam_Boundary() = 1
      MouseClicked(1).four = 1
      CamAngle# = CamAngle#+(mmx/3)
      If CamAngle#>359.9 or CamAngle#<-359.9 then CamAngle#=0

      YRotate Object Camobj,CamAngle#
   Else
      Repos_Cam_In_Boundary()
      MouseClicked(1).four = 0
   Endif
   Position Camera Object Position X(Camobj),CamHeight#,Object Position Z(Camobj)
   Set Camera To Object Orientation Camobj
   Move Camera -CamRadius#
   Point Camera Object Position X(Camobj),0,Object Position Z(Camobj)
Endfunction

Function Repos_Cam_In_Boundary()
   If Object Position X(Camobj)<-(MapSizeX/2)
      Position Object Camobj,-(MapSizeX/2),Object Position Y(Camobj),Object Position Z(Camobj)
   Endif
   If Object Position X(Camobj)>(MapSizeX/2)
      Position Object Camobj,(MapSizeX/2),Object Position Y(Camobj),Object Position Z(Camobj)
   Endif
   If Object Position Z(Camobj)>((MapSizeZ/2))
      Position Object Camobj,Object Position X(Camobj),Object Position Y(Camobj),((MapSizeZ/2))
   Endif
   If Object Position Z(Camobj)<-((MapSizeZ/2))
      Position Object Camobj,Object Position X(Camobj),Object Position Y(Camobj),-((MapSizeZ/2))
   Endif
Endfunction

Function Check_Cam_Boundary()

   If Object Position X(Camobj)=>-(MapSizeX/2)
      xnegative = 1
   Endif
   If Object Position X(Camobj)<=(MapSizeX/2)
      xpositive = 1
   endif
   If Object Position Z(Camobj)<=((MapSizeZ/2))
      znegative = 1
   endif
   If Object Position Z(Camobj)=>-((MapSizeZ/2))
      zpositive = 1
   endif
   If xnegative = 1 and xpositive = 1 and znegative = 1 and zpositive = 1
      ok = 1
   else
      ok = 0
   endif
Endfunction ok

`=================================CURSOR FUNCTIONS======================================

Function Create_Cursor()
   Cursor(1).obj = Find_Free_Object()
   Make Object Plain Cursor(1).obj,15,15
   XRotate Object Cursor(1).obj,270
   Cursor(1).editortex = 300
   Load Image "Media\editor_cur.png",Cursor(1).editortex
   texture object Cursor(1).obj,0,Cursor(1).editortex : Set Object Transparency Cursor(1).obj,1
Endfunction

function Move_Cursor()
   `rotate the cursor to make it a bit more appealing
   Yrotate Object Cursor(1).obj,Object Angle Y(Cursor(1).obj)+1.0
   cx=camera position x()
   cy=camera position y()
   cz=camera position z()
   null=make vector3(1)
   null=make vector3(2)
   null=make vector3(3)
   null=make vector3(4)
   set vector3 1,0,-1,0
   pick screen mousex(), mousey(), 1
   mx# = get pick vector x()
   my# = get pick vector y()
   mz# = get pick vector z()
   set vector3 2,mx#,my#,mz#
   angle# = acos(dot product vector3(2, 1))
   cosangle# = cos(angle#)
   hypolength# = cy/cosangle#
   normalize vector3 2,2
   scale vector3 2,2,hypolength#
   set vector3 1,cx,cy,cz
   add vector3 4,1,2
   position object Cursor(1).obj, x vector3(4),0.5,z vector3(4)
   Repos_Cursor_In_Boundary()
endfunction

Function Repos_Cursor_In_Boundary()
   If Object Position X(Cursor(1).obj)<-(MapSizeX/2)
      Position Object Cursor(1).obj,-(MapSizeX/2),Object Position Y(Cursor(1).obj),Object Position Z(Cursor(1).obj)
   Endif
   If Object Position X(Cursor(1).obj)>(MapSizeX/2)
      Position Object Cursor(1).obj,(MapSizeX/2),Object Position Y(Cursor(1).obj),Object Position Z(Cursor(1).obj)
   Endif
   If Object Position Z(Cursor(1).obj)>((MapSizeZ/2))
      Position Object Cursor(1).obj,Object Position X(Cursor(1).obj),Object Position Y(Cursor(1).obj),((MapSizeZ/2))
   Endif
   If Object Position Z(Cursor(1).obj)<-((MapSizeZ/2))
      Position Object Cursor(1).obj,Object Position X(Cursor(1).obj),Object Position Y(Cursor(1).obj),-((MapSizeZ/2))
   Endif
Endfunction

Rem Project: rts selection movement
Rem Created: 2007-06-21 16:27:09

rem created by cliff mellangard for silent thunder to help him out with rts like unit selection
rem very simple but hope it helps you out :)
rem i strongly recomend phalex rts tutorial its extremely good for an newbie

Rem ***** Main Source File *****
sync on
 sync rate 60
  autocam off
   terrainx# = 2000
    terrainy# = 2000
     mapx = 32
      mapy = 32
       ON = 1
        OFF  = 0
       make matrix 1,terrainx#,terrainy#,mapx,mapy
        randomize matrix 1,70
         gosub matrix_normals
``-----SET MATRIX Matrix Number, Wire, Transparency, Cull, Filter, Light, Fog, Ambient
set matrix 1,0,0,1,2,1,1,1
 update matrix 1
  position camera 1000,800,-1100
   point camera terrainx#/2,500,terrainz#/2
    ``-------array used to tell code that the selected unit have bin selected or not
     dim selection(20)
``------create some units
for t = 1 to 20
 make object cube t,50
  x# = rnd(terrainx#)
   z# = rnd(terrainy#)
    y# = get ground height(1,x#,z#)
     position object t,x#,y#,z#
      next t
``------here do we create an simple target dummy for the units for where to point and move
make object cube 30,25
``-------------main loop----------------------------
do
``------yust for simplicity
mb = mouseclick()
msx = mousex()
msy = mousey()
``-------reset the values neaded for the selection box
if selectionstate = 0 then msx1 = 0 : msy1 = 0

``-------if user left clicks and arent using the selection box activate it
if mb=1 and selectionstate=0 then msx1 = msx : msy1 = msy : selectionstate = ON

``-------exits the selecftion state if user lets go of the left mb
if mb<>1 then selectionstate = OFF

``-------draws an nice selection box and sets the objects selection arrays on on
if selectionstate = ON
units_selected=0 ``reset the flag that lets you se an amount of selected units
``-----------------the nice box  :) ----------------------
line msx1,msy1,msx,msy1 ``top line
line msx1,msy,msx,msy ``bottom line
line msx1,msy1,msx1,msy ``left line
line msx,msy1,msx,msy ``right line
``------here do we check if an unit is inside our selection box
for t = 1 to 20
 x = object screen x (t)
  y = object screen y (t)
   if x => msx1 and x =< msx
    selection(t) = 1
     if y => msy1 and y =< msy
      selection(t) = ON
       inc units_selected ``yust for show to show you how many you have selected
        else
         selection(t) = OFF
          endif
           else
            selection(t) = OFF
             endif
              next t
               endif
``-------here do we move the target dummy with the arrow keys
if upkey()=1 then move object 30,4
 if downkey()=1 then move object 30,-4
  if leftkey()=1 then move object left 30,4
   if rightkey()=1 then move object right 30,4
``--------store dummy objects position
xd# = object position x (30)
 zd# = object position z (30)
  yd# = get ground height(1,xd#,zd#)
   ``--------using dummy objects position to get right height towards the matrix
    position object 30,xd#,yd#,zd#

for t = 1 to 20
 if selection(t) = ON
  point object t,xd#,yd#,zd#
   if spacekey()=1 then move object t,1
    xu# = object position x (t)
     zu# = object position z (t)
      yu# = get ground height(1,xu#,zu#)
       position object t,xu#,yu#,zu#
        color object t,rgb(110,110,110)
         else
          color object t,rgb(255,255,255)
           endif
            next t
             set cursor 0,0
              print "arrow keys to move target cursor"
               print "left mouse button and move mouse to select units"
                print "space key to move selected units towards cursor"
                 print units_selected;"/20"
                sync
loop

`-----give matrix tiles right light according to its height-------
matrix_normals:
for x = 0 to mapx
   for z = 0 to mapy
`generate ground shadows / calculated strenght according to tiles height
a# = get matrix height(1,(x),z)``wrapvalue(a#+1)
if get matrix height(1,(x),z) > 15
nx# = 0.1+cos(a#*1.6)
nz# = 0.1+cos(a#*1.6)
``-----by setting these () do i tell dbp to calc (nx# + nz#) together first before adding them
ny# = 0.1 + sin(1.0 + (nx# + nz#))
else
nx# = 0.0
nz# = 0.0
ny# = 0.0
endif
if get matrix height(1,(x),z) > 160
if ny# > 0.0 then ny# = 1.9
endif
set matrix normal 1,x,z,nx#,ny#,nz#
next z
next x
return

if mouseclick()=2 then move object t,1