Sorry your browser is not supported!

// Project: MotionInputDemo 
// Created: 2015-07-12

// set window properties
CompleteRawJoystickDetection()

SetWindowTitle( "MotionInputDemo" )
SetWindowSize( 1600, 900, 0 )
// Fix to a landscape mode
SetOrientationAllowed( 0, 0, 1, 0 )

// set display properties
SetVirtualResolution( GetDeviceWidth(), GetDeviceHeight() )
//SetOrientationAllowed( 1, 1, 1, 1 )

// What can this device do?
b_HasGyro = GetGyroSensorExists()
b_HasAccel = GetAccelerometerExists()
b_HasRot = GetRotationVectorSensorExists()
b_HasKey = GetKeyboardExists()
b_HasMouse = GetMouseExists()
b_HasJoy = GetJoystickExists()
b_HasLight = GetLightSensorExists()
b_HasProx = GetProximitySensorExists()

i_NumJoys = 0
for i=1 to 4
	if GetRawJoystickExists( i )
		i_NumJoys = i_NumJoys + 1
	endif
next i

i_Key = -1

SetPrintSize( GetDeviceWidth()/ 72)
do
    if b_HasGyro
		Print( "Gyroscope detected." )
		PrintC( "-Velocity: X:" )
		PrintC( GetRawGyroVelocityX() )
		PrintC( ", Y:")
		PrintC( GetRawGyroVelocityY() )
		PrintC( ", Z:")
		Print( GetRawGyroVelocityZ() )
		Print( "")
	endif
	if b_HasAccel
		Print( "Accelerometer detected." )
		PrintC( "-Direction: X:" )
		PrintC( GetRawAccelX() )
		PrintC( ", Y:")
		PrintC( GetRawAccelY() )
		PrintC( ", Z:")
		Print( GetRawAccelZ() )
		Print( "" )
	endif
	if b_HasRot
		Print( "Rotation sensor detected." )
		PrintC( "-Rotation: W:" )
		PrintC( GetRawRotationVectorW() )
		PrintC( ", X:")
		PrintC( GetRawRotationVectorX() )
		PrintC( ", Y:")
		PrintC( GetRawRotationVectorY() )
		PrintC( ", Z:")
		Print( GetRawRotationVectorZ() )
		Print( "" )
	endif
	if b_HasKey
		Print( "Keyboard detected." )
		PrintC( "-Last key pressed: ")
		if GetRawKeyReleased( GetRawLastKey() )
			i_Key = -1
		elseif GetRawKeyPressed( GetRawLastKey() )
			i_Key = GetRawLastKey()
		endif
		if ( i_Key >= 32 ) and ( i_Key <=126 )
			PrintC( Chr( i_Key ) )
			PrintC( ", " )
		endif
		Print( i_Key )
		Print( "" )
	endif
	if b_HasMouse
		Print( "Mouse detected." )
		PrintC( "-Position: X:" )
		PrintC( GetRawMouseX() )
		PrintC( ", Y:" )
		Print( GetRawMouseY() )
		PrintC( "-Buttons: L:" )
		PrintC( GetRawMouseLeftState() )
		PrintC( ", R:" )
		PrintC( GetRawMouseRightState() )
		PrintC( ", M:" )
		Print( GetRawMouseMiddleState() )
		PrintC( "-Wheel: " )
		Print( GetRawMouseWheel() )
		Print( "" )
	endif
	if b_HasJoy
		for t=1 to i_NumJoys
			if GetRawJoystickConnected( t )
				Print( "Gamepad detected." )
				PrintC( "-Buttons:" )
				for i=1 to 32
					if GetRawJoystickButtonState( t, i )
						PrintC(" ")
						PrintC( i )
					endif
				next i
				Print( "" )
				PrintC( "-Axes: X:" )
				PrintC( GetRawJoystickX( t ) )
				PrintC( ", Y:" )
				PrintC( GetRawJoystickY( t ) )
				PrintC( ", Z:" )
				Print( GetRawJoystickZ( t ) )
				PrintC( "-Rotation: X:" )
				PrintC( GetRawJoystickRX( t ) )
				PrintC( ", Y:" )
				PrintC( GetRawJoystickRY( t ) )
				PrintC( ", Z:" )
				Print( GetRawJoystickRZ( t ) )
				Print( "" )
			endif
		next t
	endif
	if b_HasLight
		Print( "Light sensor detected." )
		PrintC( "-Lumens: " )
		Print( GetRawLightLevel() )
		Print( "" )
	endif
	if b_HasProx
		Print( "Proximity sensor detected." )
		PrintC( "-Proximity: " )
		Print( GetRawProximityDistance() )
		Print( "" )
	endif
	i_Touch = GetRawTouchCount( 0 )
	//For PC debugging
