Sorry your browser is not supported!

SXVal# = NEWXVALUE(Object Position X (400),OBJECT ANGLE Y(400),-300)
SYVal# = NEWYVALUE(Object Position Y (400),OBJECT ANGLE X(400), 50)
SZVal# = NEWZVALUE(Object Position Z (400),OBJECT ANGLE Y(400),-300)


Position Camera 0, SXVal#, SYVal#, SZVal#
point camera 0,object position x(400),object position Y(400), object position z(400)

`Setup Display
set display mode 1024,768,32,1
sync on

`Setup Environment
autocam off
hide mouse

`"Ship" Object
make object box 1,10,10,30
position object 1,100,10,100

`Some scenery
make matrix 1,200,200,20,20
randomize matrix 1,5
update matrix 1

`Define Variables
ShipObj=1
Speed#=1.5
FollowXZ#=100
FollowY#=40

`Main Loop
do
   set cursor 0,0
   print "Mouse - Look"
   print "WASD  - Strafe"

   `Mouse looks
   yrotate object ShipObj,wrapvalue(object angle y(ShipObj)+mousemovex()/8.0)
   xrotate object ShipObj,wrapvalue(object angle x(ShipObj)+mousemovey()/8.0)

   `Clear velocities
   vx#=0 : vy#=0 : vz#=0

   `WASD strafes
   if keystate(17)
      inc vx#,Speed#*cos(object angle x(ShipObj))*sin(object angle y(ShipObj))
      dec vy#,Speed#*sin(object angle x(ShipObj))
      inc vz#,Speed#*cos(object angle x(ShipObj))*cos(object angle y(ShipObj))
   endif
   if keystate(31)
      dec vx#,Speed#*cos(object angle x(ShipObj))*sin(object angle y(ShipObj))
      inc vy#,Speed#*sin(object angle x(ShipObj))
      dec vz#,Speed#*cos(object angle x(ShipObj))*cos(object angle y(ShipObj))
   endif
   if keystate(30)
      inc vx#,Speed#*sin(object angle y(ShipObj)-90)
      inc vz#,Speed#*cos(object angle y(ShipObj)-90)
   endif
   if keystate(32)
      dec vx#,Speed#*sin(object angle y(ShipObj)-90)
      dec vz#,Speed#*cos(object angle y(ShipObj)-90)
   endif

   `Update ship's position
   position object ShipObj,object position x(ShipObj)+vx#,object position y(ShipObj)+vy#,object position z(ShipObj)+vz#

   `Determine the position of the camera behind the ship using FollowXZ# and FollowY#
   xpos#=object position x(ShipObj)-(FollowXZ#*cos(object angle x(ShipObj))-FollowY#*sin(object angle x(ShipObj)))*sin(object angle y(ShipObj))
   ypos#=object position y(ShipObj)+FollowXZ#*sin(object angle x(ShipObj))+FollowY#*cos(object angle x(ShipObj))
   zpos#=object position z(ShipObj)-(FollowXZ#*cos(object angle x(ShipObj))-FollowY#*sin(object angle x(ShipObj)))*cos(object angle y(ShipObj))
   position camera 0,xpos#,ypos#,zpos#
   `Can't simply use point object because point object doesn't allow the camera to go upside-down.
   rotate camera 0,wrapvalue(object angle x(ShipObj)+atan(FollowY#/FollowXZ#)),object angle y(ShipObj),0

   `End Loop
   sync
loop

function CameraFollowObject(Camera,Object,FollowX#,FollowY#,FollowZ#,XAng#,Yang#,ZAng#)
   xpos#=object position x(Object)+(FollowZ#*cos(object angle x(Object))+FollowY#*sin(object angle x(Object)))*sin(object angle y(Object))+FollowX#*cos(object angle y(Object))
   ypos#=object position y(Object)-FollowZ#*sin(object angle x(Object))+FollowY#*cos(object angle x(Object))
   zpos#=object position z(Object)+(FollowZ#*cos(object angle x(Object))+FollowY#*sin(object angle x(Object)))*cos(object angle y(Object))-FollowX#*sin(object angle y(Object))
   position camera Camera,xpos#,ypos#,zpos#
   set camera to object orientation Camera,Object
   pitch camera down Camera,XAng#
   turn camera right Camera,YAng#
   roll camera left Camera,ZAng#
endfunction

function OrbitCamera(Camera,Object,XDist#,YDist#,ZDist#,XAng#,YAng#,ZAng#,ZDepthFlag)
   position object Object,camera position x(Camera),camera position y(Camera),camera position z(Camera)
   rotate object Object,camera angle x(Camera),camera angle y(Camera),camera angle z(Camera)
   move object right Object,XDist#
   move object up Object,YDist#
   move object Object,ZDist#
   pitch object down Object,XAng#
   turn object right Object,YAng#
   roll object left Object,ZAng#
   print camera angle x(0)
   print camera angle y(0)
   if not ZDepthFlag then disable object zdepth Object
endfunction

Rem Project: Orbit Experimentation 4
Rem Created: 1/5/09 8:29:46 PM
Rem ***** Jon L. *****

Set Display mode 1024,768,32
MAKE CAMERA 1
SET CAMERA VIEW 1,600,1,1020,300
COLOR BACKDROP 0,rgb(0,0,0)
COLOR BACKDROP 1,rgb(0,0,0)
SYNC ON

Make Matrix 1,400,400,20,20
position matrix 1,-200,0,-200

`True Target Object
make object cube 1, 10
position object 1,0,5,20

`Dummy Object
Make Object Cube 2,5 ` note make dummy size 10 to see it during render
position object 2,0,5,20
Dummy = 2

`Camera Object
Make Object Cube 3,5
Color Object 3,rgb(0,0,255)

position camera 0,0,30,-50
Position Camera 1,0,100,0

Point_Camera(0,1)
Point_Camera(1,1)

OrbitPanSpeed# = .05

`*** Main Loop ***

Do
`Draw Frame Around View
Line_Box(RGB(255,0,0),600,1,1020,300)

`Set Ink Color and Print the Frames Per Second
Ink RGB(255,255,255),0
Set Cursor 10,20
Print "FPS:"+str$(screen fps())

CameraOrbitObject(0,Dummy,.2)

sync
loop

`3D Functions

Function Center_Object(Object,Object_Target)
`Function used to simplify centering an object on another object.
Position Object (Object),Object Position X(Object_Target),Object Position Y(Object_Target), Object Position Z(Object_Target)

EndFunction

Function Point_Camera(Camera,Object_Number)
`Function used to simplify pointing a camera at an object.

Point Camera Camera, Object Position X(Object_Number),Object Position Y(Object_Number),Object Position Z(Object_Number)

Endfunction

Function Point_Object(Object_Number_1,Object_Number_2)
`Function used to simplify pointing objects at one each other.

Point Object Object_Number_1, Object Position X(Object_Number_2),Object Position Y(Object_Number_2),Object Position Z(Object_Number_2)

Endfunction

Function Center_Camera(Camera,Object)
`Function used to simplify centering a camera on an object.
Position Camera (Camera),Object Position X(Object),Object Position Y(Object), Object Position Z(Object)

EndFunction

`2D Functions

Function Line_Box(Color,X1,Y1,X2,Y2)
`Function used for drawing a (1) pixel line box at the specified color and coordinates.
`line 599,0,599,300
Ink Color,0
`Top Left to Bottom Left
line X1,Y1,X1,Y2

`Bottom Left to Bottom Right
line X1,Y2,X2,Y2

`Bottom Right to Top Left
line X2,Y2,X2,Y1

`Top Right to Top Left
line X2,Y1,X1,Y1

EndFunction

Function CameraOrbitObject(Camera, Dummy, OrbitPanSpeed#)

`This is a function based on code that I found on the DBP Forums by "Rye"
`I modified it to work with RTS style mouse panning

cax#=object angle x(Dummy)
cay#=object angle y(Dummy)

cx#=object position x(Dummy)
cy#=object position y(Dummy)
cz#=object position z(Dummy)

if leftkey()=1 or mousex() <  screen width() / 4
cay#=wrapvalue(cay#-OrbitPanSpeed#)
Endif

if rightkey() = 1 or mousex() > screen width() - screen width() / 4
  cay#=wrapvalue(cay# + OrbitPanSpeed#)
endif

if upkey()=1 or mousey() < screen height()/4
cax#=wrapvalue(cax#-OrbitPanSpeed#)
endif

if downkey()=1 or mousey() > screen height() - screen height()/4
cax#=wrapvalue(cax#+OrbitPanSpeed#)
endif
if cax# > 270 then cax# = 270
if cax# < 90  then cax# = 90

yrotate object Dummy,cay#
xrotate object Dummy,cax#

dist#=50*cos(cax#)

oy#=newyvalue(cy#,cax#,50)
ox#=newxvalue(cx#,cay#,dist#)
oz#=newzvalue(cz#,cay#,dist#)

Position Camera Camera,ox#,oy#,oz#
Position Object 3,ox#,oy#,oz# ` Remove this as it represents a camera object
Point_Camera(Camera,Dummy)
Point_Object(3,1) ` Remove this as it represents a camera object

Endfunction