Following the curve of a .x terrain?

Author

Message

Kieran

18

Years of Service

User Offline

Joined: 6th Aug 2006

Location: Hamilton, New Zealand

Posted: 15th Apr 2010 05:00

Link

Ok well currently I have a terrain, which has a scorpion. The scorpion walks over it at the correct height as found using this equation:

+ Code Snippet

yint# = 10000 - intersect object(objTerrain, x#, 10000, z#, x#, -10000, z#)
position object objPlayer, x#, yint#, z#

However, at certain points parts of the scorpion go through the ground as the scorpion is always horizontal. I am wondering how I can find the angle I need to position the scorpion at using raycasting or such on the terrain.

Back to top

Profile PM

Dia

19

Years of Service

User Offline

Joined: 16th Jan 2005

Location:

Posted: 15th Apr 2010 12:31 Edited at: 16th Apr 2010 15:39

Link

there used to be a tutorial called limit rush or somethign by binary moon on the website, but I don't know where it has gone with the new update (still looking around)

it used a matrix rather than adv terrain but it could be adapted pretty easily. If you are using a terrain mesh rather than an adv terrain it should be pretty easy to adapt.

This is what I used to determine pitch and roll of my tank across an advanced terrain:

`work out tank tilting on the terrain (straight outa the binary moon tutorial!)
     distVal#=1

`work out the positions of the front, back, left and right of the vehicle
      ang#=object angle y(49)
     frontX#=newxvalue(object position x(49),ang#,distVal#)
     frontZ#=newzvalue(object position z(49),ang#,distVal#)
      ang#=object angle y(49)+180
     backX#=newxvalue(object position x(49),ang#,distVal#)
     backZ#=newzvalue(object position z(49),ang#,distVal#)
      ang#=object angle y(49)+90
     leftX#=newxvalue(object position x(49),ang#,distVal#)
     leftZ#=newzvalue(object position z(49),ang#,distVal#)
      ang#=object angle y(49)-90
     rightX#=newxvalue(object position x(49),ang#,distVal#)
     rightZ#=newzvalue(object position z(49),ang#,distVal#)

`work out the different heights
      frontHeight#=get terrain ground height(1,frontX#,frontZ#)
      backHeight#=get terrain ground height(1,backX#,backZ#)
      leftHeight#=get terrain ground height(1,leftX#,leftZ#)
      rightHeight#=get terrain ground height(1,rightX#,rightZ#)

`Work out tilt values
      xAng#=wrapvalue(Atanfull((2*distval#),(frontHeight#-backHeight#))-90)
      zAng#=wrapvalue(Atanfull((2*distval#),(rightheight#-leftHeight#))-90)

`update the vehicle rotation
      rotate limb 49,1,xAng#,0,zAng#

+ Code Snippet

`work out tank tilting on the terrain (straight outa the binary moon tutorial!)
     distVal#=1

      `work out the positions of the front, back, left and right of the vehicle
      ang#=object angle y(49)
     frontX#=newxvalue(object position x(49),ang#,distVal#)
     frontZ#=newzvalue(object position z(49),ang#,distVal#)
      ang#=object angle y(49)+180
     backX#=newxvalue(object position x(49),ang#,distVal#)
     backZ#=newzvalue(object position z(49),ang#,distVal#)
      ang#=object angle y(49)+90
     leftX#=newxvalue(object position x(49),ang#,distVal#)
     leftZ#=newzvalue(object position z(49),ang#,distVal#)
      ang#=object angle y(49)-90
     rightX#=newxvalue(object position x(49),ang#,distVal#)
     rightZ#=newzvalue(object position z(49),ang#,distVal#)

      `work out the different heights
      frontHeight#=get terrain ground height(1,frontX#,frontZ#)
      backHeight#=get terrain ground height(1,backX#,backZ#)
      leftHeight#=get terrain ground height(1,leftX#,leftZ#)
      rightHeight#=get terrain ground height(1,rightX#,rightZ#)

      `Work out tilt values
      xAng#=wrapvalue(Atanfull((2*distval#),(frontHeight#-backHeight#))-90)
      zAng#=wrapvalue(Atanfull((2*distval#),(rightheight#-leftHeight#))-90)

      `update the vehicle rotation
      rotate limb 49,1,xAng#,0,zAng#

