Sorry your browser is not supported!

Function ColorPick(x as integer, y as integer)

` feel free to load any image you want here
//imgBackdrop = LoadImage("colourBand.png")

yMin = y + 17
yMax = y + 17 + 255

cAlpha = 255
cRed = 255
cGreen = 255
cBlue = 255

sprBackground = CreateSprite(0)
SetSpritePosition(sprBackground, x, y)
SetSpriteSize(sprBackground, 294, 300)
SetSpriteColor(sprBackground, 128, 128, 128, 255)

sprMixerBackground = CreateSprite(0)
SetSpriteSize(sprMixerBackground, 100, 100)
SetSpritePosition(sprMixerBackground, x + 175, y + 12)

sprMixer = CreateSprite(0)
SetSpriteSize(sprMixer, 100, 100)
SetSpriteColor(sprMixer, cRed, cGreen, cBlue, cAlpha)
SetSpritePosition(sprMixer, x + 175, y + 12)

sprAccept = CreateSprite(0)
SetSpriteSize(sprAccept, 48, 20)
SetSpriteColor(sprAccept, 0, 255, 0, 255)
SetSpritePosition(sprAccept, x + 175, y + 262)

sprCancel = CreateSprite(0)
SetSpriteSize(sprCancel, 48, 20)
SetSpriteColor(sprCancel, 255, 0, 0, 255)
SetSpritePosition(sprCancel, x + 227, y + 262)

txtButtons = CreateText("OKAY QUIT")
SetTextSize(txtButtons, 16)
SetTextColor(txtButtons, 0, 0, 0, 255)
SetTextPosition(txtButtons, x + 180, y + 264)

sprTrack1 = CreateSprite(0)
SetSpriteSize(sprTrack1, 3, 256)
SetSpriteColor(sprTrack1, 200, 200, 200, 255)
SetSpritePosition(sprTrack1, x + 30, y + 22)

sprTrack2 = CloneSprite(sprTrack1)
SetSpritePosition(sprTrack2, x + 65, y + 22)

sprTrack3 = CloneSprite(sprTrack1)
SetSpritePosition(sprTrack3, x + 100, y + 22)

sprTrack4 = CloneSprite(sprTrack1)
SetSpritePosition(sprTrack4, x + 135, y + 22)

txtAlpha = CreateText("Alpha: " + str(cAlpha))
SetTextSize(txtAlpha, 16)
SetTextPosition(txtAlpha, x + 175, y + 120)

txtRed = CreateText("Red  : " + str(cRed))
SetTextSize(txtRed, 16)
SetTextPosition(txtRed, x + 175, y + 136)

txtGreen = CreateText("Green: " + str(cGreen))
SetTextSize(txtGreen, 16)
SetTextPosition(txtGreen, x + 175, y + 152)

txtBlue = CreateText("Blue : " + str(cBlue))
SetTextSize(txtBlue, 16)
SetTextPosition(txtBlue, x + 175, y + 168)

txtHexLabel = CreateText("Hex:")
SetTextSize(txtHexLabel, 16)
SetTextPosition(txtHexLabel, x + 175, y + 188)

hAlpha$ = hex(cAlpha)
if len(hAlpha$) = 1 then hAlpha$ = "0" + hAlpha$
hRed$ = Hex(cRed)
if len(hRed$) = 1 then hRed$ = "0" + hRed$
hGreen$ = Hex(cGreen)
if len(hGreen$) = 1 then hGreen$ = "0" + hGreen$
hBlue$ = Hex(cBlue)
if len(hBlue$) = 1 then hBlue$ = "0" + hBlue$

hColor$ = hAlpha$ + hRed$ + hGreen$ + hBlue$

txtHex = CreateText(hColor$)
SetTextSize(txtHex, 16)
SetTextPosition(txtHex, x + 175, y + 204)

sprSliderA = CreateSprite(0)
SetSpriteSize(sprSliderA, 20, 10)
SetSpritePosition(sprSliderA, x + 22, y + 17)

sprSliderR = CloneSprite(sprSliderA)
SetSpritePosition(sprSliderR, x + 57, y + 17)
SetSpriteColor(sprSliderR, 255, 0, 0, 255)

sprSliderG = CloneSprite(sprSliderA)
SetSpritePosition(sprSliderG, x + 92, y + 17)
SetSpriteColor(sprSliderG, 0, 255, 0, 255)

sprSliderB = CloneSprite(sprSliderA)
SetSpritePosition(sprSliderB, x + 127, y + 17)
SetSpriteColor(sprSliderB, 0, 0, 255, 255)

`*** function input loop ***
do
   if GetPointerState() = 1 AND GetSpriteHit(GetPointerX(), GetPointerY()) = sprSliderA
       repeat
           y# = GetPointerY()
           if y# < yMin then y# = yMin
           if y# > yMax then y# = yMax
           SetSpritePosition(sprSliderA, x + 22, y#)
           cAlpha = 255 - (y# - yMin)
           hAlpha$ = hex(cAlpha)
           if len(hAlpha$) = 1 then hAlpha$ = "0" + hAlpha$
           hColor$ = hAlpha$ + hRed$ + hGreen$ + hBlue$
           SetTextString(txtHex, hColor$)
           SetSpriteColorAlpha(sprMixer, cAlpha)
           SetTextString(txtAlpha, "Alpha: " + str(cAlpha))
           sync()
       until GetPointerState() = 0
   endif

   if GetPointerState() = 1 AND GetSpriteHit(GetPointerX(), GetPointerY()) = sprSliderR
       repeat
           y# = GetPointerY()
           if y# < yMin then y# = yMin
           if y# > yMax then y# = yMax
           SetSpritePosition(sprSliderR, x + 57, y#)
           cRed = 255 - (y# - yMin)
           hRed$ = Hex(cRed)
           if len(hRed$) = 1 then hRed$ = "0" + hRed$
           hColor$ = hAlpha$ + hRed$ + hGreen$ + hBlue$
           SetTextString(txtHex, hColor$)
           SetSpriteColorRed(sprMixer, cRed)
           SetTextString(txtRed, "Red  : " + str(cRed))
           sync()
       until GetPointerState() = 0
   endif

   if GetPointerState() = 1 AND GetSpriteHit(GetPointerX(), GetPointerY()) = sprSliderG
       repeat
           y# = GetPointerY()
           if y# < yMin then y# = yMin
           if y# > yMax then y# = yMax
           SetSpritePosition(sprSliderG, x + 92, y#)
           cGreen = 255 - (y# - yMin)
           hGreen$ = Hex(cGreen)
           if len(hGreen$) = 1 then hGreen$ = "0" + hGreen$
           hColor$ = hAlpha$ + hRed$ + hGreen$ + hBlue$
           SetTextString(txtHex, hColor$)
           SetSpriteColorGreen(sprMixer, cGreen)
           SetTextString(txtGreen, "Green: " + str(cGreen))
           sync()
       until GetPointerState() = 0
   endif

   if GetPointerState() = 1 AND GetSpriteHit(GetPointerX(), GetPointerY()) = sprSliderB
       repeat
           y# = GetPointerY()
           if y# < yMin then y# = yMin
           if y# > yMax then y# = yMax
           SetSpritePosition(sprSliderB, x + 127, y#)
           cBlue = 255 - (y# - yMin)
           hBlue$ = Hex(cBlue)
           if len(hBlue$) = 1 then hBlue$ = "0" + hBlue$
           hColor$ = hAlpha$ + hRed$ + hGreen$ + hBlue$
           SetTextString(txtHex, hColor$)
           SetSpriteColorBlue(sprMixer, cBlue)
           SetTextString(txtBlue, "Blue : " + str(cBlue))
           sync()
       until GetPointerState() = 0
   endif

   if GetPointerReleased() = 1 AND GetSpriteHit(GetPointerX(), GetPointerY()) = sprAccept
       hColor$ = hAlpha$ + hRed$ + hGreen$ + hBlue$
       return$ = hColor$
       exit
   endif

   if GetPointerReleased() = 1 AND GetSpriteHit(GetPointerX(), GetPointerY()) = sprCancel
       return$ = "CANCELLED"
       exit
   endif

   sync()
loop

`*** cleanup ***
//DeleteImage(imgBackdrop)
DeleteSprite(sprBackground)
DeleteSprite(sprMixerBackground)
DeleteSprite(sprTrack1)
DeleteSprite(sprTrack2)
DeleteSprite(sprTrack3)
DeleteSprite(sprTrack4)
DeleteSprite(sprMixer)
DeleteSprite(sprSliderA)
DeleteSprite(sprSliderR)
DeleteSprite(sprSliderG)
DeleteSprite(sprSliderB)
DeleteSprite(sprAccept)
DeleteSprite(sprCancel)

DeleteText(txtAlpha)
DeleteText(txtRed)
DeleteText(txtGreen)
DeleteText(txtBlue)
DeleteText(txtHexLabel)
DeleteText(txtHex)
DeleteText(txtButtons)

EndFunction return$

 
// Project: colorpicker 
// Created: 2017-01-04

// show all errors
SetErrorMode(2)

#constant width=1024
#constant height=768

// set window properties
SetWindowTitle( "colorpicker" )
SetWindowSize( width, height, 0 )

// set display properties
SetVirtualResolution( width, height )
SetOrientationAllowed( 1, 1, 1, 1 )
SetSyncRate( 30, 0 ) // 30fps instead of 60 to save battery
//UseNewDefaultFonts( 1 ) // since version 2.0.20 we can use nicer default fonts


global rainbowmemory as integer[4]
global spr as integer [4]

img=rainbow(width/2,height-100)

logo=CreateText("Colour Picker")

SetTextSize(logo,30)
t=CreateText("RGB - ")
SetTextSize(t,30)
t1=CreateText("HEX - ")
SetTextSize(t1,30)
t2=CreateText("INT - ")
SetTextSize(t2,30)
t3=CreateText("INTTORGB - ")
SetTextSize(t3,30)
t4=CreateText("MAKECOLOR - ")
SetTextSize(t4,30)
alpha=255
do

	SetSpritePosition(spr[0],0,30)
	SetSpritePosition(spr[1],0,height-50)

	colour1=getpixelcolor(spr[0], rainbowmemory[0],getpointerx(),getpointery())
	colour2=getpixelcolor(spr[1], rainbowmemory[1],getpointerx(),getpointery())
	if colour1=0 
		col=colour2
	else
		col=colour1
	endif
	
// Results	
	drawbox(700,100,750,150,col,col,col,col,1)
	drawbox(0,height-80,width,height-40,0,col,0,col,1)
	SetTextString(t,"RGB - " + str(GetColorRed(col)) + " - " + str(GetColorGreen(col)) + " - " + str(GetColorBlue(col)))
	SetTextString(t1,"HEX - " +hex(getcolorred(col)) +" - " + hex(GetColorGreen(col)) + " - " + hex(GetColorBlue(col)))
	rgbvalue = (GetColorRed(col) << 24) + (GetColorGreen(col) << 16) + (GetColorBlue(col) << 8) + alpha
	SetTextString(t2,"RGB-INT - " +str(rgbvalue))
	newred = rgbvalue >> 24 && val("ff",16)
	newgreen = rgbvalue >> 16 && val("ff",16)
	newblue = rgbvalue >> 8  && val("ff",16)
	newalpha = rgbvalue && val("ff",16)
	SetTextString(t3,"INT-RGB " + str(newred) + " - " + str(newgreen) + " - " + str(newblue) + " - " + str(newalpha))
	SetTextString(t4,"MAKECOLOR=" + str(makecolor(newred,newgreen,newblue)))
	
	
	SetTextPosition(logo,700,20)
	SetTextPosition(t,600,200)
	SetTextPosition(t1,600,230)
	SetTextPosition(t2,600,260)
	SetTextPosition(t3,600,290)
	SetTextPosition(t4,600,320)
	
	
    Print( ScreenFPS() )
    Sync()
loop

function getpixelcolor(img, mem, wherex, wherey)


	if (wherex> getspritex(img) and wherex<getspritex(img)+GetSpriteWidth(img) and wherey>getspritey(img) and wherey<getspritey(img)+GetSpriteHeight(img))
		size=GetMemblockSize(mem)

		offset=12 + ((((wherey-getspritey(img)) * GetSpriteWidth(img)) + wherex) *4)
		if offset<=size
			r=GetMemblockByte(mem,offset)
			g=GetMemblockByte(mem,offset+1)
			b=GetMemblockByte(mem,offset+2)
			a=GetMemblockByte(mem,offset+3)
	
			color=makecolor(r,g,b)
		endif
	endif
	
endfunction color




function rainbow(x1, y1)

	red=makecolor(255,0,0)
	green=makecolor(0,255,0)
	blue=makecolor(0,0,255)
	white=makecolor(255,255,0)
			
	render()	
    Drawbox(0, 0, x1, y1, red, green, blue, white ,1)
	swap()
	img=getimage(0,0,x1,y1)
	rainbowmemory[0]=CreateMemblockFromImage(img)
	spr[0]=CreateSprite(rainbowmemory[0])
	
	
	render()
	drawbox(0,0,width,50,makecolor(0,0,0),makecolor(255,255,255),makecolor(0,0,0),makecolor(255,255,255),1)
	swap()
	img=getimage(0,0,width,50)
	
	rainbowmemory[1]=CreateMemblockFromImage(img)
	spr[1]=CreateSprite(rainbowmemory[1])
	
	


	
endfunction img

// Project: color_picker2
// by blendman and another guy (I don't remember its name :( )
// Created: 2017-02-20


// set window properties
SetWindowTitle( "color_picker2" )
SetWindowSize( 1024, 768, 0 )

// set display properties
SetVirtualResolution( 1024, 768 )
SetOrientationAllowed( 1, 1, 1, 1 )
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts
SetClearColor(150,150,150)

C_white = MakeColor(255,255,255)
Color = 255


// create the rainbow and color
h = 255
w = 30
x = 10
y = 10
x1 = x+w+5

iRainbow = CreateRainBow(w,h)
SpRainbow = CreateSprite(iRainbow)
SetSpritePosition(SpRAinbow,10,y)

SpColor=CreateSprite(0)
SetSpriteColor(SpColor,GetColorRed(Color),GetColorGreen(Color),GetColorBlue(Color),255)
SetSpritePosition(SpColor,50,y+h+50)
SetSpriteSize(SpColor,64,64)


do
	
	drawbox(x1,y,x1+h,y+h,0,color,0,C_white,1)
	if pick = 0
		DrawEllipse(xx0,yy0,5,5,C_white,C_white,0)
	endif
	if pick2 = 0
		DrawLine(x,yy2,x+w,yy2,C_white,C_white)
	endif
	
	
    if getpointerState()
		xx = getpointerX()
		yy = getpointerY()
		
		if xx>=x1 and xx<=x1+h and yy>=y and yy<=y+h
			pick = 1
			Color1 = ColorPick2(xx,yy)
			SetSpriteColor(SpColor,GetColorRed(Color1),GetColorGreen(Color1),GetColorBlue(Color1),255)
			xx0 = xx
			yy0 = yy
			
		elseif xx>=x and xx<=x+w and yy>=y and yy<=y+h
			// in rainbow
			pick2 = 2	
			Color = ColorPick2(xx,yy)
			xx2 = xx
			yy2 = yy
					
		endif
		
	elseif GetPointerReleased()
		pick = 0
		pick2 = 0	
	endif
	
   
    Sync()
loop


Function CreateRainBow(w,h)

	// create the rainbow

	clearscreen()
	render()
	
	local r,g,b as  float
	r 	= 255
	g	= 0
	b 	= 0
	
	phase = 0
	
	a as float
	a = (255*6)
	a = a/h
	
	c = makecolor(r,g,b)
	
	For i = 0 to h
		
		Drawbox(0, i, w, i+1, c,c,c,c,1)
		if phase = 0
			b = b + a
			if b >= 255
				b=255
				phase = 1
			endif
		elseif phase = 1			
			r = r - a
			if r<=0
				r=0
				phase = 2
			endif		
		elseif phase = 2
			g = g + a
			if g>=255
				g=255
				phase = 3
			endif		
		elseif phase = 3
			// dec b
			b = b -a
			if b<= 0
				b=0
				phase = 4
			endif		
		elseif phase = 4
			// inc r
			r = r + a
			if r>=255
				r=255
				phase =5
			endif			
		elseif phase = 5
			// dec g
			g = g -a
			if g<= 0
				g=0
				//exit				
			endif					
		endif
		c = makecolor(r,g,b)
    next
    
    swap()
    
    img=getimage(0,0,w,h)
	
EndFunction img

Function ColorPick2(x, y)
	
	colorValue = Point(x,y,0)	
		
EndFunction colorValue



// Function found on TGC forum or TGC code
`FUNCTION: Get Color Data of Point
Function Point(x as integer, y as integer, returnType as integer)

	// ReturnType 0: Return raw INTEGER color value
	// ReturnType 1: Return RED color component value
	// ReturnType 2: Return GREEN color component value
	// ReturnType 3: Return BLUE color component value
	// ReturnType 4: Return ALPHA color component value

	// Prepare scene for capturing image
	Update(0) : Render()

	// Get temporary image at specified coordinates
	pointImg = GetImage(x, y, 1, 1)

	// Convert captured image to memblock
	pointMb = CreateMemblockFromImage(pointImg)

	// Store raw integer color value
	pointColor = GetMemblockInt(pointMb, 12)
	
	// Clean Up
	DeleteImage(pointImg)
	DeleteMemblock(pointMb)
	
	// Swap Buffer
	// Swap()

	// Return appropriate data
	Select returnType
		
		// Red Value
		Case 1
			pointColor = GetColorR(pointColor)
		EndCase
		
		// Green Value
		Case 2
			pointColor = GetColorG(pointColor)
		EndCase
		
		// Blue Value
		Case 3
			pointColor = GetColorB(pointColor)
		EndCase
		
		// Alpha Value		
		Case 4
			pointColor = GetColorA(pointColor)
		EndCase

	EndSelect
	
EndFunction pointColor


`FUNCTION: Get Individual Color Data from Raw Integer Value
`Red
Function GetColorR(colorVal As Integer)
    result = colorVal && 0xff
Endfunction result

`Green
Function GetColorG(colorVal As Integer)
    result = (colorVal >> 8) && 0xff
Endfunction result

`Blue
Function GetColorB(colorVal As Integer)
    result = (colorVal >> 16) && 0xff
Endfunction result

`Alpha
Function GetColorA(colorVal As Integer)
    result = (colorVal >> 24) && 0xff
Endfunction result

// Project: TextureMaker 
// Created: 2017-02-22

// show all errors
SetErrorMode(2)

// set window properties
SetWindowTitle( "TextureMaker" )
SetWindowSize( 1024, 768, 0 )

// set display properties
SetVirtualResolution( 1024, 768 )
SetOrientationAllowed( 1, 1, 1, 1 )
SetSyncRate( 30, 0 ) // 30fps instead of 60 to save battery
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts


textureimage = createtexture(500,500, 0, 0,255)
texture = createsprite(textureimage)





do
		SetSpritePosition( texture, getpointerx(), getpointery() )
		

    Print( ScreenFPS() )
    Sync()
loop

// Function to create a texture
//
// Inputs - Sizex - size of the texture to create - width
//          Sizey - size of the texture to create - height
//          Red   - this is the value 0-255 that would introduce a red tint 
//          green   - this is the value 0-255 that would introduce a green tint 
//          Blue   - this is the value 0-255 that would introduce a blue tint 

// 
// Returns the image for the resulting texture
//
// EG. CreateTexture ( 100, 100, 0, 0, 255)
//          This could create a DEEP water effect texture?

function createtexture(sizex# as float, sizey# as float, red, green, blue as integer)

	color=makecolor(red,green,blue)
	swap()
	drawbox(0,0,sizex#, sizey#, color, color,color,color, 1)
	render()
	img = getimage(0,0,sizex#, sizey#)
	
	memblockid = CreateMemblockFromImage (img)
	imgwidth = GetMemblockInt(memblockid, 0)
	imgheight = GetMemblockInt(memblockid, 4)
	
	
        size=GetMemblockSize(memblockid)

		for offset=12 to size-4 step 4
        
            
			SetMemblockByte (memblockid, offset, random(1,red))
			SetMemblockByte (memblockid, offset+1, random(1, green))
			SetMemblockByte (memblockid, offset+2, random(1, blue) )
			SetMemblockByte (memblockid, offset+3, 255)
			 
 		
	next
	
	deleteimage	(img)
	
	img = CreateImageFromMemblock(memblockid)
	DeleteMemblock(memblockid)


endfunction img

// Project: TextureMaker 
// Created: 2017-02-22

// show all errors
SetErrorMode(2)

// set window properties
SetWindowTitle( "TextureMaker" )
SetWindowSize( 1024, 768, 0 )

// set display properties
SetVirtualResolution( 1024, 768 )
SetOrientationAllowed( 1, 1, 1, 1 )
SetSyncRate( 30, 0 ) // 30fps instead of 60 to save battery
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts



textureimage = createtexture(500,500, makecolor(0,0,255) ,100)
texture = createsprite(textureimage)





do
		SetSpritePosition( texture, getpointerx(), getpointery() )
		

    Print( ScreenFPS() )
    Sync()
loop

// Function to create a texture
//
// Inputs - Sizex - size of the texture to create - width
//          Sizey - size of the texture to create - height
//          Color - is the main color of the image
//          Denisity - is a the depth of the texture - the lower the value, the more detail. higher value = no detail
// 
// Returns the image for the resulting texture
//
// EG. CreateTexture ( 100, 100,  makecolor(0,0,255), 100)
//          This could create a DEEP water effect texture?

function createtexture(sizex# as float, sizey# as float, color, density as integer)

	
	swap()
	drawbox(0,0,sizex#, sizey#, color, color,color,color, 1)
	render()
	img = getimage(0,0,sizex#, sizey#)
	
	memblockid = CreateMemblockFromImage (img)
	imgwidth = GetMemblockInt(memblockid, 0)
	imgheight = GetMemblockInt(memblockid, 4)
	
	
        size=GetMemblockSize(memblockid)

		for offset=12 to size-4 step 4
      
			r=GetMemblockByte(memblockid, offset)
			g=GetMemblockByte(memblockid, offset+1)
			b=GetMemblockByte(memblockid, offset+2)
			a=GetMemblockByte(memblockid, offset+3)
			
        
			strength=random(1,density)

            SetMemblockByte (memblockid, offset, r-strength)
			SetMemblockByte (memblockid, offset+1, g-strength)
			SetMemblockByte (memblockid, offset+2, b-strength )
			SetMemblockByte (memblockid, offset+3, a-strength)
			 
 		
	next
	
	deleteimage	(img)
	
	img = CreateImageFromMemblock(memblockid)
	DeleteMemblock(memblockid)


endfunction img