//	i_Touch = 5 
	if i_Touch > 0
		Print( "Touch information:" )
		i_TID = GetRawFirstTouchEvent( 0 )
		q = 1
		while q <= i_Touch
			PrintC("-Touch #")
			Print( q )
			PrintC( "--Event type ( 0=default, 1=tap, 2=hold, 3=drag ): " )
			PrintC( GetRawTouchType( i_TID ) )
			PrintC( "at X:" )
			PrintC( GetRawTouchCurrentX( i_TID ) )
			PrintC( ", Y:" )
			Print( GetRawTouchCurrentY( i_TID ) )
			if q < i_Touch
				i_TID = GetRawNextTouchEvent()
			endif
			inc q
		endwhile
	endif
				
		
	

//    Print( ScreenFPS() )
    Sync()
loop

// Project: MotionInputDemo 
// Created: 2015-07-12

// Set display properties
SetWindowTitle( "MotionInputDemo" )

// What can this device do?
b_HasGyro = GetGyroSensorExists()
b_HasAccel = GetAccelerometerExists()

// Setup sprites
//
// Ring is the background circle
// Knob is the position of input
// Think of it like an analog stick where Knob is what you move and Ring is the limit of movement.
//
i_W = GetDeviceWidth()
i_H = GetDeviceHeight()

SetWindowSize( i_W*0.75, i_H*0.75, 0 )
SetVirtualResolution( i_W, i_H )

i_RingID = CreateSprite( LoadImage( "BlueOrb.png" ) )
i_KnobID = CreateSprite( LoadImage( "GrayOrb.png" ) )

i_Orient = GetOrientation()

//SetOrientationAllowed( 1, 0, 0, 0 )

b_RunOnce = 0

Orient:

// I'm not actually clear on whether this is necessary
if b_RunOnce > 0
	i_W = GetDeviceWidth()
	i_H = GetDeviceHeight()
	SetWindowSize( i_W*0.75, i_H*0.75, 0 )
	SetVirtualResolution( i_W, i_H )
endif

if i_W > i_H
	SetPrintSize( i_W / 24.0 )
	f_RSScale# = GetSpriteHeight( i_RingID ) / i_H
	f_KSScale# = GetSpriteHeight( i_KnobID ) / i_H
else
	SetPrintSize( i_H / 24.0 )
	f_RSScale# = GetSpriteWidth( i_RingID ) / i_W
	f_KSScale# = GetSpriteWidth( i_KnobID ) / i_W
endif

SetSpriteScale( i_RingID, f_RSScale#, f_RSScale# )
SetSpriteScale( i_KnobID, 0.15 * f_KSScale#, 0.15 * f_KSScale# )
SetSpriteOffset( i_RingID, GetSpriteWidth( i_RingID ) / 2, GetSpriteHeight( i_RingID ) / 2 )
SetSpriteOffset( i_KnobID, GetSpriteWidth( i_KnobID ) / 2, GetSpriteHeight( i_KnobID ) / 2 )

// These get used alot
// Half-width and Half-height
f_HW# = i_W / 2.0
f_HH# = i_H / 2.0
f_HRingW# = GetSpriteWidth( i_RingID ) / 2.0
f_HRingH# = GetSpriteHeight( i_RingID ) / 2.0

// Setup control mode
// Default to highest
i_Control = b_HasGyro + b_HasAccel

if b_RunOnce > 0
	dec b_RunOnce
	return
endif

do
	// Check for orientation change
	if GetOrientation() <> i_Orient
		i_Orient = GetOrientation()
		inc b_RunOnce
		GoSub Orient
	endif
	
	// Draw ring in the center
	SetSpritePositionByOffset( i_RingID, f_HW#, f_HH# )
	
	// Draw knob according to control
    if i_Control = 2
		Print( "Using Gyroscope" )
		SetSpritePositionByOffset( i_KnobID, ( GetRawGyroVelocityY() * f_HRingW# ) + f_HW#, ( GetRawGyroVelocityX() * f_HRingH# ) + f_HH# )		
	elseif i_Control = 1
		Print( "Using Accelerometer" )
		SetSpritePositionByOffset( i_KnobID, ( GetRawAccelX() * f_HRingW# ) + f_HW#, ( GetRawAccelY() * f_HRingH# ) + f_HH# )
	else
		Message( "Your device does not support motion controls." )
		Print( "Shutting down." )
		Sync()
		Sleep( 5000 )
		end
	endif
	
	// Rotate controls on tap
	if GetPointerPressed()
		if i_Control > 1
			dec i_Control
		else
			i_Control = b_HasGyro + b_HasAccel
		endif
	endif
	
	// End on Back/Esc
	if GetRawKeyPressed( 27 )
		exit
	endif
	
	// Draw	
    Sync()
loop