Post your code, and include the image as an upload, so we can see what you are trying.
Here is some code that demonstrates a sprite that has one color set to transparent.
' first we draw a purple square
' with a green cross centered on it
ink rgb(255,0,255),0
box 0,0,100,100
ink rgb(0,255,0),0
box 40,20,60,80
box 20,40,80,60
' now grab the image and save it
get image 1,0,0,100,100,1
save image "testimage.bmp",1
' draw a background so we can see the transparency
cls
for x = 0 to 640 step 20
for y = 0 to 480 step 20
ink rgb(200,200,200),0
box x,y,x+10,y+10
box x+10,y+10,x+20,y+20
ink rgb(255,255,255),0
box x+10,y,x+20,y+10
box x,y+10,x+10,y+20
next y
next x
' this command turns off the automatic blue background
set sprite 1,1,1
'move the sprite, no transparency
for x = 0 to 540 step 5
sprite 1,x,150,1
wait 1
next x
do
'make the purple transparent
'and reload the image
set image colorkey 255,0,255
load image "testimage.bmp",1
'move the sprite, purple is now transparent
for x = 540 to 0 step -5
sprite 1,x,150,1
wait 1
next x
' this time green is transparent
' load the image again
set image colorkey 0,255,0
load image "testimage.bmp",1
' move the sprite, green is now transparent
for x = 0 to 540 step 5
sprite 1,x,150,1
wait 1
next x
loop
Note that .png files already include transparency, so if you use one of those, you won't need to do the SET IMAGE COLORKEY. This is preferable, since SET IMAGE COLORKEY affects ALL subsequent images.
