I didn't even know there were MOVE CAMERA LEFT and MOVE CAMERA RIGHT commands and I've only just spotted the same for the objects. I guess this is what you get for going from DBC to DBPro, you just stick with what you know.
Anyway, in the vain of sticking with what I know, this is the method I use, essentially taken from the old monster hunt tutorial.
The below demo is essentially classic FPS controls, which is what I assume you're after.
EDIT: forgot to put this in a code box
`this demo shows basic first person camera controls
`use arrow key to move foward, back and strafe left and right
`use mouse to look left, right, up and down
sync rate 65
sync on
hide mouse
make matrix 1, 1000,1000,20,20
`starting values
xpos# = 500.0 :`x position of the camera
ypos# = 20.0 :`y position of the camera (height of the camera above the ground)
zpos# = 500.0 :`z position of the camera
facing# = 0.0 :`direction the camera is facing left and right
pitch# = 0.0 :`angle of camera up and down
do
`use mouse to look left, right, up and down
`rotate left and right
facing# = wrapvalue(facing# + mousemovex()*0.2)
`pitch camera up and down
pitch# = wrapvalue(pitch# + mousemovey()*0.2)
`this restricts the look up and down angle
campitchtest# = wrapvalue(pitch#+180)
if campitchtest# < 90 then pitch# = 270
if campitchtest# > 270 then pitch# = 90
`move forward
if upkey() = 1
xpos# = newxvalue(xpos#, facing#, 5)
zpos# = newzvalue(zpos#, facing#, 5)
endif
`move back
if downkey() = 1
xpos# = newxvalue(xpos#, wrapvalue(facing#+180), 5)
zpos# = newzvalue(zpos#, wrapvalue(facing#+180), 5)
endif
`strafe left
if leftkey() = 1
xpos# = newxvalue(xpos#, wrapvalue(facing#-90), 5)
zpos# = newzvalue(zpos#, wrapvalue(facing#-90), 5)
endif
`strafe right
if rightkey() = 1
xpos# = newxvalue(xpos#, wrapvalue(facing#+90), 5)
zpos# = newzvalue(zpos#, wrapvalue(facing#+90), 5)
endif
`rotate camera
yrotate camera facing#
xrotate camera pitch#
`position camera
position camera xpos#, ypos#, zpos#
sync
loop
As you can see, there is no trigonometry at all, just the use of the NEWXVALUE() and NEWZVALUE() commands.
Hope this helps.
