It's because of your misspellings/mistypes.
Specifically "cubsize" instead of "cub
esize" in the camera setup.
MAIN STARTING POINT
for z=1 to mapsize
for x=1 to mapsize
if map$(x,z)="O"
cx=x*cubsize
cz=z*cubsize
endif
next x
next z
position camera cx,0,cz
Another cubsize instead of cubesize
collisionstep=int(cubsize/10)
And...
fog distance (int(maxcubes)*cubsize)
set camera range 1,(maxcubes*cubsize)
`CALCULATE PLAYER LOCATION
cx#=int(camera position x()/cubsize)-int(maxcubes/2)
cz#=int(camera position z()/cubsize)-int(maxcubes/2)
I just did a find and replace. working on editing some of your code
sometimes dbpro lets you get away with it, but your for next loop has the wrong next variable, next yy# should be next zz. (OR the FOR zz## should be For yy....
And since you are stepping in whole numbers there is no reason for your indexes like yy xx etc... to be floats #'s, they should be normal integers.
There are other mistypes like backcolor as blackcolor, when coloring the backdrop, so look over your code carefully. check numbers too, as those are harder to spot.
=============================================
I changed the formatting of your source to make it a bit easier to read (at least to me).
There may still be some typos...
set display mode 800,600,16
sync on
sync rate 0
hide mouse
backcolor=rgb(0,0,0)
backdrop on
color backdrop backcolor
cls
`Loading Map Data (String Array)
mapsize=512
dim map$(mapsize,mapsize)
maxcubes=16
cubesize=200
collisionstep=int(cubesize/10)
`Enter Darkness! (MHA-HA-HA)
fog on
fog color backcolor
fog distance (int(maxcubes)*cubesize)
set camera range 1,(maxcubes*cubesize)
`CURRENT MAP
loadmap("media/Drew's Dugeon1.map", mapsize)
`LOAD IMAGES
load image "media/wall2.jpg", 1
load image "media/ground.jpg", 2
load image "media/wall.jpg", 3
`CREATING THE DUNGEON!
`WALL
for i=1 to maxcubes*maxcubes
make object cube 100+i,cubesize
texture object 100+i,1
next i
`FLOOR
for i=1 to maxcubes*maxcubes
make object plain 10000+i,cubesize,cubesize
rotate object 10000+i,90,0,0
texture object 10000+i,2
next i
`CEILING
for i=1 to maxcubes*maxcubes
make object plain 20000+i,cubesize,cubesize
rotate object 20000+i,270,0,0
texture object 20000+i,3
next i
`SETTING THE MOOD
`SET AMBIENT LIGHT
set ambient light 30
`CREATE AMBIENT LIGHTS
make light 1
make light 2
`DEFINE LIGHTS
set point light 1,0,0,0
set spot light 2,45,90
`COLORING LIGHT
color light 2,RGB(252,216,141)
color light 1,RGB(236,182,100)
color light 0,RGB(0,0,0)
`MAIN STARTING POINT
for z=1 to mapsize
for x=1 to mapsize
if map$(x,z)="O"
cx=x*cubesize
cz=z*cubesize
endif
next x
next z
Position camera cx,0,cz
`Variables
oldpositionx#=camera position x()
oldpositionz#=camera position z()
`THE MAIN LOOP
`MOVEMENT
do
if mouseclick()=1 then move camera maxcubes
if mouseclick()=2 then move camera maxcubes*(-1)
ry#=wrapvalue(ry#+mousemovex())
rotate camera 0,ry#,0
`CALCULATE PLAYER LOCATION
cx#=int(camera position x()/cubesize)-int(maxcubes/2)
cz#=int(camera position z()/cubesize)-int(maxcubes/2)
tx#=camera position x()
tz#=camera position z()
zzz=0
for zz=1 to maxcubes
for xx=1 to maxcubes
zzz=zzz+1
curposx=int(cx#)+xx
curposz=int(cz#)+zz
if curposx<=1 then curposx=1
if curposx>=mapsize then curposx=mapsize
if curposz<=1 then curposz=1
if curposz>=mapsize then curposz=mapsize
`WALL
if map$(int(curposx),int(curposz))="#" or map$(int(curposx),int(curposz))="S"
show object 100+zzz
position object 100+zzz,curposx*cubesize,0.0,curposz*cubesize
`COLLISION DETECTION
if map$(int(curposx),int(curposz))="#"
if tx#>=((curposx*cubesize)-(cubesize/2))-collisionstep and tx#<=((curposx*cubesize)+(cubesize/2))+collisionstep and tz#>=((curposz*cubesize)-(cubesize/2))-collisionstep and tz#<=((curposz*cubesize)+(cubesize/2))+collisionstep
position camera oldpositionx#,camera position y(),oldpositionz#
oldpositionx#=camera position x()
oldpositionz#=camera position z()
endif
endif
else
hide object 100+zzz
endif
`FLOOR
if map$(int(curposx),int(curposz))=":" or map$(int(curposx),int(curposz))="D" or map$(int(curposx),int(curposz))="S" or map$(int(curposx),int(curposz))="T"
show object 10000+zzz
position object 10000+zzz,curposx*cubesize,(cubesize/2)*(-1),curposz*cubesize
else
hide object 10000+zzz
endif
`CEILING
if map$(int(curposx),int(curposz))=":" or map$(int(curposx),int(curposz))="D" or map$(int(curposx),int(curposz))="S" or map$(int(curposx),int(curposz))="T"
show object 20000+zzz
position object 20000+zzz,curposx*maxcubesize,(cubesize/2)*(-1),curposz*cubesize
else
hide object 20000+zzz
endif
next xx
next zz
oldpositionx#=camera position x()
oldpositionz#=camera position z()
`LIGHTING EFFECTS (AGAIN?!?)
position light 1,camera position x(),camera position y(),camera position z()
position light 2,camera position x(),camera position y(),camera position z()
color light 1,RGB(200+int(rnd(50)-25),120,60)
rotate light 2,camera angle x(),camera angle y(),camera angle z()
sync
loop
`Function: LOADING MAP
function loadmap(filename$,size)
open to read 1,filename$
for y=1 to size
for x=1 to size
read byte 1,tmp
map$(x,y)=chr$(tmp)
next x
next y
close file 1
endfunction
good luck
~ZENassem
