Sorry your browser is not supported!

rem ********************************************
rem CHAFARI  22 May 2008
rem Tutorial for Papa Stiffy
rem showing sliding collision with some helpers
rem ********************************************
rem creating some texture
ink rgb(0,100,0),0
box 0,0,100,100
ink rgb(0,180,0),1
box 25,25,75,75
get image 1,0,0,100,100,1
autocam off
sync on

rem object player
make object box 1,10,10,10

rem helper objects(four)
for i= 2 to 5
make object box i,10,10,10
color object i,rgb(255,0,0)
next i

rem some more obstacles _to collide with.
for i= 10 to 50
make object box i,200,30,180
position object i,40+rnd(2000),rnd(5),40+rnd(2000)
yrotate object i,rnd(90)
color object i,rgb(rnd(255),rnd(255),rnd(255))
next i

rem adding a floor_
make object box 1000,4000,1,4000:position object 1000,0,-10,0
texture object 1000,1
scale object texture 1000,80,80
do
rem player movements
IF upkey()=1 then x#=NEWXVALUE(x#,gira#,1):z#=NEWZVALUE(z#,gira#,1)
IF downkey()=1 then x#=NEWXVALUE(x#,gira#,-1):z#=NEWZVALUE(z#,gira#,-1)
if leftkey()=1 then gira#=wrapvalue(gira#-1)
if rightkey()=1 then gira#=wrapvalue(gira#+1)

yrotate object 1,gira#
yrotate camera gira#

rem checking collision
if object collision(2,0)>0 then inc x#
if object collision(3,0)>0 then dec x#
if object collision(4,0)>0 then inc z#
if object collision(5,0)>0 then dec z#

rem updating position of player and helpers objects
position object 1,x#,0,z#
position object 2,x#-15,0,z#
position object 3,x#+15,0,z#
position object 4,x#,0,z#-15
position object 5,x#,0,z#+15

rem th person camera view
position camera x#,30,z#
move camera -50:point camera x#,30,z#
set cursor 5,5
print "USE ARROWKEYS TO MOVE"
sync
loop

`===============================================
`    CHAFARI   EXAMPLE
`    sliding collision
`    + intersec object for gravity
`    robertochafari@hotmail.com
`===============================================
set cursor 200,200
print "  P L E A S E   W A I T . . . "
sync

hide mouse:autocam off:sync on
set ambient light 90
color backdrop rgb(0,0,0)


`****** starting positions *********
`============================================================================
x#=0  :z#=0  :y#=0 :gira#=45  :avance=2 :vol=120  :suavizado=5:jugad=1
`============================================================================

set camera range 10,25000

`******** we create the player **************
make object cylinder jugad,100

`******** loading our .x  model ************

load object "iglesia.x",778
scale object 778,800,800,800
set object collision to polygons 778

do
gosub control
sync
loop

control:
oldx#=x#
oldz#=z#
y#=object position y(1)

`camera controls
gira#=wrapvalue(gira#+mousemovex()*0.7):cam#=wrapvalue(cam#+mousemovey()*0.7)

`limits for the camera moving
if cam#<=290 and cam#>180 then cam#=290
if cam#>=70 and cam#<180 then cam#=70
rotate camera cam#,gira#,0

`********* player movements *************
if upkey()=1 THEN x#=NEWXVALUE(x#,gira#,avance):z#=NEWZVALUE(z#,gira#,avance)
if downkey()=1 THEN x#=NEWXVALUE(x#,gira#,0-avance):z#=NEWZVALUE(z#,gira#,-avance)

`side left movement
if leftkey()=1 THEN x#=NEWXVALUE(x#,gira#-90,avance):z#=NEWZVALUE(z#,gira#-90,avance)

`side right movement
if rightkey()=1 THEN x#=NEWXVALUE(x#,gira#-90,0-avance):z#=NEWZVALUE(z#,gira#-90,0-avance)


for i= 777 to 790
if object exist (i)
  `distance from floor ( y#)
  if INTERSECT OBJECT(i,x#,y#,z#,x#,y#-vol,z#)>0 then y#=y#+(vol-INTERSECT OBJECT(i,x#,y#,z#,x#,y#-vol,z#))/suavizado


`if not floor to stay on ,we fall down for gravity
  if INTERSECT OBJECT(i,x#,y#,z#,x#,y#-90,z#)=0 then gravedad#=3
  endif
next i

rem update camera position
position object jugad,x#+30,y#-gravedad#,z#
position camera x#,y#-gravedad#+40,z#


`THIS PART IS THE MOST IMPORTAN AS IT CALCULATE ALL COLLISION (0º, 90º, º80, 279º)
`-----------------------------------
if object collision(jugad,0)>0:gosub zzol
if object collision(jugad,0)=0:z#=oldz#
endif
endif

if object collision(jugad,0)>0:gosub xxol
if object collision(jugad,0)=0:x#=oldx#
endif
endif

if object collision(jugad,0)>0
x#=oldx#:z#=oldz#
endif
return
`------------------------------------
xxol:
POSITION OBJECT jugad,oldx#+30,y#-gravedad#,z#
return

zzol:
POSITION OBJECT jugad,x#+30,y#-gravedad#,oldz#
return