Sorry your browser is not supported!

Collision=SC_sphereCast(0,camera position x(),camera position y(),camera position z(),oldX,oldY,oldZ,50,0)

Collision=SC_sphereCast(0,oldX,oldY,oldZ,camera position x(),camera position y(),camera position z(),50,0)

` by LBFN  31 March,2010
sync on : sync rate 60
autocam off : hide mouse
backdrop on : color backdrop rgb(0,45,189)
global obj as integer : obj = 1 : global player as integer : global collide as integer
global radius# as float : radius# = 5.0
MakeWorld()
position camera -120,2,134
disable escapekey
repeat
  MoveCamera()
  Debug()
  sync
until keystate(1) = 1
DeleteAll()
show mouse
end

function MakeWorld()
` green floor
flor = GetObj()
make object box flor,500,10,500
position object flor,0,-5,0
color object flor,rgb(0,200,0)
sc_setupobject flor,1,2

` brown walls
wall = GetObj()
make object box wall,500,20,10
position object wall,0,10,245
color object wall,rgb(155,73,13)
sc_setupobject wall,1,2
wall = GetObj()
make object box wall,500,20,10
position object wall,0,10,-245
color object wall,rgb(155,73,13)
sc_setupobject wall,1,2
wall = GetObj()
make object box wall,10,20,500
position object wall,245,10,0
color object wall,rgb(155,73,13)
sc_setupobject wall,1,2
wall = GetObj()
make object box wall,10,20,500
position object wall,-245,10,0
color object wall,rgb(155,73,13)
sc_setupobject wall,1,2
` put some in the middle
wall = GetObj()
make object box wall,100,20,30
position object wall,0,10,0
color object wall,rgb(190,0,190)
set object ambience wall,rgb(190,0,190)
sc_setupobject wall,1,2
wall = GetObj()
make object box wall,30,20,30
position object wall,110,10,110
color object wall,rgb(190,190,0)
set object ambience wall,rgb(190,190,0)
sc_setupobject wall,1,2


` sphere where the camera is
player = GetObj()
make object sphere player,10
sc_setupobject player,0,1
hide object player

endfunction

function MoveCamera()
if upkey() = 1
  collide = CheckColl(2.0)
  if collide = 0 then move camera 2 : position object player, camera position x(),camera position y(),camera position z()
endif
if downkey() = 1
  collide = CheckColl(-2.0)
  if collide = 0 then move camera -2 : position object player, camera position x(),camera position y(),camera position z()
endif
if rightkey() = 1
  y# = camera angle y()
  y# = wrapvalue(y# + 1.5)
  yrotate camera y#
  yrotate object player,y#
endif
if leftkey() = 1
  y# = camera angle y()
  y# = wrapvalue(y# - 1.5)
  yrotate camera y#
  yrotate object player,y#
endif

endfunction

function CheckColl(atm#)
oldx# = object position x(player)
oldy# = object position y(player)
oldz# = object position z(player)
move object player,atm#
x# = object position x(player)
y# = object position y(player)
z# = object position z(player)
collide = sc_spherecastgroup( 1, oldx#, oldy#, oldz#, x#, y#, z#, radius#, 0 )
if collide > 0
  position object player,oldx#,oldy#,oldz#
endif
sc_updateobject player
endfunction collide

function GetObj()
okay = 0
while object exist(obj) = 1
  inc obj,1 : okay = 1
endwhile
endfunction obj

function DeleteAll()
 for j = 1 to obj -1
   if object exist(j) = 1 then delete object j
 next j
endfunction

function Debug()
text 10,10,"FPS: " + str$(screen fps())
`text 10,50,"CAMX# = " + str$(camera position x())
`text 10,70,"CAMZ# = " + str$(camera position z())

endfunction

gosub SetupProgramEnvironment
gosub SetupPlayer
gosub SetupWorld

do
  gosub HandlePlayer
  gosub HandleCamera
  sync
loop

end

SetupProgramEnvironment:
  set display mode 1024,768,32,1
  sync on
  
  autocam off
  hide mouse
  return

SetupPlayer:
  type Player
    Object      as integer
    Radius      as float
    Speed       as float
    MaxSlope    as float
    
    XPos        as float
    YPos        as float
    ZPos        as float
    
    XAng        as float
    YAng        as float
    ZAng        as float
    
    XVel        as float
    YVel        as float
    ZVel        as float
  endtype
  
  global Player as Player
  
  Player.Object=1
  Player.Radius=5
  Player.Speed=1.0
  Player.MaxSlope=0.7
  
  Player.XPos=0
  Player.YPos=30
  Player.ZPos=0
  
  Player.XAng=0
  Player.YAng=0
  Player.ZAng=0
  
  `The player object doesn't need to be setup because nothing will be colliding with the player object.
  `All checks are done using a sphere that encompasses the player, and has nothing to do with the player object itself.
  make object sphere Player.Object,10
  position object Player.Object,Player.XPos,Player.YPos,Player.ZPos
  rotate object Player.Object,Player.XAng,Player.YAng,Player.ZAng
  
  #constant FollowDistance 30
  FollowAngle as float
  FollowAngle=30
  return

SetupWorld:
  `All terrain objects will be placed in this group
  #constant TerrainGroup 1
  
  `The ground
  make object plane 2,100,100,1
  xrotate object 2,90
  SC_setupObject 2,TerrainGroup,2
  
  `15 random boxes
  for a=3 to 18
    XLength=rnd(10)+5
    YLength=rnd(10)+5
    ZLength=rnd(10)+5
    make object box a,XLength,YLength,ZLength
    position object a,rnd(100)-50,YLength/2.0,rnd(100)-50
    rotate object a,rnd(360),rnd(360),0
    SC_setupObject a,TerrainGroup,2
  next a
  
  #constant WorldGravity 0.1
  return

