Hovering Objects - GameCreators Forum

Author

Message

kordman916

17

Years of Service

User Offline

Joined: 5th Oct 2007

Location:

Posted: 3rd May 2009 07:32

Link

How would I make an object "bob" up and down like it's hovering

Back to top

Profile PM Email

Izzy545

20

Years of Service

User Offline

Joined: 18th Feb 2004

Location:

Posted: 3rd May 2009 07:55 Edited at: 3rd May 2009 07:55

Link

There are multiple solutions for this. Here's one. We store the initial height in variable starty# and how high/low it bobs is stored in bobheight#. This code assumes the object is object 1 and "up" is on the y-axis.

Based on position:

+ Code Snippet

goingup = 1
starty# = object position y(1)
bobheight# = 2

do
x# = object position x(1)
y# = object position y(1)
z# = object position z(1)

if y# < starty# + bobheight# and goingup = 1
   y# = y# + 0.05
else
   goingup = 0
endif

if y# > starty# - bobheight# and goingup = 0
   y# = y# - 0.05
else
   goingup = 1
endif

position object 1, x#, y#, z#
loop

and in a sample program:

sync on : sync rate 60

make object cube 1, 3
position object 1, 0, 1, 0

make matrix 1, 50, 50, 10, 10
position matrix 1, -25, -6, -25

x# = object position x(1)
y# = object position y(1)
z# = object position z(1)

position camera -25,15,-25
point camera 0,0,1

goingup = 1
starty# = object position y(1)
bobheight# = 2

do
   x# = object position x(1)
   y# = object position y(1)
   z# = object position z(1)

if y# < starty# + bobheight# and goingup = 1
      y# = y# + 0.05
   else
      goingup = 0
   endif

if y# > starty# - bobheight# and goingup = 0
      y# = y# - 0.05
   else
      goingup = 1
   endif

if upkey()
      move object 1, 0.5
   endif

if downkey()
      move object 1, -0.5
   endif

x# = object position x(1)
   z# = object position z(1)

if rightkey()
      yrotate object 1, object angle y(1)+1
   endif

if leftkey()
      yrotate object 1, object angle y(1)-1
   endif

position object 1, x#, y#, z#
   set camera to follow x#, y#, z#, object angle y(1), 20, 5, 1, 1

sync
loop

+ Code Snippet

sync on : sync rate 60

make object cube 1, 3
position object 1, 0, 1, 0

make matrix 1, 50, 50, 10, 10
position matrix 1, -25, -6, -25

x# = object position x(1)
y# = object position y(1)
z# = object position z(1)

position camera -25,15,-25
point camera 0,0,1

goingup = 1
starty# = object position y(1)
bobheight# = 2

do
   x# = object position x(1)
   y# = object position y(1)
   z# = object position z(1)

   if y# < starty# + bobheight# and goingup = 1
      y# = y# + 0.05
   else
      goingup = 0
   endif

   if y# > starty# - bobheight# and goingup = 0
      y# = y# - 0.05
   else
      goingup = 1
   endif

   if upkey()
      move object 1, 0.5
   endif

   if downkey()
      move object 1, -0.5
   endif

   x# = object position x(1)
   z# = object position z(1)

   if rightkey()
      yrotate object 1, object angle y(1)+1
   endif

   if leftkey()
      yrotate object 1, object angle y(1)-1
   endif

   position object 1, x#, y#, z#
   set camera to follow x#, y#, z#, object angle y(1), 20, 5, 1, 1

   sync
loop

Hope that helps. Obviously it's a very basic bobbing up and down, you'll probably want to smooth it out some, but it's a start.

Check out my books

Back to top

Profile PM

kordman916

17

Years of Service

User Offline

Joined: 5th Oct 2007

Location:

Posted: 3rd May 2009 09:31

Link

How would I go about smoothing it out?

Back to top

Profile PM Email

Izzy545

20

Years of Service

User Offline

Joined: 18th Feb 2004

Location:

Posted: 3rd May 2009 10:09 Edited at: 3rd May 2009 10:11

Link

Well, I think slowing it down at the bottom and at the top of the float cycle looks a little better. There are some maths involved and as I'm not very good I wouldn't be able to give you a good function to do so, but I did modify the code a bit so it bobbed slower, slowed down a bit at the top and bottom (not in the way I imagined) and bobbed less, looks a bit better. Here's the code:

