Sorry your browser is not supported!

sync on
sync rate 60

autocam off

randomize timer()

global radius# as double float : radius# = 7.0

makeLevel()
makePlayer()

global rtimer as integer
global stimer as integer
global vtimer as integer

rem player movement vector
global vx# as double float
global vy# as double float
global vz# as double float

global gravity# as double float : gravity# = -0.1
global slope# as double float : slope# = 0.5
global ground as integer : ground = 1
global jumptimer as integer : jumptimer = 0

global syncmode as integer : syncmode = 60
global hide as integer : hide = 0

do

   MovePlayer()

   rem enable/disable sync limit
   if inkey$()="l" and stimer<timer()
      stimer = timer()+300
      syncmode = 60-syncmode
      sync rate syncmode
   endif

   positionCameraToObject(2,view)

   text 0,0,"FPS="+str$(screen fps())
   text 0,10,"POLYGONS="+str$(statistic(1))
   text 0,20,"DRAWS: "+str$(statistic(5))
   text 0,30,"POLYS/DRAW: "+str$(int((statistic(1)*1.0)/(statistic(5)*1.0)))
   text 0,40,"Touching Ground: "+str$(ground)

   sync
loop

function makeLevel()

   rem add box
   make object box 1,200,1,200
   position object 1,0,0,0
   sc_setupObject 1,1,2

   load image "jb_wood.bmp",1
   texture object 1,1
   scale object texture 1,12,12

   load object "new.x",3
   scale object 3,4100,4100,4100
   sc_setupobject 3,1,0
   sc_allowobjectscaling 3

   rem all level objects are group 1
endfunction

function makePlayer()
   make object box 2,4,5,2
   position object 2,-80,15,-20
   sc_setupObject 2,0,0

   rem player has no group
endfunction

function movePlayer()

   oldx# = object position x(2)
   oldy# = object position y(2)
   oldz# = object position z(2)

   rem apply gravity, and user changes to movement
   angy# = object angle y(2)
   vx# = 0
   vz# = 0
   rem if player is jumping or falling then apply 'normal' gravity
   rem if not attempt to keep the player stuck to the floor
   if vy#=0 and jumptimer=0 then vy# = vy# + 10*gravity# else vy# = vy# + gravity#
   if keystate(32)=1 then vx# = vx# + cos(angy#) : vz# = vz# - sin(angy#)
   if keystate(30)=1 then vx# = vx# - cos(angy#) : vz# = vz# + sin(angy#)
   if keystate(31)=1 then vx# = vx# - sin(angy#) : vz# = vz# - cos(angy#)
   if keystate(17)=1 then vx# = vx# + sin(angy#) : vz# = vz# + cos(angy#)
   rem only jump if on ground, and a certain time after last jump
   if ground=1
      if spacekey()=1 and jumptimer=0 then vy# = vy# + 3.0 : jumptimer = 20
   endif

   rem this would be the player's final position without collision
   x# = oldx#+vx#
   y# = oldy#+vy#
   z# = oldz#+vz#

   rem first handle gravity - seperated from horizontal movement
   rem to achieve a more realistic effect
   rem Method: simple - cast a sphere vertically down, if it hits the level then
   rem                  position the object there (sticky collision) then move
   rem                  on to horizontal movement
   rem   more complex - if we were to only use the simple method the player would be
   rem                  allowed to climb almost vertical slopes. Alternative is to
   rem                  get the normalY direction to work out how flat the gorund
   rem                  below the player is, 0-slope# is flatter, slope#-1 is steeper.
   rem                  if it's flat, use sticky collision, if it's steep slide the
   rem                  player down the slope. Changing slope# determines how steep the
   rem                  player can climb. NOTE: this also effects stairs.
   collide = sc_SphereCastGroup(1,oldx#,oldy#,oldz#,oldx#,oldy#+vy#,oldz#,radius#,0)
   if collide>0
      rem how flat is this ground
      ny# = sc_getCollisionNormalY()
      if abs(ny#)>slope#
         rem FLAT, stick
         oldy# = sc_getStaticCollisionY()
      else
         rem STEEP, slide
         x# = x# - oldx# : z# = z# - oldz#
         oldx# = sc_getCollisionSlideX()
         oldy# = sc_getCollisionSlideY()
         oldz# = sc_getCollisionSlideZ()
         x# = x# + oldx# : z# = z# + oldz#
      endif

      rem ny#<0 means the player has hit a ceiling rather than a floor

      if ny#>slope#
         rem only on ground if standing on flat ground
         ground = 1
         vy# = 0
      else
         ground = 0
         rem if player has hit a flat ceiling then stop vy# movement
         if ny#<-slope# then vy# = gravity#
      endif
   else
      rem nothing below player, not on ground, add vertical speed to player
      oldy# = oldy# + vy#
      ground = 0
   endif

   rem jumptimer will decrease only when player is back on ground
   rem creates a pause between two successive jumps
   if ground = 1 and jumptimer>0 then dec jumptimer

   rem handle horizontal movement as sliding
   rem player only collides with group 1 (level) objs and moves freely through others
   collide = sc_SphereSlideGroup(1,oldx#,oldy#,oldz#,x#,oldy#,z#,radius#,0)

   if collide>0
      rem if hit, reposition player, halt movement vector
      x# = sc_getCollisionSlideX()
      oldy# = sc_getCollisionSlideY()
      z# = sc_getCollisionSlideZ()
      vx# = 0
      vz# = 0

      rem possible code for giving the player a jumping help up stairs...
      rem might be useful if slope# is set very high but stairs are still required
      `dy# = oldy#-sc_getStaticCollisionY()
      `if dy#<slope# and dy#>0 and ground=1 then vy# = 0.5
   endif

   rem position the player
   position object 2,x#,oldy#,z#

   sc_updateObject 2

endfunction

function positionCameraToObject(obj,thirdPerson)
   position camera object position x(2),object position y(2)+5,object position z(2)
   rotate camera camera angle x()+(mousemovey()/2.0),camera angle y()+(mousemovex()/2.0),0
   yrotate object 2,camera angle y()
endfunction

if memblock exist(1) then delete memblock 1