Sorry your browser is not supported!

set display mode 800,600,32
sync on
sync rate 60
rem DBC v120

`make random alpha texture, and create memblock(alpha)
alpha=2
for x=0 to 294 step 30
   for y=0 to 240 step 30
      color=rnd(255)
      ink rgb(color,color,color),0
      x1=x
      y1=y
      x2=294-x
      y2=240-y
      box x1,y1,x2,y2
   next y
next x
get image alpha,0,0,294,240
sync
make memblock from image alpha,alpha

`load texture, and create memblock(texture)
texture=1
load image "294px-Morrice-La_veille_maison_Holton_a_Montreal.jpg",texture
make memblock from image texture,texture

`if size memblock texture are different, then stop
size=get memblock size(texture)
if get memblock size(alpha)<>size then end

`mix 'alpha' and 'texture' ; copy result in memblock 'texture'
for pos=12 to size-1
   valu=((memblock byte(texture,pos)+1)*(255-memblock byte(alpha,pos)))/255.0
   write memblock byte texture,pos,valu
next pos

`make mixed texture
delete image texture
make image from memblock texture,texture

`free memory
delete memblock texture
delete memblock alpha

`make object for mixed texture
make object plain texture,294,240
texture object texture,texture
level=128
set object ambient texture,rgb(level,level,level)
set object diffuse texture,rgb(level,level,level)
position object texture,0,60,0
ghost object on texture

`make object for alpha texture
make object plain alpha,294,240
texture object alpha,alpha
set object ambient alpha,rgb(255,255,255)
set object diffuse alpha,rgb(255,255,255)
position object alpha,0,60,0
ghost object on alpha,1

`green object
make object box 5,1024,128,8
color object 5,rgb(0,128,0)
position object 5,0,0,300

`position camera
autocam off
position camera 0,120,-300

`main
repeat
   xrotate object texture,wrapvalue(object angle x(texture)+0.5)
   xrotate object alpha,wrapvalue(object angle x(alpha)+0.5)
   xrotate object 5,wrapvalue(object angle x(5)+1.0)
sync
until scancode()

delete image texture
delete image alpha

sync
end