It should be the same, because the random number algorithm used is the same. The only problem with relying on random for procedural content is that if the random algorithm were to change during an update (which it shouldn't do, but might when a bug is being fixed for example) then your levels will change. Probably best to use your own algorithms. Mod and FMOD are good for creating pseudo random numbers.
... thought I'd have a play around and create a pseudo random function. Ended up making a funky little scribble demo with it! Here it is (note: function myrand requires a global variable called myseed (integer)):
// Project: pseudo_random
// Created: 2017-02-21
// show all errors
SetErrorMode(2)
// set window properties
SetWindowTitle( "pseudo_random" )
SetWindowSize( 1000, 500, 0 )
// set display properties
SetVirtualResolution( 1000, 500 )
SetOrientationAllowed( 1, 1, 1, 1 )
SetSyncRate( 60, 0 ) // 30fps instead of 60 to save battery
UseNewDefaultFonts( 1 ) // since version 2.0.22 we can use nicer default fonts
global myseed as integer
myseed = 1
` For this example, we will define dx and dy as our directions 1=up, 2=right, 3=down, 4=left
dx = 1
dy = 1
posx = 500
posy = 250
` Make it look cool
CreateRenderImage(1,1024,512,0,0)
CreateSprite(1,1)
setspritesize(1,1000,500)
SetSpritePositionByOffset(1,500,250)
CreateSprite(2,CreateImageColor(0,0,0,5))
SetSpriteSize(2,1000,500)
SetSpritePositionByOffset(2,500,250)
CreateSprite(3,1)
SetSpriteSize(3,1000.3,500.2)
SetSpritePositionByOffset(3,499.9,249.9)
SetSpriteAngle(3,0.1)
do
SetRenderToImage(1,0)
dx = myrand(-15,15)
dy = myrand(-15,15)
drawline(posx,posy,posx+dx,posy+dy, MakeColor(myrand(1,255),myrand(1,255),myrand(1,255)),MakeColor(myrand(1,255),myrand(1,255),myrand(1,255)))
DrawSprite(2)
DrawSprite(3)
posx = posx+dx
posy = posy+dy
`wrap our scribble
if posx > 1000 then posx = posx - 1000
if posy > 500 then posy = posy -500
if posx < 0 then posx = posx + 1000
if posy < 0 then posy = posy +500
` Print( ScreenFPS() )
SetRenderToScreen()
Sync()
loop
` a = lowest possible range, b = highest
function myrand(a as integer, b as integer)
` Use a standard Linear Congruential Generator algorithm
hi = myseed / 127773
lo = mod(myseed, 127773)
myseed = 16807 * lo - 2836 * hi
if myseed <= 0 then myseed = myseed + 2147482647
` fit the result into our required range
diff = (b-a)+1
result = a + mod(myseed, diff)
endfunction result