sync on : sync rate 60

make object cube 1, 3
position object 1, 0, 1, 0

make matrix 1, 50, 50, 10, 10
position matrix 1, -25, -6, -25

x# = object position x(1)
y# = object position y(1)
z# = object position z(1)

position camera -25,15,-25
point camera 0,0,1

goingup = 1
starty# = object position y(1)
bobheight# = 1
speedmult# = 0.75

do
   x# = object position x(1)
   y# = object position y(1)
   z# = object position z(1)
   
   set cursor 0,0
   print speedmult#

if y# <= starty# + bobheight# and goingup = 1
      speedmult# = (starty#+bobheight#-y#)/5+0.25
      y# = y# + 0.05 * speedmult#
   else
      goingup = 0
   endif

if y# >= starty# - bobheight# and goingup = 0
      speedmult# = (y#-starty#+bobheight#)/5+0.25   
      y# = y# - 0.05 * speedmult#
   else
      goingup = 1
   endif

if upkey()
      move object 1, 0.5
   endif

if downkey()
      move object 1, -0.5
   endif

x# = object position x(1)
   z# = object position z(1)

if rightkey()
      yrotate object 1, object angle y(1)+1
   endif

if leftkey()
      yrotate object 1, object angle y(1)-1
   endif

position object 1, x#, y#, z#
   set camera to follow x#, y#, z#, object angle y(1), 20, 5, 1, 1

sync
loop

+ Code Snippet

sync on : sync rate 60

make object cube 1, 3
position object 1, 0, 1, 0

make matrix 1, 50, 50, 10, 10
position matrix 1, -25, -6, -25

x# = object position x(1)
y# = object position y(1)
z# = object position z(1)

position camera -25,15,-25
point camera 0,0,1

goingup = 1
starty# = object position y(1)
bobheight# = 1
speedmult# = 0.75

do
   x# = object position x(1)
   y# = object position y(1)
   z# = object position z(1)
   
   set cursor 0,0
   print speedmult#

   if y# <= starty# + bobheight# and goingup = 1
      speedmult# = (starty#+bobheight#-y#)/5+0.25
      y# = y# + 0.05 * speedmult#
   else
      goingup = 0
   endif

   if y# >= starty# - bobheight# and goingup = 0
      speedmult# = (y#-starty#+bobheight#)/5+0.25   
      y# = y# - 0.05 * speedmult#
   else
      goingup = 1
   endif

   if upkey()
      move object 1, 0.5
   endif

   if downkey()
      move object 1, -0.5
   endif

   x# = object position x(1)
   z# = object position z(1)

   if rightkey()
      yrotate object 1, object angle y(1)+1
   endif

   if leftkey()
      yrotate object 1, object angle y(1)-1
   endif

   position object 1, x#, y#, z#
   set camera to follow x#, y#, z#, object angle y(1), 20, 5, 1, 1

   sync
loop

Essentially we're taking the current height, modifying it by where it started from and how high it's supposed to go, and getting a multiplier from it. Even if you don't know maths, think about a workaround to get the result you want and you'll probably be able to come up with SOMETHING like I did

Good luck!

Check out my books

Back to top

Profile PM

bobbel

15

Years of Service

User Offline

Joined: 5th Jan 2009

Location: In my DBPro case xD

Posted: 3rd May 2009 15:59

Link

maybe something like this? its very simple

+ Code Snippet

sync on : sync rate 60 : autocam off

make camera 1
position camera 1, 0, 20, -100

make matrix 1, 1000, 1000, 25, 25
position matrix 1, -500, 0, -500
make object cube 1, 10
position object 1, 0, 0, 0

MaxY# = 10
MinY# = -10

Operator# = 0.1
PosOperator# = 0.1
NegOperator# = -0.1
Speed# = 0
MaxSpeed# = 2.5

do
set cursor 0,0

if object position y(1) > MaxY# then Operator# = PosOperator#
if object position y(1) < MinY# then Operator# = NegOperator#

position object 1, 0, object position y(1)+Speed#, 0

Dec Speed#, Operator#
if Speed# > 2.5 then Speed# = 2.5
if Speed# < -2.5 then Speed# = -2.5

point camera 1, object position x(1), object position y(1), object position z(1)

print "X Y Z: ("; object position x(1);" ,"; object position y(1);" ,"; object position z(1)
print "Speed: ";Speed#
print "Operator: ";Operator#
sync
loop

