Sorry your browser is not supported!

RPG Toolkit (Tile File) by Christopher MatthewsThe RPG 
Toolkit is a development system for creating Role Playing Games. 
The Standard Edition is free. A user has submitted this as the 
format for these files.

A 6 bytes header:
** 2 bytes - magic 0x14 0x00
** 2 bytes - number of tiles, little endian
** 2 bytes - subformat (0x01 0x00 or 0x02 0x00, maybe something else)
In 0x01 0x00 format, what follows are tiles, 3072 bytes per tile.
Each tile is always 32x32, with 3 bytes per tile (in order red, 
green, blue). The pixel data is transposed compared to the usual 
pixel formats, that is first are all the pixels of the first, 
column, then the second column etc. (in most formats it's first 
row, second row etc.). One color indicates "transparent", but it 
differs depending on the tileset, and is just a convention. 
Usually it's black or pink, but a few other colors are used 
sometimes. Information which color indicates transparent is not in 
the file.

The 0x02 0x00 format differs however it's rather rare.

imageCount = loadTst("S:\tilesets\rmxp_worldmap1.tst", 1)


pages = imageCount / 180

sync on
DO
	cls rgb(0,0,128)
	
	
	center text 320, 6, "Now viewing page "+str$(page+1)+" of "+str$(pages+1)
	center text 320, 24, "Use the left/right arrow keys to flip pages, spacebar to show image numbers"
	
	rem controls to flip through displayed images
	if rightkey() = 1 and vkflag = 0
		vkflag = 1
		inc page
		if page > pages then page = pages
	endif
	if leftkey() = 1 and vkflag = 0
		vkflag = 1
		dec page
		if page < 0 then page = 0
	endif
	if spacekey() = 1 and vkflag = 0
		vkflag = 1
		showNo = 1 - showNo
	endif
	if leftkey()+rightkey()+spacekey() = 0 then vkflag = 0

	
	rem display images
	i = page*180
	for y = 1 to 10
		for x = 0 to 17
			inc i
			if i <= imageCount 
				paste image i, 14+x*34, 20+y*36
				if showNo = 1 then center text 30+x*34, 22+y*36, str$(i)
			else
				exit
			endif
		next x
	next y
	
	
sync
LOOP


REM +++++++++++++++++++++++++++++++++++++++++++++++++
REM
REM Reads a TST file and extracts its individual
REM tiles into separate images
REM
REM file$     = TST file to load
REM             (rpgToolKit tileset)
REM imgOffset = Loads images from tileset starting 
REM             at this image number
REM Returns   = Number of images created from tileset
REM
REM +++++++++++++++++++++++++++++++++++++++++++++++++
function loadTst(file$, imgOffset)

	rem if file doesn't exist, exit function
	if file exist(file$) = 0 then exitfunction 0
	
	rem memblock number to use to build tiles
	mem = 1
	
	rem open the tst file
	open to read 1, file$
	
	read word 1, magic
	read word 1, tileCount
	read word 1, subFormat
	
	rem not a TST file
	if magic <> 20 then exitfunction 0
	
	rem verify we load for the correct format
	if subFormat = 1
	
		rem tiles are always 32x32 (32*32*4+12)
		make memblock mem, 4108
		write memblock dword mem, 0, 32
		write memblock dword mem, 4, 32
		write memblock dword mem, 8, 32
		rem loop through all tiles in file
		for i = 0 to tileCount-1
			for x = 0 to 31
				for y = 0 to 31
					read byte 1, red
					read byte 1, green
					read byte 1, blue
					pos = ((y*32) + x)*4 + 12
					write memblock dword mem, pos, rgb(red, green, blue)
				next y
			next x
			make image from memblock imgOffset+i, mem
		next i
	endif
	
	rem free up memory and close file
	if memblock exist(mem) then delete memblock mem
	close file 1
	
endfunction tileCount

function makePngFile()
	
	bitmapWidth = 32*4
	bitmapHeight = 32*3
	CREATE BITMAP 1,bitmapWidth,bitmapHeight
	SET CURRENT BITMAP 1
	PASTE IMAGE 41,0,0
	PASTE IMAGE	42,32,0
	PASTE IMAGE 110,64,0
	PASTE IMAGE	111,96,0
	PASTE IMAGE 49,0,32
	PASTE IMAGE	50,32,32
	PASTE IMAGE 118,64,32
	PASTE IMAGE	119,96,32
	PASTE IMAGE 57,0,64
	PASTE IMAGE	58,32,64
	PASTE IMAGE 231,64,64
	PASTE IMAGE	232,96,64
	
	MAKE MEMBLOCK FROM BITMAP 2,1
	DELETE BITMAP 1
	MAKE IMAGE FROM MEMBLOCK 5000,2
	DELETE MEMBLOCK 2
	SAVE IMAGE "ImageX.png",5000
	 
ENDFUNCTION