First thing...
Define your huds
in the first batch of lines, as I mentioned to another user before in
this thread. The syntax layout is what gets people all the time.
So your huds
should be defined first:
;Artificial Intelligence Script
;Header
desc = SCRIPT DESCRIPTION
;Triggers
:state=0:hudreset,hudx=50,hudy=90,hudimagefine=gamecore\huds\arpg\intro1.png,hudname=bandit1,hudhide=1,hudmake=display
:state=0:hudreset,hudx=50,hudy=90,hudimagefine=gamecore\huds\arpg\intro2.png,hudname=guard1,hudhide=1,hudmake=display
:state=0:hudreset,hudx=50,hudy=90,hudimagefine=gamecore\huds\arpg\intro3.png,hudname=bandit2,hudhide=1,hudmake=display
:state=0:state=1
Second... is this script running via trigger (plrinzone) or are you attaching it to a dynamic entity and player is at a certain distance (plrdistwithin=x).
If you are using distance and the script is attached to a dynamic entity, then the next line would be like this:
:state=1,plrdistwithin=50:plrfreeze=12000,state=2
If you are using a trigger and the script runs once player enters the zone, then it would be like this:
:state=1,plrwithinzone=1:plrfreeze=12000,state=2
Third... never use "timergreater" and "timerstart". As mentioned before in other threads, if you have more than one script using those two commands, there will be a conflict. Use "etimerstart" and "etimergreater".
With that explained, here is the next part of the script:
:state=2:etimerstart,hudshow=bandit1,hudfadeout=bandit1,state=3
:state=3,etimergreater=4000:state=4
:state=4:etimerstart,hudshow=guard1,hudfadeout=guard1,state=5
:state=5,etimergreater=4000:state=6
:state=6:etimerstart,hudshow=bandit2,hudfadeout=bandit2,state=7
:state=7,etimergreater=4000:state=10
You can also change the above to a different format. Instead of the hud coming in and fading out, you can use the "etimer" to control when it fades out, like this:
:state=2:hudshow=bandit1,etimerstart,state=3
:state=3,etimergreater=4000:hudfadeout=bandit1,etimerstart,state=4
:state=4,etimergreater=1000:hudshow=guard1,etimerstart,state=5
:state=5,etimergreater=4000:hudfadeout=guard1,etimerstart,state=6
:state=6,etimergreater=1000:hudshow=bandit2,,etimerstart,state=7
:state=7,etimergreater=4000:hudfadeout=bandit2,state=10
Now the last part... to unfreeze the player:
(Using plrdistwithin in the beginning)
:state=10:plrfreeze=0,state=11
:state=11,plrdistfurther=60:state=12
;End of Script
(Using plrwithinzone in the beginning)
:state=10:plrfreeze=0,state=11
:state=11,plrwithinzone=0:state=12
;End of Script
Twitter: @NFoxMedia
