Game Time Varying - GameCreators Forum

Author

Message

Daryn Alsup

16

Years of Service

User Offline

Joined: 5th Jul 2008

Location: In your head... dun dun DUN!!!!!!!!

Posted: 18th Dec 2008 08:05

Link

I have two objects, one rotating around another whilst the other rotates in place. Plainly it's like a sun rotating around a planet. You can rotate the camera around the planet but what I need is to adjust the time based on the cameras position (which is constantly pointing at the objects location)

I know that a sawtooth function is needed. As there are 24 hours in a day, 60 minutes in an hour and 60 seconds in a minute. So for every 14 degrees, sixty minutes should pass, and 3600 seconds. How can I make an equation that can show this? I would know this type of math by heart if my math wasn't so lacking.

I should also say that the planet is only in appearance- rotating around the sun. In actuality, the sun is doing the rotation.

-Daryn

Jack and Jill went up a hill to fetch a pale of water... but Jill got tired of his s#%& so she shot him.

Back to top

Profile PM Email Website

Daryn Alsup

16

Years of Service

User Offline

Joined: 5th Jul 2008

Location: In your head... dun dun DUN!!!!!!!!

Posted: 18th Dec 2008 08:08

Link

I forgot to mention that rather than have the total seconds for each hour, it should be the total seconds for each minute. Obviously

Jack and Jill went up a hill to fetch a pale of water... but Jill got tired of his s#%& so she shot him.

Back to top

Profile PM Email Website

Pillarofire

20

Years of Service

User Offline

Joined: 31st Dec 2003

Location: Good Question, <looks around.>

Posted: 18th Dec 2008 11:41

Link

There are 60 sec per min.
and 60 min per hour, (60 * 60 = 3600 sec per hour)
and 24 hours per day (3600 * 24 = 86400 sec per day)
and 365.25 days per revolution of the earth around the sun. (86400 * 365.25 = 31557600 sec per year)

So then there are 31557600 / 360 sec in one degree, because that is how many degrees are in a complete revolution. So one degree of revolution of the earth about the sun is 87660 seconds.

+ Code Snippet


