Here's one way to do it. Red cubes are objects that can be collided with, arrows to move camera, mouse to steer:
set display mode 800,600,32
sync on
sync rate 60
hide mouse
randomize timer()
rem make a grass texture
cls rgb(0,30,0)
for n=0 to 20000
c=rnd(130)
ink rgb(0,c,0),0
dot rnd(128),rnd(128)
next n
get image 1,0,0,128,128,1
sync
rem make a matrix for reference
make matrix 1,10000,10000,40,40
prepare matrix texture 1,1,1,1
update matrix 1
randomize matrix 1,100
rem place a bunch of objects around
for obj=10 to 50
make object cube obj,300
x=rnd(10000)
z=rnd(10000)
y=get ground height(1,x,z)
position object obj,x,y,z
color object obj,rgb(255,0,0)
rem setup simple collision for these objects
set object collision on obj
set object collision to boxes obj
next obj
rem make cube that will be positioned with the camera
make object cube 1,20
rem set up collision and hide the object so we never see it
set object collision on 1
set object collision to boxes 1
position camera 5000,get ground height(1,5000,5000)+20,5000
ink rgb(255,255,255),0
rem the main loop
do
gosub _move_camera
sync
loop
end
`----------------------------------------------------------------
_move_camera:
speed=(upkey()-downkey())*5
move camera speed
yang#=wrapvalue(camera angle y()+mousemovex())
yrotate camera yang#
yrotate object 1,yang#
rem get camera position and position invisible box there
objx#=camera position x()
objz#=camera position z()
objy#=get ground height(1,objx#,objz#)+20
position camera objx#,objy#,objz#
position object 1,objx#,objy#,objz#
rem check for collision with hidden camera object
bang=object collision(1,0)
text 0,0,"Colliding with object "+str$(bang)
if bang<>0
move camera 0-speed
move object 1,0-speed
endif
return
`----------------------------------------------------------------Enjoy your day.