(\__/)
(O.o )
(> < ) This is Bunny. Copy Bunny into your signature to help him on his way to world domination!

Back to top

Profile PM Website

kordman916

17

Years of Service

User Offline

Joined: 5th Oct 2007

Location:

Posted: 7th May 2009 04:34

Link

how would i slow it down

Back to top

Profile PM Email

bobbel

15

Years of Service

User Offline

Joined: 5th Jan 2009

Location: In my DBPro case xD

Posted: 7th May 2009 08:33

Link

you have the MaxSpeed# = 2.5 variable, if you adjust it, it'll slow down

i forgot to ad something to the last code, this one is better

+ Code Snippet

sync on : sync rate 60 : autocam off

make camera 1
position camera 1, 0, 20, -100

make matrix 1, 1000, 1000, 25, 25
position matrix 1, -500, 0, -500
make object cube 1, 10
position object 1, 0, 0, 0

MaxY# = 10
MinY# = -10

Operator# = 0.1
PosOperator# = 0.1
NegOperator# = -0.1
Speed# = 0
MaxSpeed# = 1.3
MinSpeed# = MaxSpeed#*-1

do
set cursor 0,0

if object position y(1) > MaxY# then Operator# = PosOperator#
if object position y(1) < MinY# then Operator# = NegOperator#

position object 1, 0, object position y(1)+Speed#, 0

Dec Speed#, Operator#
if Speed# > MaxSpeed# then Speed# = MaxSpeed#
if Speed# < MinSpeed# then Speed# = MinSpeed#

point camera 1, object position x(1), object position y(1), object position z(1)

print "X Y Z: ("; object position x(1);" ,"; object position y(1);" ,"; object position z(1)
print "Speed: ";Speed#
print "Operator: ";Operator#
sync
loop

(\__/)
(O.o )
(> < ) This is Bunny. Copy Bunny into your signature to help him on his way to world domination!

Back to top

Profile PM Website

CuCuMBeR

21

Years of Service

User Offline

Joined: 11th Jan 2003

Location: Turkey

Posted: 8th May 2009 15:02

Link

Try this more usable and more elegant

way:

+ Code Snippet

Sync On
Rem Ground
Make Object Plain 1, 1000, 1000, 1
xRotate Object 1, 90

Rem Cube
Make Object cube 2, 30

Rem position camera to watch scene
Position Camera 0, 20, -100

Rem irrelevant shadow stuff, to visualize the hovering better
set global shadows on : set global shadow shades 1 : set global shadow color 0,0,0,64
set shadow light 1,50,100,0,500 : set shadow position -1,50,100,0
set shadow shading on 2

rem main loop
Do
rem a wrapvalue function to pass a wrapping angle to ping pong function
ang# = math_wrapFloat(ang#, 0.5)
rem 20 and 40 are the values which you want to interval inbetween
y# = math_wrapPingPong(y#, 20, 40, ang#)
Position Object 2, 0.0, y#, 0.0

Sync
Loop
End

Function math_wrapFloat(n As Float, spd As Float)
   n = n + spd
   If n => 360.0 Then n = 0.0
endFunction n

Function math_wrapPingPong(n As Float, rng1 As Float, rng2 As Float, ang As Float)
Local i As Float
i = (rng2 - rng1) / 2.0
   n = rng1 + i + (Cos(ang) * i)
endFunction n

There is always one more imbecile than you counted on.

Back to top

Profile PM

bobbel

15

Years of Service

User Offline

Joined: 5th Jan 2009

Location: In my DBPro case xD

Posted: 8th May 2009 16:28

Link

very good, i don;t understand it, but its better than my code

(\__/)
(O.o )
(> < ) This is Bunny. Copy Bunny into your signature to help him on his way to world domination!

Back to top

Profile PM Website

CuCuMBeR

21

Years of Service

User Offline

Joined: 11th Jan 2003

Location: Turkey

Posted: 8th May 2009 16:54 Edited at: 8th May 2009 16:55

Link

which part you dont understand?

This function is same as wrapvalue() in DBPro
It just fakes the n variable as global and adds the spd variable to it every loop and wraps it to 0 if its bigger than 360

+ Code Snippet

Function math_wrapFloat(n As Float, spd As Float)
   n = n + spd
   If n => 360.0 Then n = 0.0
