Sorry your browser is not supported!

SetWindowSize( 1024, 768, 0 )
SetVirtualResolution(1024,768)
SetSyncRate( 60, 0 ) 

buttonX = 462
buttonY = 100
button = createSprite(0)
setSpriteSize(button, 100, 50)
setSpriteColor(button, 255,0,0,255)
setSpritePosition(button, buttonX, buttonY)


Global _OldMouseX = 0
Global _OldMouseY = 0


myTimer = 0

do
	frameTimer = getMilliseconds()
	
	if getMouseMoved() = 1
		myTimer = getMilliseconds()
		shakeButton = 0
		setSpritePosition(button, buttonX, buttonY)
	endif
  

	if (frameTimer - myTimer) >= 3000 and shakeButton = 0
		shakeButton = getMilliseconds()
	endif
	
	if shakeButton > 0
		if (frameTimer - shakeButton) >= 1500
			myTimer = getMilliseconds()
			shakeButton = 0
			setSpritePosition(button, buttonX, buttonY)
		else
			x = random(1,8)-4 
			y = random(1,8)-4 
			setSpritePosition(button, buttonX+x, buttonY+y)
		endif
	endif
	
  
  
   
   
	print("Timer: "+str(3 - (frameTimer - myTimer)/1000))
	updateGlobalMouse()
    Sync()
loop



function updateGlobalMouse()
	_OldMouseX = getRawMouseX()
	_OldMouseY = getRawMouseY()
endfunction


function getMouseMoved()
	if abs(getRawMouseX() - _OldMouseX) > 1 or  abs(getRawMouseY() - _OldMouseY) > 1
		exitfunction 1
	endif
endfunction 0

// Project: Hey You!
// Created: 2022-02-27
// By: Virtual Nomad
// show all errors
SetErrorMode(2)

// set window properties
SetWindowTitle( "Hey You!" )
SetWindowSize( 1280,720, 0 )
SetWindowAllowResize( 1 )

// set display properties
SetVirtualResolution( 640,360)
SetOrientationAllowed( 1, 1, 1, 1 )
SetSyncRate( 30, 0 ) 
SetScissor( 0,0,0,0 )
UseNewDefaultFonts( 1 ) 


GLOBAL MyTiles as Integer []
for x = 1 to 5
	for y = 1 to 5
		ThisTile = CreateSprite(0)	:	SetSpriteSize(ThisTile,60,60)
		SetSpriteColor(ThisTile, Random(128,255),Random(128,255),Random(128,255),255)
		SetSpritePositionByOffset(ThisTile,100 + x*64,y*64)
		SetSpriteDepth(ThisTile,100)
		MyTiles.Insert(ThisTile)
	next y
next x

Type Zoom
	SpriteID, Toggle
EndType

GLOBAL MyZooms as Zoom []

do

    If GetRawKeyState(27) then End
      
	If LastZoom# + 0.5 <= Timer()
		Repeat
			ThisSprite = MyTiles[ Random(0, MyTiles.Length) ]
		Until MyZooms.Find(ThisSprite) = -1
		AddZoom( ThisSprite )
		LastZoom# = Timer()
	EndIf

	If MyZooms.Length > -1 then Zoom()
		
    Sync()
loop

Function AddZoom(ThisSprite)
	ThisZoom as Zoom
		ThisZoom.SpriteID = ThisSprite
		ThisZoom.Toggle = 1
	MyZooms.InsertSorted(ThisZoom)
	SetSpriteDepth(ThisSprite,50)
EndFunction

Function Zoom()
	For x = MyZooms.Length to 0 Step -1
		ThisSprite = MyZooms[x].SpriteID
		ThisToggle = MyZooms[x].Toggle
		ThisScale# = GetSpriteScaleX(ThisSprite) + (ThisToggle/75.0) //change denominator to affect zoom rate
		If ThisToggle > 0 and ThisScale# => 1.2 then MyZooms[x].Toggle = -1
		If ThisToggle = -1 and ThisScale# <= 1.0
			MyZooms.Remove(x)
			ThisScale# = 1.0
			SetSpriteDepth(ThisSprite,100)
		EndIf
		SetSpriteScaleByOffset(ThisSprite, ThisScale#, ThisScale#)
	Next x
EndFunction