A question about vectors/trig and asteroid style ship movement

Author

Message

=PRoF=

21

Years of Service

User Offline

Joined: 17th Mar 2003

Location: Milton Keynes, UK

Posted: 16th May 2010 18:38

Link

Hi Guys,

This feels a bit of a n00by question, so I'm posting it here.

I've been puzzling over this for a while now, but just keep running into deadends, with little or no joy or success.

I'm currently doing a conversion of an old Spectrum game (Which I thought would be nice and simple to do... lol), in this you control your little player using something similar to the control's you would Expect in a game of Asteroids, only with 2 minor differences. 1) You can reverse, and 2) There is air resistance (i.e. your ship slows and stops eventually, if you don't keep thrusting)

function gameLoop()

// declare variables
	local playerInput as integer : playerInput=userInput(1) :` change this to use menu value when menus implemented

local originX# as float : originX#=object position x(player(1).object.objectNumber)
	local originY# as float : originY#=object position z(player(1).object.objectNumber)
	
	// handle controls
	` steering
		
	` player presses left - rotate left
	if checkBit(playerInput,cbLeft)=true
		dec player(1).lookAngleY,playerTurnSpeed*system(0).move
	endif
	
	` player presses right - rotate right
	if checkBit(playerInput,cbRight)=true
		inc player(1).lookAngleY,playerTurnSpeed*system(0).move
	endif

` thrusting
	thrusting=false
		
	` player presses up - forward thrust
	if checkBit(playerInput,cbUp)=true
		if player(1).speed=0 
			player(1).direction=1
		endif
		
		if player(1).direction=1
			inc player(1).Speed,playerAccelerate*system(0).move
		else
			dec player(1).Speed,playerAccelerate*system(0).move
		endif
	
		thrusting=true
	endif
	
	` player presses down - reverse thrust
	if checkBit(playerInput,cbDown)=true
		if player(1).speed=0 
			player(1).direction=-1
		endif
		
		if player(1).direction=-1
			inc player(1).Speed,playerAccelerate*system(0).move
		else
			dec player(1).Speed,playerAccelerate*system(0).move
		endif

thrusting=true
	endif
	
	// handle speed stuff
	
	if player(1).speed>playerMaxSpeed
		player(1).speed=playerMaxSpeed
	endif
	
	if player(1).speed<0
		player(1).speed=0
		player(1).direction=0
	endif
	
	
	if thrusting=true
		thrustDeltaX#=sin(player(1).lookAngleY)*10
		thrustDeltaY#=cos(player(1).lookAngleY)*10
		
		moveDeltaX#=sin(player(1).moveAngleY)*10
		moveDeltaY#=cos(player(1).moveAngleY)*10
		
		player(1).moveAngleY=aTanfull((thrustDeltaX#+moveDeltaX#),(thrustDeltaY#+moveDeltaY#))
	else
		if player(1).speed>0
			dec player(1).Speed,playerDecelerate*system(0).move : ` wind resistance
		endif
	endif
	
	// update player Object
	deltaX#=sin(player(1).moveAngleY)*(player(1).speed*system(0).move*player(1).direction)
	deltaY#=cos(player(1).moveAngleY)*(player(1).speed*system(0).move*player(1).direction)

player(1).x=originX#+deltaX#
	player(1).z=originY#+deltaY#

// check collisions
	wallCol=sc_SphereSlideGroup(1,originX#,playerHeight,originY#,player(1).x,playerHeight,player(1).z,playerRadius/2,0)
	
	if wallCol>0
		`if 
		player(1).x=sc_getCollisionslideX()
		player(1).z=sc_getCollisionslideZ()
		null=sc_getcollisionSlideY()
		
		normX#=sc_getCollisionBounceX()
		normZ#=sc_getCollisionBounceZ()
		
		if player(1).direction=1
			point object player(1).object.objectNumber,player(1).x+normx#,7,player(1).z+normz#
		else
			point object player(1).object.objectNumber,player(1).x-normx#,7,player(1).z-normz#
		endif
		
		player(1).moveAngleY=object angle y(player(1).object.objectNumber)
		yrotate object player(1).object.objectNumber,player(1).lookAngleY
	endif
	
	// updates ship Position	
	position object player(1).object.objectNumber,player(1).x,playerHeight,player(1).z
	yrotate object player(1).object.objectNumber,player(1).lookAngleY
	
	sc_updateObject player(1).object.objectNumber
	
	// updates the camera
	updateCamera() : ` putting this here instead of the main loop, in case menu's have different updateCam function

endfunction

+ Code Snippet

function gameLoop()

	// declare variables
	local playerInput as integer : playerInput=userInput(1) :` change this to use menu value when menus implemented

	local originX# as float : originX#=object position x(player(1).object.objectNumber)
	local originY# as float : originY#=object position z(player(1).object.objectNumber)
	
	// handle controls
	` steering
		
	` player presses left - rotate left
	if checkBit(playerInput,cbLeft)=true
		dec player(1).lookAngleY,playerTurnSpeed*system(0).move
	endif
	
	` player presses right - rotate right
	if checkBit(playerInput,cbRight)=true
		inc player(1).lookAngleY,playerTurnSpeed*system(0).move
	endif


	` thrusting
	thrusting=false
		
	` player presses up - forward thrust
	if checkBit(playerInput,cbUp)=true
		if player(1).speed=0 
			player(1).direction=1
		endif
		
		if player(1).direction=1
			inc player(1).Speed,playerAccelerate*system(0).move
		else
			dec player(1).Speed,playerAccelerate*system(0).move
		endif
	
		thrusting=true
	endif
	
	` player presses down - reverse thrust
	if checkBit(playerInput,cbDown)=true
		if player(1).speed=0 
			player(1).direction=-1
		endif
		
		if player(1).direction=-1
			inc player(1).Speed,playerAccelerate*system(0).move
		else
			dec player(1).Speed,playerAccelerate*system(0).move
		endif

		thrusting=true
	endif
	
	// handle speed stuff
	
	if player(1).speed>playerMaxSpeed
		player(1).speed=playerMaxSpeed
	endif
	
	if player(1).speed<0
		player(1).speed=0
		player(1).direction=0
	endif
	
	
	if thrusting=true
		thrustDeltaX#=sin(player(1).lookAngleY)*10
		thrustDeltaY#=cos(player(1).lookAngleY)*10
		
		moveDeltaX#=sin(player(1).moveAngleY)*10
		moveDeltaY#=cos(player(1).moveAngleY)*10
		
		player(1).moveAngleY=aTanfull((thrustDeltaX#+moveDeltaX#),(thrustDeltaY#+moveDeltaY#))
	else
		if player(1).speed>0
			dec player(1).Speed,playerDecelerate*system(0).move : ` wind resistance
		endif
	endif
	
	// update player Object
	deltaX#=sin(player(1).moveAngleY)*(player(1).speed*system(0).move*player(1).direction)
	deltaY#=cos(player(1).moveAngleY)*(player(1).speed*system(0).move*player(1).direction)

	player(1).x=originX#+deltaX#
	player(1).z=originY#+deltaY#

	// check collisions
	wallCol=sc_SphereSlideGroup(1,originX#,playerHeight,originY#,player(1).x,playerHeight,player(1).z,playerRadius/2,0)
	
	if wallCol>0
		`if 
		player(1).x=sc_getCollisionslideX()
		player(1).z=sc_getCollisionslideZ()
		null=sc_getcollisionSlideY()
		
		normX#=sc_getCollisionBounceX()
		normZ#=sc_getCollisionBounceZ()
		
		if player(1).direction=1
			point object player(1).object.objectNumber,player(1).x+normx#,7,player(1).z+normz#
		else
			point object player(1).object.objectNumber,player(1).x-normx#,7,player(1).z-normz#
		endif
		
		player(1).moveAngleY=object angle y(player(1).object.objectNumber)
		yrotate object player(1).object.objectNumber,player(1).lookAngleY
	endif
	
	// updates ship Position	
	position object player(1).object.objectNumber,player(1).x,playerHeight,player(1).z
	yrotate object player(1).object.objectNumber,player(1).lookAngleY
	
	sc_updateObject player(1).object.objectNumber
	
	// updates the camera
	updateCamera() : ` putting this here instead of the main loop, in case menu's have different updateCam function

endfunction

Here is my best working code to date, altho it's pretty close to what I want, it suffers from issues when bouncing off walls and then thrusting.

I've tried adapting the vector asteroids tutorial code to work, and I've tried just using basic trig; but to no avail

Searching hasn't helped in this case.

Can someone please point me in the right direction?

Back to top

Profile PM Email Website

KISTech

16

Years of Service

User Offline

Joined: 8th Feb 2008

Location: Aloha, Oregon

Posted: 16th May 2010 19:38

Link

The simplest method to simulate inertia (moving in the same direction while pointing in another) is to create a dummy object and use it for navigation.

Make a small cube and hide it, then when the player turns it only turns the ship, not the cube. When the player thrusts you slowly turn the cube to face the same direction as the ship. If they stop thrusting, then you stop turning the cube.

Bouncing off of walls is as easy as calculating the angle the cube was at, at the time of impact, and then calculate the resulting angle of travel after the impact. You only turn the cube, not the ship.

Back to top

Profile PM Email Website

=PRoF=

21

Years of Service

User Offline

Joined: 17th Mar 2003

Location: Milton Keynes, UK

Posted: 16th May 2010 19:49

Link

Thank you KISTech, I'll give it a go

Back to top

Profile PM Email Website

Zotoaster

19

Years of Service

User Offline

Joined: 20th Dec 2004

Location: Scotland

Posted: 16th May 2010 21:23

Link

It's not so difficult if you know some basic stuff.

Some very basic Newtonian movement would look like:

vel = vel + acc
vel = vel * drag
pos = pos + vel

Where fields in bold are vectors, and drag is a value between 0 and 1 (where 1 is no drag at all, and 0 is no movement).

As long as you keep those equations running, all you have to do is control the acceleration.

To do that, you just need an acceleration value and an angle.

acc.x = sin(angle) * value
acc.y = cos(angle) * value

Where value is 0 if you're not pressing any buttons, negative if you're reversing and positive if you're moving forward.

"everyone forgets a semi-colon sometimes." - Phaelax

Back to top

Profile PM Email

Neuro Fuzzy

17

Years of Service

User Offline

Joined: 11th Jun 2007

Location:

Posted: 17th May 2010 08:10 Edited at: 17th May 2010 08:15

Link

I agree with zotoaster. Vector addition and forces should do just fine.

[edit]
after realizing how unhelpful my post is

keep a vector containing how fast the object is moving in what direction (three values x, y, and z, the length of this vector is it's overall velocity) and keep adding that to the position of the camera. When the user clicks (or decides to move, however), move the camera or a dummy object forward from the camera, grab that position, and subtract that position from the original position to get your acceleration direction, and multiply that by the desired acceleration, then add that to the velocity vector. GOOD to go!

Back to top

Profile PM Email

=PRoF=

21

Years of Service

User Offline

Joined: 17th Mar 2003

Location: Milton Keynes, UK

Posted: 17th May 2010 11:37

Link

Thank you guys.

As soon as I get a spare 5 mins I will try out both methods and see which one I get on best with/have most success doing.

Thanks again, and I'll post back if I have any more issues with it

Back to top

Profile PM Email Website

Spectre 117

14

Years of Service

User Offline

Joined: 18th Apr 2010

Location: *Insert cheesy location here*

Posted: 23rd May 2010 05:19 Edited at: 23rd May 2010 05:23

Link

Prof,
I had the same issue a few weeks ago and Serial Velocity helped me out with a code snippet for the dummy object method. I can speak for experience when I say the it is the simplest method to get the desired effect you are look for and its not nearly as calculation intense as programming with trig. You can find the code here http://forum.thegamecreators.com/?m=forum_view&t=169703&b=7
hope it helps. Also and drag to this code won't be difficult either.

Back to top

Profile PM

=PRoF=

21

Years of Service

User Offline

Joined: 17th Mar 2003

Location: Milton Keynes, UK

Posted: 23rd May 2010 12:49

Link

Thanks Spectre 117, I've looked at the snippet and it does look helpful.

I've as yet had no time to work any further on this due to other commitments, but I will soon.

Thanks again to everyone who has helped me on this.

Back to top

Profile PM Email Website

=PRoF=

21

Years of Service

User Offline

Joined: 17th Mar 2003

Location: Milton Keynes, UK

Posted: 24th May 2010 11:47 Edited at: 24th May 2010 11:54

Link

Sorry for the double post, but I did it

I used vectors in the end, as suggested by Zotoaster;

function gameLoop()
	
	// declare variables
	local playerInput as integer : playerInput=userInput(1) :` change this to use menu value when menus implemented
	local x# as float : x#=0
	local z# as float : z#=0

local normX# as float : normX#=0
	local normZ# as float : normZ#=0
	local wallCol as integer : wallcol=0
	
	// handling of controls
	` steering
	
	` left
	if checkBit(playerInput,cbLeft)=true
		player(1).lookAngle=wrapvalue(player(1).lookAngle-(playerTurnSpeed*system(0).move))
	endif
	
	` right
	if checkBit(playerInput,cbRight)=true
		player(1).lookAngle=wrapvalue(player(1).lookAngle+(playerTurnSpeed*system(0).move))
	endif
	
	` thrusting
	
	` accelerate
	if checkBit(playerInput,cbUp)=true and length vector2(vectorVelocity)<maxSpeed
		x#=sin(player(1).lookAngle)*accelerationValue
		z#=cos(player(1).lookAngle)*accelerationValue
		set vector2 vectorAcceleration,x#,z#
		add vector2 vectorVelocity,vectorAcceleration,vectorVelocity
	endif

` decelerate
	if checkBit(playerInput,cbDown)=true and length vector2(vectorVelocity)<maxSpeed
		x#=sin(player(1).lookAngle)*-accelerationValue
		z#=cos(player(1).lookAngle)*-accelerationValue
		set vector2 vectorAcceleration,x#,z#
		add vector2 vectorVelocity,vectorAcceleration,vectorVelocity
	endif
	
	` air resistance, until velocity is next to nothing.
	if length vector2(vectorVelocity)>0.01
		multiply vector2 vectorVelocity,dragCoeficient
	endif
	
	` updates position vector, then adds velocity vector
	set Vector2 vectorPosition,object position x(player(1).object.objectNumber),object position z(player(1).object.objectNumber)
	add vector2 vectorPosition, vectorVelocity, vectorPosition

// check collisions
	wallCol=sc_SphereSlideGroup(1,object position x(player(1).object.objectNumber),playerHeight,object position z(player(1).object.objectNumber),x vector2(vectorPosition),playerHeight,y vector2(vectorPosition),0.5*playerRadius,0)

if wallCol>0
	
		// reposition ship after collision	
		player(1).x=sc_getCollisionslideX()
		player(1).z=sc_getCollisionslideZ()
		
		set vector2 vectorPosition, player(1).x, player(1).z
		
		// then set velocity as the collision bounce normals
		normX#=sc_getCollisionBounceX()
		normZ#=sc_getCollisionBounceZ()
	
		set vector2 vectorVelocity,normx#,normz#
		
	endif
	
	// update the player position
	position object player(1).object.objectNumber,x vector2(vectorPosition),playerHeight,y vector2(vectorPosition)
	yrotate object player(1).object.objectNumber,player(1).lookAngle
	sc_updateObject player(1).object.objectNumber

// updates the camera
	updateCamera() : ` putting this here instead of the main loop, in case menu's have different updateCam function

endfunction

+ Code Snippet

function gameLoop()
	
	// declare variables
	local playerInput as integer : playerInput=userInput(1) :` change this to use menu value when menus implemented
	local x# as float : x#=0
	local z# as float : z#=0

	local normX# as float : normX#=0
	local normZ# as float : normZ#=0
	local wallCol as integer : wallcol=0
	
	// handling of controls
	` steering
	
	` left
	if checkBit(playerInput,cbLeft)=true
		player(1).lookAngle=wrapvalue(player(1).lookAngle-(playerTurnSpeed*system(0).move))
	endif
	
	` right
	if checkBit(playerInput,cbRight)=true
		player(1).lookAngle=wrapvalue(player(1).lookAngle+(playerTurnSpeed*system(0).move))
	endif
	
	` thrusting
	
	` accelerate
	if checkBit(playerInput,cbUp)=true and length vector2(vectorVelocity)<maxSpeed
		x#=sin(player(1).lookAngle)*accelerationValue
		z#=cos(player(1).lookAngle)*accelerationValue
		set vector2 vectorAcceleration,x#,z#
		add vector2 vectorVelocity,vectorAcceleration,vectorVelocity
	endif

	` decelerate
	if checkBit(playerInput,cbDown)=true and length vector2(vectorVelocity)<maxSpeed
		x#=sin(player(1).lookAngle)*-accelerationValue
		z#=cos(player(1).lookAngle)*-accelerationValue
		set vector2 vectorAcceleration,x#,z#
		add vector2 vectorVelocity,vectorAcceleration,vectorVelocity
	endif
	
	` air resistance, until velocity is next to nothing.
	if length vector2(vectorVelocity)>0.01
		multiply vector2 vectorVelocity,dragCoeficient
	endif
	
	` updates position vector, then adds velocity vector
	set Vector2 vectorPosition,object position x(player(1).object.objectNumber),object position z(player(1).object.objectNumber)
	add vector2 vectorPosition, vectorVelocity, vectorPosition

	// check collisions
	wallCol=sc_SphereSlideGroup(1,object position x(player(1).object.objectNumber),playerHeight,object position z(player(1).object.objectNumber),x vector2(vectorPosition),playerHeight,y vector2(vectorPosition),0.5*playerRadius,0)
	

	if wallCol>0
	
		// reposition ship after collision	
		player(1).x=sc_getCollisionslideX()
		player(1).z=sc_getCollisionslideZ()
		
		set vector2 vectorPosition, player(1).x, player(1).z
		
		// then set velocity as the collision bounce normals
		normX#=sc_getCollisionBounceX()
		normZ#=sc_getCollisionBounceZ()
	
		set vector2 vectorVelocity,normx#,normz#
		
	endif
	
	// update the player position
	position object player(1).object.objectNumber,x vector2(vectorPosition),playerHeight,y vector2(vectorPosition)
	yrotate object player(1).object.objectNumber,player(1).lookAngle
	sc_updateObject player(1).object.objectNumber
	

	// updates the camera
	updateCamera() : ` putting this here instead of the main loop, in case menu's have different updateCam function

endfunction

The collisions caused me a little bit of grief, but I got that working about 1am last night, lol.

Now all I need to do is integrate some Timer Based Movement, (Never done TBM with vectors before) and "Gravity Zones" (Where your ship is pulled toward a specific object) then I'm a very happy bunny

Thanks to everyone who's helped me with this

Back to top

Profile PM Email Website

=PRoF=

21

Years of Service

User Offline

Joined: 17th Mar 2003

Location: Milton Keynes, UK

Posted: 25th May 2010 11:55

Link

Gah! I'm not having any luck trying to integrate Timer Based movement into the above snippet.

Its working with the Steering ok, but I have little understanding of how vectors work (This is my first time using them), or how to use TBM to scale the speed and acceleration/deceleration.

Please can someone give me a gentle nudge in the right direction?

Back to top

Profile PM Email Website

Sven B

19

Years of Service

User Offline

Joined: 5th Jan 2005

Location: Belgium

Posted: 25th May 2010 13:50 Edited at: 26th May 2010 10:37

Link

Well, if you're trying to use Euler's method:

m*a = F - friction * v

a(n+1) = F/m - friction * v(n)
v(n+1) = v(n) + a(n+1) * dt
x(n+1) = x(n) + v(n+1) * dt

or to get to Zotoasters lines:
drag = 1 - friction, so
a(n+1) = F/m
v(n+1) = v(n) - friction * v(n) + a(n+1) * dt
= (1 - friction) * v(n) + a(n+1) * dt
= drag * v(n) + a(n+1) * dt
x(n+1) = x(n) + v(n+1) * dt
[EDIT] I made a mistake here. See next post. The following should be still the same though.

dt is the time that is elapsed, and can be determined using the following at the start of the loop

+ Code Snippet

`Get elapsed time in seconds (hence /1000.0)
Elasped# = (timer() - LastTimer) / 1000.0
LastTimer = timer()

(dt = Elapsed#)

So basically you multiply the acceleration and speed vector with Elapsed# just before you add them to the other vector (speed and position).

You might have to alter the speeds a bit in order to get the effect you want. Because when you multiply with Elapsed# as calculated above, the acceleration will be in units/second² and speed in units/second.

If you don't want to alter any values, then use this as the time factor dt:

+ Code Snippet

`Get elapsed time
Elasped# = (timer() - LastTimer) * FPSWhereSpeedsAreBasedOn / 1000.0
LastTimer = timer()

If I made a mistake somewhere along the way do tell.

Cheers!
Sven B

Back to top

Profile PM Email

Sven B

19

Years of Service

User Offline

Joined: 5th Jan 2005

Location: Belgium

Posted: 26th May 2010 10:35

Link

Hi =Prof=

I realized there was a mistake in my formulas. The first one was right, but if you want to use timer based movement with friction then they are wrong when I try to get to Zotoasters version.

Timer based movement with friction works a little different. Friction is actually a force, so you'll get
a = F/m - friction * v
v = v + a * dt
x = x + v * dt

Sorry for the inconvenience.

Sven B

Back to top

Profile PM Email

=PRoF=

21

Years of Service

User Offline

Joined: 17th Mar 2003

Location: Milton Keynes, UK

Posted: 26th May 2010 11:27

Link

@SvenB
No worries

I did try getting it work, but had no joy. Will try with your corrected stuff this evening.

I dunno why I'm struggling so much with this, I have an A-Level in Applied maths, and another in Physics, but somehow Vector maths (and it's application in games) just really confuses me.

Will post back with my successes/failures

Thanks again.

Back to top

Profile PM Email Website

=PRoF=

21

Years of Service

User Offline

Joined: 17th Mar 2003

Location: Milton Keynes, UK

Posted: 15th Aug 2010 17:18 Edited at: 15th Aug 2010 17:27

Link

@SvenB:
I still haven't been able to get this to work properly.

I have to admit, I did get fed up and leave it alone for a little while and worked on other things.

But have been trying again the last few days but to no avail.

//********************************************
//	Variables and ting
//********************************************
#constant vectorPosition 1
#constant vectorVelocity 2
#constant vectorAcceleration 3
`#constant vectorDrag 4

#constant playerHeight 5

type dPlayer
	shipObj as integer
	
	acc as float
	drag as float
	
	lookAngle as float
endtype

type dTBM
	start as integer
	finish as integer
	
	move as float
endtype

dim tbm(0) as dTBM
	
dim player(0) as dPlayer

null=make vector2(vectorPosition)
null=make vector2(vectorVelocity)
null=make vector2(vectorAcceleration)
`null=make vector2(vectorDrag)

player(0).shipObj=1

player(0).acc=0.05:` 15000:`0.05
`player(0).drag=0.05 : ` tried 0.001 to 15000  nothing seems to change it

//********************************************
// system stuff
//********************************************

sync rate 60
sync on

autocam off

//********************************************
// create & position media
//********************************************

` player
make object box player(0).shipObj,10,10,20
position object player(0).shipObj,0,playerHeight,0
color object player(0).shipObj,rgb(255,0,0)

` ground
make object plane 4,500,500
position object 4,0,0,0
xrotate object 4,-90
color object 4,rgb(0,255,0)

` camera
position camera 0,0,500,0
point camera 0,0,0,0

//********************************************
//	main loop
//********************************************

do
	thrust=0 : ` not thrusting

updateTBM()
		
	` Control the spaceships rotation
	If LeftKey()

dec player(0).lookAngle,180*tbm(0).move
	
	endif
	
	If RightKey()

inc player(0).lookAngle,180*tbm(0).move
	
	endif

If upkey()
	
		thrust=1

EndIf
	
	
	If downkey()
	
		thrust=-1

EndIf

// physics

` part 1 
    x#=sin(player(0).lookAngle)*(player(0).acc*thrust)
    z#=cos(player(0).lookAngle)*(player(0).acc*thrust)

set vector2 vectorAcceleration,x#,z#
 	
	
	` part 2
	`multiply vector2 vectorAcceleration,tbm(0).move
    
	add vector2 vectorVelocity,vectorVelocity,vectorAcceleration

` part 3
	`multiply vector2 vectorVelocity,tbm(0).move
    
	add vector2 vectorPosition,vectorPosition,vectorVelocity
	
	// finally updates the object
	position object player(0).shipObj,x vector2(vectorPosition),playerHeight,y vector2(vectorPosition)
    yrotate object player(0).shipObj,player(0).lookAngle

// draws the Debug info to screen
	drawDebug()
	
	// updates the screen
	sync
loop

end

//********************************************
// functions
//********************************************

//********************************************
// on screen debug information
//********************************************

function drawDebug()

local currentLine as integer : currentLine=0
	local textSize as integer : textSize=text size()
	
	text 0,textSize*currentLine,"FPS: "+str$(screen fps()) : inc currentLine,2
	text 0,textSize*currentLine,"Player Data" : inc currentLine,1
	text 0,textSize*currentLine,"vVelocity: "+str$(length vector2(vectorVelocity)) : inc currentLine,1
	text 0,textSize*currentLine,"vPosition: "+str$(length vector2(vectorPosition)) : inc currentLine,1
	`text 0,textSize*currentLine,"vForce: "+str$(length vector2(vectorForce)) : inc currentLine,1
	text 0,textSize*currentLine,"vAcceleration: "+str$(length vector2(vectorAcceleration)) : inc currentLine,1
	`text 0,textSize*currentLine,"InertiaZ: "+str$(player(0).inertiaZ) : inc currentLine,1

endfunction

//**********************************************************************
//	This updates the TBM stuff
//**********************************************************************

function updateTBM

if tbm(0).start=0
		tbm(0).start=hiTimer()
	else
		tbm(0).finish=hiTimer()
		tbm(0).move=(tbm(0).finish-tbm(0).start)/1000.0
		tbm(0).start=hiTimer()
	endif
		
endfunction

+ Code Snippet

//********************************************
//	Variables and ting
//********************************************
#constant vectorPosition 1
#constant vectorVelocity 2
#constant vectorAcceleration 3
`#constant vectorDrag 4


#constant playerHeight 5

type dPlayer
	shipObj as integer
	
	acc as float
	drag as float
	
	lookAngle as float
endtype


type dTBM
	start as integer
	finish as integer
	
	move as float
endtype


dim tbm(0) as dTBM
	
dim player(0) as dPlayer

null=make vector2(vectorPosition)
null=make vector2(vectorVelocity)
null=make vector2(vectorAcceleration)
`null=make vector2(vectorDrag)

player(0).shipObj=1

player(0).acc=0.05:` 15000:`0.05
`player(0).drag=0.05 : ` tried 0.001 to 15000  nothing seems to change it


//********************************************
// system stuff
//********************************************

sync rate 60
sync on

autocam off


//********************************************
// create & position media
//********************************************

` player
make object box player(0).shipObj,10,10,20
position object player(0).shipObj,0,playerHeight,0
color object player(0).shipObj,rgb(255,0,0)


` ground
make object plane 4,500,500
position object 4,0,0,0
xrotate object 4,-90
color object 4,rgb(0,255,0)

` camera
position camera 0,0,500,0
point camera 0,0,0,0


//********************************************
//	main loop
//********************************************

do
	thrust=0 : ` not thrusting

	updateTBM()
		
	` Control the spaceships rotation
	If LeftKey()

		dec player(0).lookAngle,180*tbm(0).move
	
	endif
	
	If RightKey()

		inc player(0).lookAngle,180*tbm(0).move
	
	endif
	

	If upkey()
	
		thrust=1

	EndIf
	
	
	If downkey()
	
		thrust=-1

	EndIf

	// physics

	` part 1 
    x#=sin(player(0).lookAngle)*(player(0).acc*thrust)
    z#=cos(player(0).lookAngle)*(player(0).acc*thrust)

    set vector2 vectorAcceleration,x#,z#
 	
	
	` part 2
	`multiply vector2 vectorAcceleration,tbm(0).move
    
	add vector2 vectorVelocity,vectorVelocity,vectorAcceleration

	` part 3
	`multiply vector2 vectorVelocity,tbm(0).move
    
	add vector2 vectorPosition,vectorPosition,vectorVelocity
	
	// finally updates the object
	position object player(0).shipObj,x vector2(vectorPosition),playerHeight,y vector2(vectorPosition)
    yrotate object player(0).shipObj,player(0).lookAngle


	// draws the Debug info to screen
	drawDebug()
	
	// updates the screen
	sync
loop

end

//********************************************
// functions
//********************************************

//********************************************
// on screen debug information
//********************************************

function drawDebug()

	local currentLine as integer : currentLine=0
	local textSize as integer : textSize=text size()
	
	text 0,textSize*currentLine,"FPS: "+str$(screen fps()) : inc currentLine,2
	text 0,textSize*currentLine,"Player Data" : inc currentLine,1
	text 0,textSize*currentLine,"vVelocity: "+str$(length vector2(vectorVelocity)) : inc currentLine,1
	text 0,textSize*currentLine,"vPosition: "+str$(length vector2(vectorPosition)) : inc currentLine,1
	`text 0,textSize*currentLine,"vForce: "+str$(length vector2(vectorForce)) : inc currentLine,1
	text 0,textSize*currentLine,"vAcceleration: "+str$(length vector2(vectorAcceleration)) : inc currentLine,1
	`text 0,textSize*currentLine,"InertiaZ: "+str$(player(0).inertiaZ) : inc currentLine,1

endfunction


//**********************************************************************
//	This updates the TBM stuff
//**********************************************************************

function updateTBM

	if tbm(0).start=0
		tbm(0).start=hiTimer()
	else
		tbm(0).finish=hiTimer()
		tbm(0).move=(tbm(0).finish-tbm(0).start)/1000.0
		tbm(0).start=hiTimer()
	endif
		
endfunction

The code above works as expected; with the ship accelerating when thrust is applied, and conitinuing uninterupted until you thrust again.

However, when you uncomment the 2 lines where the Timer Based Movement factor is applied to the vectors (And change the value for acceleration); then the ship stops when your not thrusting.

I've removed all the collision and drag stuff for the time being until I can get this issue sorted. (Initially, I thought I was doing the drag wrong, and wasted many hours trying to rectify that)

Can you (or anyone else) see where have I gone wrong?

Thanks as always

=PRoF=

>edit<
Removed some stuff from the code from when I was trying with hidden objects instead of vectors

Back to top

Profile PM Email Website

Sven B

19

Years of Service

User Offline

Joined: 5th Jan 2005

Location: Belgium

Posted: 15th Aug 2010 19:11 Edited at: 16th Aug 2010 13:00

Link

Hi =Prof=,

The speed vector has to be multiplied with the time factor when it is added to the position vector, but by using multiply vector, the speed vector is changed. Therefor you're not storing the speed vector, but the speed vector multiplied by the time factor.
There are a number of solutions for this, the easiest one being writing the formula per component:

+ Code Snippet

set vector2 vectorPosition, x vector2(vectorPosition) + (tbm(0).move * x vector2(vectorVelocity)), y vector2(vectorPosition) + (tbm(0).move * y vector2(vectorVelocity))

Cheers!
Sven B

Back to top

Profile PM Email

=PRoF=

21

Years of Service

User Offline

Joined: 17th Mar 2003

Location: Milton Keynes, UK

Posted: 15th Aug 2010 22:52

Link

Thanks so much SvenB

It's all sorted now and working 100%

Once again the collisions proved troublesome, but I've done it now

Thanks again

Back to top

Profile PM Email Website

Neuro Fuzzy

17

Years of Service

User Offline

Joined: 11th Jun 2007

Location:

Posted: 17th Aug 2010 10:31

Link

Quote: "but somehow Vector maths (and it's application in games) just really confuses me."

search "vectors don't bite!" on the forums to get an amazing tutorial.

What really makes vectors amazing in my opinion is the dot product, because, where A is a normalized vector and B is any old vector, A*B (A.x*B.x+A.y+B.y) literally gives "the magnitude of B in the direction of A", or ||A||*cos(theta) where theta is the angle separating the two vectors. There's some really cool stuff in that tutorial.

Is't life, I ask, is't even prudence, to bore thyself and bore thy students?

Back to top

Profile PM Email

Sorry your browser is not supported!

Newcomers DBPro Corner / A question about vectors/trig and asteroid style ship movement