basically this code checks the terrain height at 4 positions around the tank (fron, back, left, right, at 1 unit displaced from the mesh origin) if you are using a mesh object rather than heightmap or memblock terrain, you could use raycasting rather than get terrain ground height to get the 4 height values

then the height difference is turned into a pitch (xang#) and bank (zang#) variable

This is not the Sig you are looking for....

Back to top

Profile PM

chafari

Valued Member

18

Years of Service

User Offline

Joined: 2nd May 2006

Location: Canary Islands

Posted: 15th Apr 2010 12:33

Link

HI there.Here is an example to get what you want.If you are using advance terrain, you have to change get ground height for get terrain ground height

I hope it can help to you.

Cheers.

`AJUSTE DE UN TANQUE CON EL TERRENO :EJEMPLO 2
create bitmap 1,50,50:for i= 1 to 1550:ink rgb(230,95,55),0:line rnd(60),i,i,rnd(130)
next i:blur bitmap 1,6:get image 1,10,10,50,50:delete bitmap 1

make matrix 1,10000.0,10000.0,25,25
prepare matrix texture 1,1,1,1
randomize matrix 1,350.0
rem set matrix height 1,12,12,700.0
update matrix 1
set ambient light 20

`CREAMOS LOS OBJETOS CHIVATOS, Y AL OBJETO BLINDADO
make object sphere 1,10
make object sphere 4,10
make object sphere 5,10
`------------------------------------------------------
`---OBJETO BLINDADO CON UNOS CUANTOS LIMBS-------------
make object box 2,50,5,80:color object 2,rgb(50,100,100)
make object box 3,40,20,50
make mesh from object 1,3 :delete object 3
add limb 2,1,1 :add limb 2,2,1
scale limb 2,2,10,10,120 :offset limb 2,2,0,22,30:offset limb 2,1,0,10,0
color limb 2,2,rgb(0,0,200):color limb 2,1,rgb(0,50,170)

x#=500
z#=500
sync on
do
if upkey()=1 then x#=newxvalue(x#,a#,1) : z#=newzvalue(z#,a#,1)
if downkey()=1 then x#=newxvalue(x#,a#,-1) : z#=newzvalue(z#,a#,-1)
if leftkey()=1 then a#=wrapvalue(a#-1)
if rightkey()=1 then a#=wrapvalue(a#+1)

`calculamos la coordenadas "Y" de los dos chivatos
yb#=get ground height(1,object position x(1),object position z(1))
yb2#=get ground height(1,object position x(5),object position z(5))
yb3#=get ground height(1,object position x(4),object position z(4))

`calculamos la coordenada "y" del coche
y#=get ground height(1,x#,z#)
`pocisionamos a los objetos
position object 1,x#,yb#+40,z#
position object 2,x#,y#+30,z#
position object 5,x#,yb2#,z#
position object 4,x#,yb3#,z#

`rotamos a los objetos
yrotate object 1,a#
yrotate object 2,a#
yrotate object 5,a#
yrotate object 4,a#

`desplazamos al objeto chivato que lleva el blindado, para calcular la inclinacion
move object 1,80
`desplazamos al segundo chivato, que comprobara los alaveos
move object left 5,30
move object right 4,30

`hacemos que el blindado apunte a las coordenadas del chivato
`solo con esto, hemos conseguido, el efecto que se buscaba
point object 2,object position x(1),object position y(1),object position z(1)

`hacemos que el blindado, se alavee hacia la izquierda, la algura del blindado
`menos la atura del chivato..... TACHANNN
roll object left 2,y#-yb2#
roll object right 2,y#-yb3#
`Posiciona la cámara por detrás del objeto
cx#=newxvalue(x#,wrapvalue(a#+180),300)
cz#=newzvalue(z#,wrapvalue(a#+180),300)
cy#=get ground height(1,cx#,cz#)+100.0
position camera cx#,cy#+200,cz#

`enfoca la cámara al objeto
point camera x#,y#,z#
sync
loop

+ Code Snippet

`AJUSTE DE UN TANQUE CON EL TERRENO :EJEMPLO 2
create bitmap 1,50,50:for i= 1 to 1550:ink rgb(230,95,55),0:line rnd(60),i,i,rnd(130)
next i:blur bitmap 1,6:get image 1,10,10,50,50:delete bitmap 1

make matrix 1,10000.0,10000.0,25,25
prepare matrix texture 1,1,1,1
randomize matrix 1,350.0
rem set matrix height 1,12,12,700.0
update matrix 1
set ambient light 20

`CREAMOS LOS OBJETOS CHIVATOS, Y AL OBJETO BLINDADO
make object sphere 1,10
make object sphere 4,10
make object sphere 5,10
`------------------------------------------------------
`---OBJETO BLINDADO CON UNOS CUANTOS LIMBS-------------
make object box 2,50,5,80:color object 2,rgb(50,100,100)
make object box 3,40,20,50
make mesh from object 1,3 :delete object 3
add limb 2,1,1 :add limb 2,2,1
scale limb 2,2,10,10,120 :offset limb 2,2,0,22,30:offset limb 2,1,0,10,0
color limb 2,2,rgb(0,0,200):color limb 2,1,rgb(0,50,170)

x#=500
z#=500
sync on
do
if upkey()=1 then x#=newxvalue(x#,a#,1) : z#=newzvalue(z#,a#,1)
if downkey()=1 then x#=newxvalue(x#,a#,-1) : z#=newzvalue(z#,a#,-1)
if leftkey()=1 then a#=wrapvalue(a#-1)
if rightkey()=1 then a#=wrapvalue(a#+1)

`calculamos la coordenadas "Y" de los dos chivatos
yb#=get ground height(1,object position x(1),object position z(1))
yb2#=get ground height(1,object position x(5),object position z(5))
yb3#=get ground height(1,object position x(4),object position z(4))

`calculamos la coordenada "y" del coche
y#=get ground height(1,x#,z#)
`pocisionamos a los objetos
position object 1,x#,yb#+40,z#
position object 2,x#,y#+30,z#
position object 5,x#,yb2#,z#
position object 4,x#,yb3#,z#

`rotamos a los objetos
yrotate object 1,a#
yrotate object 2,a#
yrotate object 5,a#
yrotate object 4,a#


`desplazamos al objeto chivato que lleva el blindado, para calcular la inclinacion
move object 1,80
`desplazamos al segundo chivato, que comprobara los alaveos
move object left 5,30
move object right 4,30

`hacemos que el blindado apunte a las coordenadas del chivato
`solo con esto, hemos conseguido, el efecto que se buscaba
point object 2,object position x(1),object position y(1),object position z(1)

`hacemos que el blindado, se alavee hacia la izquierda, la algura del blindado
`menos la atura del chivato..... TACHANNN
roll object left 2,y#-yb2#
roll object right 2,y#-yb3#
`Posiciona la cámara por detrás del objeto
cx#=newxvalue(x#,wrapvalue(a#+180),300)
cz#=newzvalue(z#,wrapvalue(a#+180),300)
cy#=get ground height(1,cx#,cz#)+100.0
position camera cx#,cy#+200,cz#

`enfoca la cámara al objeto
point camera x#,y#,z#
sync
loop

I'm not a grumpy grandpa

Back to top

Profile PM Email

Kira Vakaan

15

Years of Service

User Offline

Joined: 1st Dec 2008

Location: MI, United States

Posted: 16th Apr 2010 23:55

Link

You could cast another ray right in front of the scorpion, and then point the scorpion object at the second collision point. This wouldn't be perfect, but it would be better.

Back to top

Profile PM Email

Sorry your browser is not supported!

Newcomers DBPro Corner / Following the curve of a .x terrain?