Quote: "Is there a practical way to set the application to run in a window, instead of fullscreen?"
sync on
set_screen_size(400,300,"Test")
do
cls
text 0,0,"Hello World"
sync
loop
function set_screen_size(nWindowwidth as integer,nWindowheight as integer,sWindowtitle as string)
rem local variables
local nDesktopwidth as integer
local nDesktopheight as integer
rem find desktop resolution
load dll "user32.dll",1
nDesktopwidth=call dll(1,"GetSystemMetrics",0)
nDesktopheight=call dll(1,"GetSystemMetrics",1)
delete dll 1
rem set to windowed and set title
set window on
set window title sWindowtitle
rem if the window width or window height are bigger than desktop then set
rem window height and width to desktop dimensions.
if nWindowwidth>nDesktopwidth or nWindowheight>nDesktopheight
nWindowwidth=nDesktopwidth
nWindowheight=nDesktopheight
endif
rem set the display mode
set display mode nWindowwidth,nWindowheight,32
rem if window width or height are smaller than desktop then set as window
rem and position centraly
if nWindowwidth<nDesktopwidth or nWindowheight<nDesktopheight
set window layout 4,1,1
set window position (nDesktopwidth/2)-(nWindowwidth/2),(nDesktopheight/2)-(nWindowheight/2)
rem else make full screen
else
set window layout 0,0,0
endif
endfunction
The word "Gullible" cannot be found in any English Dictionary.