function SecondsPerDegrees( Degrees# as float )
  Time# as float
  Time# = Degrees * 87660.0
endfunction Time#

function MinutesPerDegrees( Degrees# as float )
  Time# as float
  Time# = (Degrees# * 87660.0) / 60.0
endfunction Time#

Is that what you want?

Back to top

Profile PM Website

Daryn Alsup

16

Years of Service

User Offline

Joined: 5th Jul 2008

Location: In your head... dun dun DUN!!!!!!!!

Posted: 18th Dec 2008 15:10

Link

Your close. YOu nearly hit the nail on the head. How would I then create the clock which (only in appearance if needed) restarts its seconds ever 60 turns and likewise for minuetes?

That was very helpful though. Thank you

Jack and Jill went up a hill to fetch a pale of water... but Jill got tired of his s#%& so she shot him.

Back to top

Profile PM Email Website

Daryn Alsup

16

Years of Service

User Offline

Joined: 5th Jul 2008

Location: In your head... dun dun DUN!!!!!!!!

Posted: 18th Dec 2008 16:35

Link

Pardon the double post, but I am looking for HH:MM:SS format. I would use the clock function included in dbpro if it could be altered in a way to give you your in game time. But as it can't be fast forwarded and such I really need some sort of sawtooth equation. (See picture for reference)
A= Another smaller sawtooth equation for 60 seconds within each minute
B=60 minutes or 'the ceiling' of the equation
C= the total length of the equation (or 360 for the rotation of the planet)

If anyone can help it would be most appreciated. I would much prefer this type of time regulation as apposed to anything else unless you can sway me

. Thank you though for the help in the matter.

Jack and Jill went up a hill to fetch a pale of water... but Jill got tired of his s#%& so she shot him.

Attachments

Login to view attachments

Back to top

Profile PM Email Website

Pillarofire

20

Years of Service

User Offline

Joined: 31st Dec 2003

Location: Good Question, <looks around.>

Posted: 19th Dec 2008 15:59

Link

Okay I understand now.

There is a slight bug with the INT(float) causing some anomalous output, however, it appears to work pretty well. maybe implement a rounding routine, but that just means more overhead. Your choice anyway, here is what I got.

+ Code Snippet


do
  cls
  if mouseclick()=0 then if a# < 320000.0 then inc a# else a# = 0.0
  set cursor 250, 100
  print TimeFormat( a# )," : ", a#

loop

function TimeFormat( Time# as float )
  SS# = SawTooth( Time#, 60.0 )
  MM# = SawTooth( Time#/60.0, 60.0 )
  HH# = SawTooth( Time#/3600.0, 24.0 )
  TimeString$ = (str$(int(HH#))) + ":" + (str$(int(MM#))) + ":" + (str$(int(SS#)))
endfunction TimeString$

function SawTooth( x# as float, Amplitude# as float )
  t# = Amplitude# * ( x#/Amplitude# - floor( x#/Amplitude# ) )
endfunction t#

Back to top

Profile PM Website

Daryn Alsup

16

Years of Service

User Offline

Joined: 5th Jul 2008

Location: In your head... dun dun DUN!!!!!!!!

Posted: 20th Dec 2008 07:05

Link

I Bow to you pillarofire! wonderful. Now to conver this into what I need.

+ Code Snippet

Set display mode 1280,1024,32
Make object sphere 1,50,50,50
Dist#=300
Ang#=0
Do

position object 1,px#,15.0,pz#

ang# = wrapvalue(ang# + 0.240)

  px# = newxvalue(object position x(1),ang#,dist#)
  pz# = newzvalue(object position z(1),ang#,dist#)

  px2# = newxvalue(object position x(1),ang2#,dist2#)
  pz2# = newzvalue(object position z(1),ang2#,dist2#)

Where and by what means can I make this object above relate to the clock-code you provided. Since the angle (Ang#) is always a constant 360º at max and 0º at min, I suppose replacing the "A#" may work but I'm not sure. If you can point me in the right direction it would help... but it is also simple enough for me to figure out with some time. Thank you.

Jack and Jill went up a hill to fetch a pale of water... but Jill got tired of his s#%& so she shot him.

Back to top

Profile PM Email Website

Daryn Alsup

16

Years of Service

User Offline

Joined: 5th Jul 2008

Location: In your head... dun dun DUN!!!!!!!!

Posted: 20th Dec 2008 10:57

Link

I got it. Just through in

+ Code Snippet

A#=Ang#*(10*(24))

and its all good. From this I can through in months, years, days and so fourth. Thank you all so much!

Jack and Jill went up a hill to fetch a pale of water... but Jill got tired of his s#%& so she shot him.

Back to top

Profile PM Email Website

Pillarofire

20

Years of Service

User Offline

Joined: 31st Dec 2003

Location: Good Question, <looks around.>

Posted: 21st Dec 2008 10:33

Link

Well I'm not sure exactly what you were trying to accomplish, but judging from you other posts I'm guessing that you will find this useful.

sync on
autocam off

` Constants
#constant SUN    1
#constant EARTH  2
#constant PICKr   3

` Variables
Dist# as float = 300.0
Ang# as float = 0.0

` Make sun
make object sphere SUN, 50
position object SUN, 0.0, 0.0, 0.0
color object SUN, 0xFFFF00

` Make earth
make object sphere EARTH, 2
position object EARTH, 0.0, 0.0, 150.0
color object EARTH, 0x30FF30

` Pick Helper object
make object plain PICKr, 1000.0, 1000.0
xrotate object PICKr, 90.0
position object PICKr, 0.0, 0.0, 0.0
color object PICKr, 0x000000
set object light PICKr, 1

` position camera
position camera 0.0, 450.0, 0.0
point camera 0.0, 0.0, 0.0

ac# = 0.00001 ` angle change.
Do

if pick object( mousex(), mousey(), PICKr, PICKr )=PICKr and mouseclick()=1
    pickx# = camera position x() + get pick vector x()
    pickz# = camera position z() + get pick vector z()
    Ang# = atanfull( pickx#, pickz# )
    position object EARTH, 150.0 * sin(Ang#), 0.0, 150.0 * cos(Ang#)
   else
    Ang# = Ang# + ac#
    RotateObjectAroundObject( EARTH, SUN, ac# )
  endif

ac# = ac# + mousemovez()/10000.0
  Time# = SecondsPerDegrees( Ang# )
  text object screen x(EARTH), object screen y(EARTH), TimeFormat( Time# )

sync
loop

function RotateObjectAroundObject( o1 as integer, o2 as integer, ang# as float )
  x# = object position x(o2)
  y# = object position y(o2)
  z# = object position z(o2)
  dx# = object position x(o1) - x#
  dy# = object position y(o1) - y#
  dz# = object position z(o1) - z#
  nx# = dx# * cos( -ang# ) - dz# * sin( -ang# )
  nz# = dx# * sin( -ang# ) + dz# * cos( -ang# )
  nx# = nx# + x#
  nz# = nz# + z#
  position object o1, nx#, object position y(o1), nz#
endfunction

function SecondsPerDegrees( Degrees# as float )
  Time# as float
  Time# = Degrees# * 87660.0
endfunction Time#

function MinutesPerDegrees( Degrees# as float )
  Time# as float
  Time# = (Degrees# * 87660.0) / 60.0
endfunction Time#

function TimeFormat( Time# as float )
  SS# = SawTooth( Time#, 60.0 )
  MM# = SawTooth( Time#/60.0, 60.0 )
  HH# = SawTooth( Time#/3600.0, 24.0 )
  DD# = SawTooth( Time#/86400.0, 365.25 )
  TimeString$ = (str$(int(DD#))) + ":" + (str$(int(HH#))) + ":" + (str$(int(MM#))) + ":" + (str$(int(SS#)))
endfunction TimeString$

function SawTooth( x# as float, Amplitude# as float )
  t# = Amplitude# * ( x#/Amplitude# - floor( x#/Amplitude# ) )
endfunction t#

+ Code Snippet




sync on
autocam off

` Constants
#constant SUN    1
#constant EARTH  2
#constant PICKr   3

` Variables
Dist# as float = 300.0
Ang# as float = 0.0

` Make sun
make object sphere SUN, 50
position object SUN, 0.0, 0.0, 0.0
color object SUN, 0xFFFF00

` Make earth
make object sphere EARTH, 2
position object EARTH, 0.0, 0.0, 150.0
color object EARTH, 0x30FF30

` Pick Helper object
make object plain PICKr, 1000.0, 1000.0
xrotate object PICKr, 90.0
position object PICKr, 0.0, 0.0, 0.0
color object PICKr, 0x000000
set object light PICKr, 1

` position camera
position camera 0.0, 450.0, 0.0
point camera 0.0, 0.0, 0.0

ac# = 0.00001 ` angle change.
Do

  if pick object( mousex(), mousey(), PICKr, PICKr )=PICKr and mouseclick()=1
    pickx# = camera position x() + get pick vector x()
    pickz# = camera position z() + get pick vector z()
    Ang# = atanfull( pickx#, pickz# )
    position object EARTH, 150.0 * sin(Ang#), 0.0, 150.0 * cos(Ang#)
   else
    Ang# = Ang# + ac#
    RotateObjectAroundObject( EARTH, SUN, ac# )
  endif

  ac# = ac# + mousemovez()/10000.0
  Time# = SecondsPerDegrees( Ang# )
  text object screen x(EARTH), object screen y(EARTH), TimeFormat( Time# )


  sync
loop

function RotateObjectAroundObject( o1 as integer, o2 as integer, ang# as float )
  x# = object position x(o2)
  y# = object position y(o2)
  z# = object position z(o2)
  dx# = object position x(o1) - x#
  dy# = object position y(o1) - y#
  dz# = object position z(o1) - z#
  nx# = dx# * cos( -ang# ) - dz# * sin( -ang# )
  nz# = dx# * sin( -ang# ) + dz# * cos( -ang# )
  nx# = nx# + x#
  nz# = nz# + z#
  position object o1, nx#, object position y(o1), nz#
endfunction

function SecondsPerDegrees( Degrees# as float )
  Time# as float
  Time# = Degrees# * 87660.0
endfunction Time#

function MinutesPerDegrees( Degrees# as float )
  Time# as float
  Time# = (Degrees# * 87660.0) / 60.0
endfunction Time#

function TimeFormat( Time# as float )
  SS# = SawTooth( Time#, 60.0 )
  MM# = SawTooth( Time#/60.0, 60.0 )
  HH# = SawTooth( Time#/3600.0, 24.0 )
  DD# = SawTooth( Time#/86400.0, 365.25 )
  TimeString$ = (str$(int(DD#))) + ":" + (str$(int(HH#))) + ":" + (str$(int(MM#))) + ":" + (str$(int(SS#)))
endfunction TimeString$

function SawTooth( x# as float, Amplitude# as float )
  t# = Amplitude# * ( x#/Amplitude# - floor( x#/Amplitude# ) )
endfunction t#

Back to top

Profile PM Website

Sorry your browser is not supported!

Newcomers DBPro Corner / Game Time Varying

Attachments