Function Parameter and Output Help

Author

Message

Mr909

12

Years of Service

User Offline

Joined: 2nd Jun 2012

Location:

Posted: 2nd Jun 2012 18:52

Link

Okay, I have a couple different questions on how to use function parameters.

(1) I want to develop a single function to average 2-5 numbers really quickly, but obviously the function would behave differently depending on how many numbers were averaged in. Is there an easy way to do it? I might have 0's in the averaged numbers, so I can't just input 0's where I don't want parameters.

(2) I want a function that removes everything after a set of parentheses, and another that takes everything before it. I also want it to ignore spaces.

For example, reading:

$string = Intelligence (20%)

Would return two different things if put through the functions

line_traitname($string) would return "Intelligence"
line_traitvalue($string) would return "20%"

(3) Related to 2, how do I reliably turn a percentage in the form of a string into a decimal for calculation? Not all traitvalue returns will be percentages, some will remain strings, some will be other types of values. Can someone link me to a page explaining the types of values and what numbers they can store?

(4) Also, I'm really confused as to how RGB values behave when input into functions, and I imagine what could easily be three to four hours of work being blown on not understanding what would otherwise be really easy, if I could get a little forewarning.

Basically, I have several functions in mind to fix or change colors. I want to have them in 3 seperate variables for processing, but from what I understand, functions only return one value.

So, like
FUNCTION color_redshift(R,G,B,shift,lower)

R= R+shift
G= G-lower
B= B-lower

ENDFUNCTION