HandlePlayer:
  `Mouse moves camera and steers player
  Player.YAng=wrapvalue(Player.YAng+mousemovex()/5.0)
  dec FollowAngle,mousemovey()/5.0
  if FollowAngle<0 then FollowAngle=0
  if FollowAngle>85 then FollowAngle=85
  
  `WASD Strafe
  Player.XVel=0 : Player.ZVel=0
  if keystate(17) then inc Player.XVel,Player.Speed*sin(Player.YAng) : inc Player.ZVel,Player.Speed*cos(Player.YAng)
  if keystate(31) then dec Player.XVel,Player.Speed*sin(Player.YAng) : dec Player.ZVel,Player.Speed*cos(Player.YAng)
  if keystate(32) then inc Player.XVel,Player.Speed*sin(Player.YAng+90) : inc Player.ZVel,Player.Speed*cos(Player.YAng+90)
  if keystate(30) then inc Player.XVel,Player.Speed*sin(Player.YAng-90) : inc Player.ZVel,Player.Speed*cos(Player.YAng-90)
  
  `Space to jump
  if spacekey() and Player.YVel=0 then inc Player.YVel,2.1
  
  dec Player.YVel,WorldGravity
  
  `Alrighty, to the collision!
  `The first check to do is to cast a sphere of radius Player.Radius straight down to check for collision with a floor.
  `Lateral checks with the walls and stuff will be done later.
  Collision=SC_sphereCastGroup(TerrainGroup,Player.XPos,Player.YPos,Player.ZPos,Player.XPos,Player.YPos+Player.YVel,Player.ZPos,Player.Radius,0)
  `If there was a collision,
  if Collision
    `Get the Y component of the normal of the surface we're colliding with (the ground we're standing on).
    YNormal as float
    YNormal=SC_getCollisionNormalY()
    `If the ground is flat enough to stand on, get the sticky collision point.
    `Completely Flat => YNormal=+/-1  /  Completely Vertical => YNormal=0
    if abs(YNormal)>=Player.MaxSlope
      Player.YPos=SC_getStaticCollisionY()
      Player.YVel=0
    `Otherwise, slide down the surface
    else
      Player.XPos=SC_getCollisionSlideX()
      Player.YPos=SC_getCollisionSlideY()
      Player.ZPos=SC_getCollisionSlideZ()
    endif
  `If there was no collision, move the player up or down normally.
  else
    inc Player.YPos,Player.YVel
  endif
  
  `This check is for the surfaces with which we collide laterally (walls).
  `We use SC_sphereSlideGroup instead of SC_sphereCastGroup because SlideGroup provides better sliding collision data, which is what we're after.
  Collision=SC_sphereSlideGroup(TerrainGroup,Player.XPos,Player.YPos,Player.ZPos,Player.XPos+Player.XVel,Player.YPos,Player.ZPos+Player.ZVel,Player.Radius,0)
  `If there was a collision, slide along the face
  if Collision
    Player.XPos=SC_getCollisionSlideX()
    Player.YPos=SC_getCollisionSlideY()
    Player.ZPos=SC_getCollisionSlideZ()
  `Otherwise, move the player laterally as normal
  else
    inc Player.XPos,Player.XVel
    inc Player.ZPos,Player.ZVel
  endif
  
  `Place the player object at the player's position
  position object Player.Object,Player.XPos,Player.YPos,Player.ZPos
  rotate object Player.Object,Player.XAng,Player.YAng,Player.ZAng
  return

HandleCamera:
  `Start the camera oriented with the player and then move it backwards
  position camera 0,Player.XPos,Player.YPos,Player.ZPos
  rotate camera 0,Player.XAng+FollowAngle,Player.YAng,Player.ZAng
  move camera 0,-FollowDistance
  
  `We want the camera to slide along any face it hits, so we use SC_sphereSlideGroup to slide a sphere with a radius of 1
  `from the player's position to the camera's position (we'll change the camera's position if there's a hit, of course).
  Collision=SC_sphereSlideGroup(TerrainGroup,Player.XPos,Player.YPos,Player.ZPos,camera position x(0),camera position y(0),camera position z(0),1,0)
  `If there was a collision, position the camera at the sliding collision point
  if Collision
    position camera 0,SC_getCollisionSlideX(),SC_getCollisionSlideY(),SC_getCollisionSlideZ()
    point camera 0,Player.XPos,Player.YPos,Player.ZPos
  endif
  return