endFunction n

This function uses cos() of the above n variable(360 degree angle in this case) and smoothly intervals it between the given range

+ Code Snippet

Function math_wrapPingPong(n As Float, rng1 As Float, rng2 As Float, ang As Float)
Local i As Float
i = (rng2 - rng1) / 2.0
   n = rng1 + i + (Cos(ang) * i)
endFunction n

and below part in the main loop;
ang# is the angle i mentioned above(wrapped variable)
y# is the value which we smoothly interval between 20 and 40 back and forth
0.5 is the speed of wrapping thus effects the hovering speed

+ Code Snippet

ang# = math_wrapFloat(ang#, 0.5)
y# = math_wrapPingPong(y#, 20, 40, ang#)

Hope its more clear now.

There is always one more imbecile than you counted on.

Back to top

Profile PM

CuCuMBeR

21

Years of Service

User Offline

Joined: 11th Jan 2003

Location: Turkey

Posted: 8th May 2009 17:13

Link

This one shows how to use different speeds for different cubes

Type obj
a As Float
y As Float
endtype

Sync On
Rem Ground
Make Object Plain 1, 1000, 1000, 1
xRotate Object 1, 90

Rem irrelevant shadow stuff, to visualize the hovering better
set global shadows on : set global shadow shades 1 : set global shadow color 0,0,0,64
set shadow light 1,50,100,50,500 : set shadow position -1,50,100,50
Rem Cube
For i = 2 To 11
   Make Object cube i, 10
   set shadow shading on i
Next i

Rem position camera to watch scene
Position Camera 0, 20, -100

dim obj(10) as obj
rem main loop
Do
For i = 1 To 10
   obj(i).a = math_wrapFloat(obj(i).a, i/10.0)
   obj(i).y = math_wrapPingPong(obj(i).y, 20, 40, obj(i).a)
   Position Object i+1, (i*15)-50, obj(i).y, 0.0
   Center Text object screen x(i+1), object screen y(i+1), Left$(Str$(obj(i).a), 6)
Next i

Control Camera using arrowkeys 0, 1, 1

Sync
Loop
End

Function math_wrapFloat(n As Float, spd As Float)
   n = n + spd
   If n => 360.0 Then n = 0.0
endFunction n

Function math_wrapPingPong(n As Float, rng1 As Float, rng2 As Float, ang As Float)
Local i As Float
i = (rng2 - rng1) / 2.0
   n = rng1 + i + (Cos(ang) * i)
endFunction n

+ Code Snippet

Type obj
a As Float
y As Float
endtype

Sync On
Rem Ground
Make Object Plain 1, 1000, 1000, 1
xRotate Object 1, 90

Rem irrelevant shadow stuff, to visualize the hovering better
set global shadows on : set global shadow shades 1 : set global shadow color 0,0,0,64
set shadow light 1,50,100,50,500 : set shadow position -1,50,100,50
Rem Cube
For i = 2 To 11
   Make Object cube i, 10
   set shadow shading on i
Next i

Rem position camera to watch scene
Position Camera 0, 20, -100

dim obj(10) as obj
rem main loop
Do
For i = 1 To 10
   obj(i).a = math_wrapFloat(obj(i).a, i/10.0)
   obj(i).y = math_wrapPingPong(obj(i).y, 20, 40, obj(i).a)
   Position Object i+1, (i*15)-50, obj(i).y, 0.0
   Center Text object screen x(i+1), object screen y(i+1), Left$(Str$(obj(i).a), 6)
Next i

Control Camera using arrowkeys 0, 1, 1

Sync
Loop
End

Function math_wrapFloat(n As Float, spd As Float)
   n = n + spd
   If n => 360.0 Then n = 0.0
endFunction n

Function math_wrapPingPong(n As Float, rng1 As Float, rng2 As Float, ang As Float)
Local i As Float
i = (rng2 - rng1) / 2.0
   n = rng1 + i + (Cos(ang) * i)
endFunction n

This one shows how to use different height ranges for each cube

Type obj
a As Float
y As Float
r1 As Float
r2 As Float
endtype

dim obj(10) as obj

Sync On
Rem Ground
Make Object Plain 1, 1000, 1000, 1
xRotate Object 1, 90

