Sorry your browser is not supported!

// Project: 3d collision test
// Created: 2016-06-04

// set the size of the player to 10
size=10

// set window properties
SetVirtualResolution(1280,800)
SetWindowSize( 1280, 800, 0 )
SetDisplayAspect(1280 / 800.0)
SetScissor(0,0,0,0)
SetOrientationAllowed( 1, 1, 1, 1 )
SetCameraPosition(1,0,0,-150)
SetCameraLookAt(1,0,0,0,0)


// make player and colour him red
player=1
CreateObjectBox(player,size,size,size)
SetObjectColor(player,255,255,255,100)
SetObjectPosition(player,-90,0,0)
SetObjectCollisionMode(player,0)
SetObjectColor(player,255,0,0,255)

// make platform
platform=2
CreateObjectBox(platform,100,5,30)
SetObjectColor(platform,255,255,255,100)
SetObjectPosition(platform,0,-40,0)

// make an invisible platform that is bigger than the white platform (by the size of the player)
// the invisible platform is placed at the same position as the white platform
// the invisible platform is then used to detect collision
platform_inv = 3
CreateObjectBox(platform_inv,100+size,5+size,30+size)
SetObjectVisible(platform_inv,0)
SetObjectPosition(platform_inv,0,-40,0)

do

	// get player input
	joystick_y# = GetJoystickY()*-1
	joystick_x# = GetJoystickX()*1

	player_x#=player_x#+joystick_x#
	player_y#=player_y#+joystick_y#

	// save old position
	player_oldx# = GetObjectX(player)
	player_oldy# = GetObjectY(player)

	// check to see if player hits platform
	// if player touches platform , make him stay there
	// inside of sphere cast use a ray cast against the invisible platform
	// this then looks like the red box is colliding with the white platform in a perfect "box slide" collision
	if ObjectRayCast(platform_inv, player_oldx#, player_oldy#,0.0,player_x#, player_y#,0.0) <> 0
		player_x# = GetObjectRayCastSlideX(0)
		player_y# = GetObjectRayCastSlideY(0)
	endif

	// position the player
	SetObjectPosition(player, player_x#, player_y#, 0.0)
	sync()

loop

// Project: Basic World Setup 
// Created: 2016-03-05 By Stab In The Dark Software/slightly modifyed by Micky4fun

//Set window properties
SetWindowTitle( "Basic World Setup" )
SetWindowSize( GetDeviceWidth(), GetDeviceHeight(), 0 )
//Set display properties
SetVirtualResolution ( GetDeviceWidth(), GetDeviceHeight() )

//Set Backdrop color
SetClearColor( 0,170,204 ) // light blue
//Set display orientation for mobile device
SetOrientationAllowed( 0, 0, 1, 0 )
SetScissor( 0, 0, 0, 0 )
SetVSync(1)  

//Set camera
SetCameraRange( 1, 1, 5000 )
SetCameraPosition(1, 0, 100.0, -250.0)
SetCameraLookAt(1, 0.0, 50.0, 0.0, 0.0)

Create3DPhysicsWorld()

Platform = CreateObjectBox( 280, 10, 10 )
SetObjectPosition( Platform, 0, 0, 0 )
SetObjectRotation(Platform,0,0,25)
//This command creates a static physics body for the floor box with a triangle mesh collision shape.
//A static physics body has no mass and does not get moved.
Create3DPhysicsStaticBody( Platform )
//This 3D Physics command changes the collision shape to a primative box shape since we do not need the accuracy of
// polygon collision for just a box. The physics body is still static.
SetObjectShapeBox( Platform ) //


do
	
    //small delay before creating next object.
	delay=delay+1
	
	if delay>30
		delay=0
		primativeType = Random( 1, 3 )

		if ( primativeType = 1 )
			objectID = CreateObjectBox( 15.0, 40.0, 15.0 )
			SetObjectColor( objectID, 255, 0, 0, 255 )
			SetObjectPosition( objectID , 100.0, 120.0, 0.0 )
			//This command creates a dynamic body for the object. By default it gives it a box collision shape.
			Create3DPhysicsDynamicBody( objectID )
		endif
		
		if ( primativeType = 2 )
			objectID = CreateObjectSphere( 10, 10, 10 )
			SetObjectColor( objectID, 0, 255, 0, 255 )
			SetObjectPosition( objectID , 100.0, 150.0, 0.0 )
			Create3DPhysicsDynamicBody( objectID )
			//This command changes the collison shape to a sphere.
			SetObjectShapeSphere( objectID )	
		endif
		
		if ( primativeType = 3 )
			objectID = CreateObjectCylinder( 20.0, 15.0, 16 )
			SetObjectColor( objectID, 0, 0, 255, 255 )
			SetObjectPosition( objectID , 100, 180.0, 0.0 )
			Create3DPhysicsDynamicBody( objectID )
			//This command changes the collison shape to a cylinder.
			SetObjectShapeCylinder( objectID, 1 )
		endif
	
   endif

    Step3DPhysicsWorld() //required for updating physics.
    Sync()
loop