(That's just pseudo-code to show you what I mean)

I can't make it return three separate values, right? I sort of need it to, as the variables are all stored separately. Unless I could get a traitvalue string (explained in 2) to be treated as an RGB value. Which I highly doubt that'll even work.

Back to top

Profile PM Email

zeroSlave

15

Years of Service

User Offline

Joined: 13th Jun 2009

Location: Springfield

Posted: 3rd Jun 2012 02:34 Edited at: 3rd Jun 2012 03:12

Link

(1) My suggestion would be to use array lists with a couple functions. There may be a better way to do this, but this is the first thing that came to mind. Here is some code to show an example of it in use:

+ Code Snippet

sync on
sync rate 60

Dim ValuesToAverage()

do
    AddNumber(5)
    AddNumber(24)
    AddNumber(77)
    AddNumber(457)
    AddNumber(242)
    set cursor 0,0: print AverageValues()
    clearNumbers()
    
    sync
loop
end

function AddNumber(i)
    array insert at bottom ValuesToAverage()
    array index to bottom ValuesToAverage()
    ValuesToAverage() = i
endfunction

function AverageValues()
    ValueCount = Array count( ValuesToAverage() ) + 1
    
    array index to top ValuesToAverage()
    
    while array index valid( ValuesToAverage() )
        ValueTotal = ValueTotal + ValuesToAverage()
        next array index ValuesToAverage()
    endwhile
    
    ValueAverage = ValueTotal / ValueCount
endfunction ValueAverage

function clearNumbers()
    empty array ValuesToAverage()
endfunction

(2) You should check out the left$(), right$(), len(), trim$, & mid$() functions. Here is some code:

sync on
sync rate 60

NewString$ = "Intelligence (56.56%)"
do
    TraitName$ = line_traitname(NewString$)
    TraitValue$ = line_traitvalue(NewString$)
    TraitValueDecimal# = line_traitvaluedecimal(TraitValue$)
    set cursor 0,0
    print TraitName$
    print TraitValue$
    print TraitValueDecimal#
    sync
loop

end

function line_traitname(s$)
    repeat
        inc cursor
    until mid$(s$, cursor) = "("
    s$ = trim$(left$(s$, cursor - 1))
endfunction s$

function line_traitvalue(s$)
    repeat
        inc cursor
    until mid$(s$, cursor) = "(" || cursor = 1000
    s$ = trim$(right$(s$, len(s$) - cursor))
    
    cursor = 0
    repeat
        inc cursor
    until mid$(s$, cursor) = ")" || cursor = 1000
    s$ = trim$(left$(s$, cursor - 1))    
endfunction s$

function line_traitvaluedecimal(s$)
    repeat
        inc cursor
        if mid$(s$, cursor) = "." then inc cursor
    until mid$(s$, cursor) < str$(0) || mid$(s$, cursor) > str$(9) || cursor = 1000
    s$ = trim$(left$(s$, cursor - 1))
    decValue# = val(s$) / 100.0
endfunction decValue#

+ Code Snippet

sync on
sync rate 60

NewString$ = "Intelligence (56.56%)"
do
    TraitName$ = line_traitname(NewString$)
    TraitValue$ = line_traitvalue(NewString$)
    TraitValueDecimal# = line_traitvaluedecimal(TraitValue$)
    set cursor 0,0
    print TraitName$
    print TraitValue$
    print TraitValueDecimal#
    sync
loop

end

function line_traitname(s$)
    repeat
        inc cursor
    until mid$(s$, cursor) = "("
    s$ = trim$(left$(s$, cursor - 1))
endfunction s$

function line_traitvalue(s$)
    repeat
        inc cursor
    until mid$(s$, cursor) = "(" || cursor = 1000
    s$ = trim$(right$(s$, len(s$) - cursor))
    
    cursor = 0
    repeat
        inc cursor
    until mid$(s$, cursor) = ")" || cursor = 1000
    s$ = trim$(left$(s$, cursor - 1))    
endfunction s$

function line_traitvaluedecimal(s$)
    repeat
        inc cursor
        if mid$(s$, cursor) = "." then inc cursor
    until mid$(s$, cursor) < str$(0) || mid$(s$, cursor) > str$(9) || cursor = 1000
    s$ = trim$(left$(s$, cursor - 1))
    decValue# = val(s$) / 100.0
endfunction decValue#

(3) I'm not sure about what you mean. If you need to turn a string into a number, you can use the val() function (used in the above code) to return a number instead of a string. You can also use the str$() function to return a string from a number.

(4) For the color part, you can send a dword to the function and return a dword from it for the color. i = rgb(100,56,34) would return a dword. Then you can use the rgbr(), rgbg(), & rgbb() functions to return the integer value of the respective color.
i = rgb(100,56,34)
rgbr(i) would return 100
rgbg(i) would return 56
rgbb(i) would return 34

Here is code to show it working:

+ Code Snippet

sync on
sync rate 60

do
    boxColor1 = rgb(100, 0, 100)
    boxColor2 = Color_RedShift(boxColor1, 150, 40) 
    box 0, 0, 100, 100, boxColor1
    box 100, 0, 200, 100, boxColor2
    sync
loop
End

function Color_RedShift(col, shiftVal, lowerVal)
    R = rgbr(col) + shiftVal
    G = rgbg(col) - lowerVal
    B = rgbb(col) - lowerVal
    
    if R > 255 then R = 255
    if G < 0 then G = 0
    if B < 0 then B = 0
    
    sendColor = rgb(R, G, B)
endfunction sendColor

Hope this helps and isn't to confusing.

Everybody is a genius. But if you judge a fish by its ability to climb a tree, it will live its whole life believing that it is stupid.

Back to top

Profile PM Email

nonZero

13

Years of Service

User Offline

Joined: 10th Jul 2011

Location: Dark Empire HQ, Otherworld, Silent Hill

Posted: 3rd Jun 2012 10:54 Edited at: 3rd Jun 2012 10:56

Link

Quote: "(1) I want to develop a single function to average 2-5 numbers really quickly,"

This is a much quicker (easier, coding-wise method) but if you want more flexibility, stick with zeroSlave's example. It depends largely on the application.

+ Code Snippet

av45# = Average(0,4,0,0,5)

PRINT "The average of 4 and 5 is: " + STR$(av45#)
PRINT "The average of 1, 2, 3, 4 is: " + STR$(Average(1,2,3,4,0))
PRINT "The average of -10 and -20 is: " + STR$(Average(-10,-20,0,0,0))



PRINT "": PRINT "Press any key...": WAIT KEY: END

Function Average(n1#, n2#, n3#, n4#, n5#)
      avg# = 0.0        `DBPro needs decimals in a var to output decimals from a var. Think of this as the equivilent to "float avg" in C++
      ctr = 0           `Insurance. I always assign INCremented variables a zero value before use (prevents any possibility of unwanted behaviou).
      IF n1# <> 0: INC avg#, n1#: INC ctr: ENDIF
      IF n2# <> 0: INC avg#, n2#: INC ctr: ENDIF
      IF n3# <> 0: INC avg#, n3#: INC ctr: ENDIF
      IF n4# <> 0: INC avg#, n4#: INC ctr: ENDIF
      IF n5# <> 0: INC avg#, n5#: INC ctr: ENDIF
      IF avg# <> 0: avg# = avg# / ctr: ENDIF
EndFunction avg#

Quote: "(2) I want a function that removes everything after a set of parentheses, and another that takes everything before it. I also want it to ignore spaces."

Here's a basic example. It's not the best but you can customize it. Have a look at the string-manipulation function in the DBP help. If used correctly, you only ever need the LEFT$, RIGHT$ and LEN functions. However, the others like MID$ and FIND FIRST TOKEN$ make life a lot easier.

+ Code Snippet

mystat$ = "intelligence(30%)"

PRINT "Original Text: " + mystat$
PRINT GetString$(mystat$)
PRINT GetValue(mystat$)

PRINT "": PRINT "Press any key...": WAIT KEY: END

Function GetString$(txt$)
      ret$ = FIRST TOKEN$(txt$, "(")
EndFunction ret$


Function GetValue(txt$)
      tmp$ = FIRST TOKEN$(txt$, ")")
      ccount = FIND FIRST CHAR$(txt$, "(")
      tmp$ = RIGHT$(tmp$, LEN(tmp$) - ccount)
      ret# = VAL(tmp$)
EndFunction ret#

Quote: "Related to 2, how do I reliably turn a percentage in the form of a string into a decimal for calculation?"

What zeroSlave said

Quote: "Can someone link me to a page explaining the types of values and what numbers they can store?
"

Open a blank file in the editor, press F1. Click "Principles" then "Datatypes and variables". All you basically need to know.

Quote: "Also, I'm really confused as to how RGB values behave when input into functions,"

The other thing zeroSlave said.

Quote: "Hope this helps and isn't to confusing."

It shouldn't be. In fact you could be writing tutorials. That was very well put and a lot more coherent then many of the "|-|0\/\/ |-0 c0|)3 ||\| |-3|-| Darkbasicz"* floating about the web.

Translation:

+ Code Snippet

"|-|0\/\/ |-0 c0|)3 ||\| |-3|-| Darkbasicz"
"How to code in t3h Darkbasicz"

After countless volumes of Megatokyo, one gets to understand
some of this...err...language, scarily.

Back to top

Profile PM Email Website

Sorry your browser is not supported!

Newcomers DBPro Corner / Function Parameter and Output Help