Rem irrelevant shadow stuff, to visualize the hovering better
set global shadows on : set global shadow shades 1 : set global shadow color 0,0,0,64
set shadow light 1,50,100,50,500 : set shadow position -1,50,100,50
Rem Cube
For i = 2 To 11
   Make Object cube i, 10
   set shadow shading on i
   obj(i-1).r1 = Rnd(20)
   obj(i-1).r2 = Rnd(40)
Next i

Rem position camera to watch scene
Position Camera 0, 20, -100

rem main loop
Do
For i = 1 To 10
   obj(i).a = math_wrapFloat(obj(i).a, 0.2)
   obj(i).y = math_wrapPingPong(obj(i).y, obj(i).r1, obj(i).r2, obj(i).a)
   Position Object i+1, (i*15)-50, obj(i).y, 0.0
   Center Text object screen x(i+1), object screen y(i+1), Left$(Str$(obj(i).y), 6)
Next i

Control Camera using arrowkeys 0, 1, 1

Sync
Loop
End

Function math_wrapFloat(n As Float, spd As Float)
   n = n + spd
   If n => 360.0 Then n = 0.0
endFunction n

Function math_wrapPingPong(n As Float, rng1 As Float, rng2 As Float, ang As Float)
Local i As Float
i = (rng2 - rng1) / 2.0
   n = rng1 + i + (Cos(ang) * i)
endFunction n

+ Code Snippet

Type obj
a As Float
y As Float
r1 As Float
r2 As Float
endtype

dim obj(10) as obj

Sync On
Rem Ground
Make Object Plain 1, 1000, 1000, 1
xRotate Object 1, 90

Rem irrelevant shadow stuff, to visualize the hovering better
set global shadows on : set global shadow shades 1 : set global shadow color 0,0,0,64
set shadow light 1,50,100,50,500 : set shadow position -1,50,100,50
Rem Cube
For i = 2 To 11
   Make Object cube i, 10
   set shadow shading on i
   obj(i-1).r1 = Rnd(20)
   obj(i-1).r2 = Rnd(40)
Next i

Rem position camera to watch scene
Position Camera 0, 20, -100


rem main loop
Do
For i = 1 To 10
   obj(i).a = math_wrapFloat(obj(i).a, 0.2)
   obj(i).y = math_wrapPingPong(obj(i).y, obj(i).r1, obj(i).r2, obj(i).a)
   Position Object i+1, (i*15)-50, obj(i).y, 0.0
   Center Text object screen x(i+1), object screen y(i+1), Left$(Str$(obj(i).y), 6)
Next i

Control Camera using arrowkeys 0, 1, 1

Sync
Loop
End

Function math_wrapFloat(n As Float, spd As Float)
   n = n + spd
   If n => 360.0 Then n = 0.0
endFunction n

Function math_wrapPingPong(n As Float, rng1 As Float, rng2 As Float, ang As Float)
Local i As Float
i = (rng2 - rng1) / 2.0
   n = rng1 + i + (Cos(ang) * i)
endFunction n

There is always one more imbecile than you counted on.

Back to top

Profile PM

bobbel

15

Years of Service

User Offline

Joined: 5th Jan 2009

Location: In my DBPro case xD

Posted: 8th May 2009 20:13

Link

ok now i get it, i thought the ang# variable was a real angle value, but its not i think

(\__/)
(O.o )
(> < ) This is Bunny. Copy Bunny into your signature to help him on his way to world domination!

Back to top

Profile PM Website

CuCuMBeR

21

Years of Service

User Offline

Joined: 11th Jan 2003

Location: Turkey

Posted: 8th May 2009 21:58 Edited at: 8th May 2009 21:59

Link

well, it is a real angle value. in this case.

There is always one more imbecile than you counted on.

Back to top

Profile PM

kordman916

17

Years of Service

User Offline

Joined: 5th Oct 2007

Location:

Posted: 9th May 2009 04:05

Link

Hehe, thanks guys this helps alot.

Back to top

Profile PM Email

bobbel

15

Years of Service

User Offline

Joined: 5th Jan 2009

Location: In my DBPro case xD

Posted: 16th May 2009 23:16

Link

Cucumber, i use your code in my game ok? i'll put you in teh credits

(\__/)
(O.o )
(> < ) This is Bunny. Copy Bunny into your signature to help him on his way to world domination!

Back to top

Profile PM Website

Sorry your browser is not supported!

Newcomers DBPro Corner / Hovering Objects