Sorry your browser is not supported!

// Project: CSV 
// Created: 2022-07-22
// By: Virtual Nomad
// show all errors
SetErrorMode(2)

// set window properties
SetWindowTitle( "CSV" )
SetWindowSize( 1280,720, 0 )
SetWindowAllowResize( 1 )

// set display properties
SetVirtualResolution( 1280,720)
SetOrientationAllowed( 1, 1, 1, 1 )
SetSyncRate( 30, 0 ) 
SetScissor( 0,0,0,0 )
UseNewDefaultFonts( 1 ) 


GLOBAL Width, Height, NumRows, NumCols, YOff = 100
Width = 50	:	Height = 24
NumRows = GetVirtualWidth()/Width
NumCols = (GetVirtualHeight()-YOff)/Height

GLOBAL File$ = "testfile.csv"
Type Cell
	ID, Value$
EndType

//load/make 50,50 csv
If GetFileExists(File$) = 0 then GenerateCSV()
LoadCSV(File$)

GLOBAL Data as Cell [100,100]
GLOBAL OnScreen as Cell [25,25]

GLOBAL StartX,StartY
FillScreen(0,0)

Type LookUp
	ID, x, y
EndType

GLOBAL TextIDs as LookUp []

CurrentCell$ = ""
do
	
    If GetRawKeyState(27) then End
    If Last# + 0.1 <= Timer()
		LR = GetRawKeyState(39)-GetRawKeyState(37)
		UD = GetRawKeyState(40)-GetRawKeyState(38)
		If LR <> 0 or UD <> 0
			StartX = StartX + LR	:	If StartX < 0 then StartX = 0	:	If StartX > 50-NumCols then StartX = 50-NumCols
			StartY = StartY + UD	:	If StartY < 0 then StartY = 0	:	IF StartY > 50-NumRows then StartY = 50 - NumRows
			FillScreen(StartX,StartY)
			Last# = Timer()
		EndIf
	EndIf
	
	If GetPointerPressed()
		CurrentCell$ = ""
		For x = 0 to TextIDs.Length
			ThisID = GetTextHitTest( TextIDs[x].ID,GetPointerX(),GetPointerY())
			If ThisID = 1
				CurrentCell$ = STR(TextIDs[x].x) + "," + STR(TextIDs[x].y) + "=" + GetTextString(TextIDs[x].ID)
				Exit
			EndIf
				
		Next x
	EndIf
	
	Print(STR(StartX) +","+STR(StartY))
	Print(CurrentCell$)
    Sync()
loop

Function ShowCell(x,y)

EndFunction
Function FillScreen(xx,yy)
	for x = 0 to 24
		for y = 0 to 24
			ThisX = xx + x	:	ThisY = yy + y
			If OnScreen[x,y].ID = 0
				OnScreen[x,y].ID = CreateText(Data[ThisX,ThisY].Value$)
				SetTextPosition(OnScreen[x,y].ID, x*Width+50, y*Height+100)
				SetTextSize(OnScreen[x,y].ID,16)
				SetTextAlignment(OnScreen[x,y].ID,2)
				ThisTXT as LookUp
					ThisTXT.ID = OnScreen[x,y].ID
				TextIDs.InsertSorted(ThisTXT)
			EndIf
			IND = TextIDs.Find(OnScreen[x,y].ID)
			TextIDs[IND].x = ThisX	:	TextIDs[IND].y = ThisY
			SetTextString(OnScreen[x,y].ID,Data[ThisX,ThisY].Value$)
			OnScreen[x,y].Value$ = Data[ThisX,ThisY].Value$
		next y
	next x
EndFunction

Function GenerateCSV()
	ThisCSV = OpenToWrite(File$)
		for y = 1 to 50
			ThisRow$ = ""
			for x = 1 to 50
				ThisData$ = STR( Random(100,3000)*100 )
				If x < 50 then ThisData$ = ThisData$ + ","
				ThisCell as Cell
				ThisCell.Value$ = ThisRow$ + ThisData$
				ThisRow$ = ThisRow$ + ThisData$
			next x
			WriteLine(ThisCSV,ThisRow$)
		next y
	CloseFile(ThisCSV)
EndFunction

Function LoadCSV(f$)
	If GetFileExists(f$)
		ThisCSV = OpenToRead(f$)
		Row = -1
		Repeat
			INC Row
			ThisRow$ = ReadLine(ThisCSV)
			For x = 1 to CountStringTokens2(ThisRow$,",")
				Data[x-1,Row].Value$ = GetStringToken2(ThisRow$,",",x)
			next x
		Until FileEOF(ThisCSV)
	EndIf
EndFunction

// Project: SearchResults 
// Created: 2022-07-25
// By: Virtual Nomad
// show all errors
SetErrorMode(2)
 
// set window properties
SetWindowTitle( "SearchResults" )
SetWindowSize( 360,640, 1 )
SetWindowAllowResize( 1 )

// set display properties
SetVirtualResolution( 360,640)
SetOrientationAllowed( 1, 1, 1, 1 )
SetSyncRate( 30, 0 ) 
SetScissor( 0,0,0,0 )
UseNewDefaultFonts( 1 ) 
SetPrintSize(24)

GLOBAL File$ = "inventory.dat"

Type Item
	ID$, ItemNum$, ItemName$, ItemDetails$
EndType

GLOBAL Inventory as Item []

Type Result
	SprID, TextID, ID$, ItemNum$, ItemName$, ItemDetails$
EndType

GetInventory() // Make/Load Inventory

GLOBAL SearchBUT = 1
	AddVirtualButton(SearchBUT,25,25,50)
	SetVirtualButtonText(SearchBUT,"SEARCH")
GLOBAL GoBUT = 2
	AddVirtualButton(GoBut,335,25,50)
	SetVirtualButtonText(GoBUT, "GO")
	SetVirtualButtonColor(GoBUT, 0,255,0)
	SetVirtualButtonVisible(GoBUT,0)
	SetVirtualButtonActive(GoBUT,0)
GLOBAL ClearBUT = 3
	AddVirtualButton(ClearBUT,285,25,50)
	SetVirtualButtonText(ClearBUT, "CLEAR")
	SetVirtualButtonColor(ClearBUT, 255,0,0)
	SetVirtualButtonVisible(ClearBUT,0)
	SetVirtualButtonActive(ClearBUT,0)
GLOBAL ReturnBUT = 4
	AddVirtualButton(ReturnBUT,25,25,50)
	SetVirtualButtonText(ReturnBUT, "RETURN")
	SetVirtualButtonColor(ReturnBUT, 255,0,255)
	SetVirtualButtonVisible(ReturnBUT,0)
	SetVirtualButtonActive(ReturnBUT,0)
GLOBAL SearchBox

SearchBox = CreateEditBox()	:	FixEditBoxToScreen(SearchBox,1)
	SetEditBoxText(SearchBox,"Enter ID")
	SetEditBoxSize(SearchBox,210,50)
	SetEditBoxPosition(SearchBox,50,0)
	SetEditBoxInputType(SearchBox,1)
	SetEditBoxTextSize( SearchBox, 36 )
	SetEditBoxCursorColor(SearchBox,0,0,0)
	SetEditBoxMaxChars(SearchBox,6)
	SetEditBoxActive(SearchBox,0)
	SetEditBoxVisible(SearchBox,0)
GLOBAL Results as Result []

do

    If GetRawKeyPressed(27) then End    

	If GetVirtualButtonPressed(SearchBUT) then Search()
	
	
    Print( Inventory.Length)
    Sync()
loop

Function Search()
	SetViewOffset(0,0)
	SetVirtualButtonVisible(SearchBUT,0)	:	SetVirtualButtonActive(SearchBUT,0)
	SetSearchActive(1)
	Repeat
		If GetVirtualButtonReleased(ReturnBUT)
			SetSearchActive(0)
			ExitFunction
		EndIf
		Sync()
	Until GetEditBoxHasFocus(SearchBox)
	
	If GetEditBoxHasFocus(SearchBox)
		SetEditBoxText(SearchBox,"")
		Repeat
			If GetVirtualButtonReleased(ClearBUT)
				SetEditBoxText(SearchBox,"")
				SetEditBoxFocus(SearchBox,1)
			EndIf
			
			//Ensure Numeric Only
			If LEN(GetEditBoxText(SearchBox)) > 0
				LastChar$ = MID( GetEditBoxText(SearchBox), LEN(GetEditBoxText(SearchBox)),1)
				While ASC(LastChar$) < 48 or ASC(LastChar$) > 57 and  LEN(GetEditBoxText(SearchBox)) > 0
					SetEditBoxText(SearchBox, LEFT( GetEditBoxText(SearchBox), LEN(GetEditBoxText(SearchBox))-1))
					If LEN(GetEditBoxText(SearchBox))
						LastChar$ = MID( GetEditBoxText(SearchBox), LEN(GetEditBoxText(SearchBox)),1)
					EndIf
					Sync()
				EndWhile
			EndIf

		Sync()
		Until GetVirtualButtonReleased(GoBUT) or GetRawKeyPressed(13) //ESC
	EndIf
	
	If LEN( GetEditBoxText(SearchBox) ) > 0
		DoSearch(GetEditBoxText(SearchBox))
	EndIf
	
EndFunction

Function DoSearch(ThisSearch$)
	SetViewOffset(0,0)

	YOff = 0
	For x = 0 to Inventory.Length
		If Inventory[x].ID$ = ThisSearch$
			INC Yoff, 50
			ThisItem as Result
			ThisItem.SprID = CreateSprite(0)
				If Results.Length = 0 or MOD(Results.Length,2) = 0
					SetSpriteColor(ThisItem.SprID,192,192,192,255)
				EndIf
				SetSpriteSize(ThisItem.SprID, 360,50)
				SetSpriteY(ThisItem.SprID, Yoff)
				`SetSpriteScissor(ThisItem.SprID,0,50,360,640)
				SetSpriteDepth(ThisItem.SprID,100)
				
			ThisItem.TextID = CreateText(Inventory[x].ItemNum$ + "|" + Inventory[x].ItemName$)
				SetTextSize(ThisItem.TextID,32)
				SetTextAlignment(ThisItem.TextID,0)
				SetTextY(ThisItem.TextID,Yoff)
				SetTextColor(ThisItem.TextID,0,0,0,255)
				`SetTextScissor(ThisItem.TextID,0,50,360,640)
				SetTextDepth(ThisItem.TextID,99)
			ThisItem.ID$ = ThisSearch$
			ThisItem.ItemNum$ = Inventory[x].ItemNum$
			ThisItem.ItemName$ = Inventory[x].ItemName$
			ThisItem.ItemDetails$ = Inventory[x].ItemDetails$
			Results.InsertSorted(ThisItem)
		EndIf

	Next x
	SetSearchActive(0)
	YOff = 0
	Repeat
		Print(Results.Length)
		YOff = Yoff - GetRawMouseWheelDelta()*5
		If Yoff < 0 then Yoff = 0
		If Yoff > (Results.Length-10)*50 then Yoff = (Results.Length-10)*50
		SetViewOffset(0,Yoff)
		If GetPointerPressed()
			ThisPick = GetSpriteHit(GetPointerX(), GetPointerY()+YOff )
		EndIf
		Sync()
	Until ThisPick > 0 or GetRawKeyPressed(27)
	If ThisPick > 0
		ShowDetails( Results.Find(ThisPick) )
	EndIf
	For x = Results.Length to 0 Step -1
		If GetSpriteExists(Results[x].SprID) then DeleteSprite(Results[x].SprID)
		If GetTextExists(Results[x].TextID) then DeleteText(Results[x].TextID)
		Results.Remove(x)
	Next x
EndFunction
Function ShowDetails(Index)
	SetViewOffset(0,0)
	Back = CreateSprite(0)	:	SetSpriteColor(Back,128,0,0,255)
	SetSpriteDepth(Back,50)	:	SetSpriteSize(Back,360,640)
	TXT = CreateText( Results[Index].ItemDetails$)
	SetTextSize(TXT,24)	:	SetTextDepth(TXT,49)
	SetTextPosition(TXT,0,50)
	Repeat

		Sync()
	Until GetVirtualButtonPressed(SearchBUT)
	DeleteSprite(Back)
	DeleteText(TXT)
EndFunction

Function SetSearchActive(Flag)
	SetVirtualButtonVisible(ReturnBUT,Flag)	:	SetVirtualButtonActive(ReturnBUT,Flag)
	SetVirtualButtonVisible(GoBUT,Flag)	:	SetVirtualButtonActive(GoBUT,Flag)
	SetVirtualButtonVisible(ClearBUT,Flag)	:	SetVirtualButtonActive(ClearBUT,Flag)
	
	SetEditBoxActive(SearchBox,Flag)
	SetEditBoxVisible(SearchBox,Flag)

	If Flag = 0 then Flag = 1 Else Flag = 0
	SetVirtualButtonVisible(SearchBUT,Flag)	:	SetVirtualButtonActive(SearchBUT,Flag)
EndFunction



Function GetInventory()
	If GetFileExists(File$)
		LoadInventory()
	Else
		GenerateInventory()
		LoadInventory()
	EndIf
EndFunction

Function GenerateInventory()
	ThisFile = OpenToWrite(File$)
	For x = 1 to 500 //ID$, ItemNum#, ItemName$, ItemDetails$
		ID$ = STR(Random(1,20)) //Searchable
		//Pad Item #s to 6 digits 100001-100100 for uniformity (my preference, not necessary :) )
		x$ = STR(x)
		While LEN(x$) < 3
			x$ = "0" + x$
		EndWhile
		ItemNum$ = "100"+x$
		
		ItemName$ = "Item #" + ItemNum$
		ItemDetails$ = "Details for " + ItemName$ + " (" + ItemNum$ + ")"
		
		WriteLine(ThisFile,ID$+","+ItemNum$+","+ItemName$+","+ItemDetails$)
	Next x
	CloseFile(ThisFile)
EndFunction

Function LoadInventory()
	ThisFile = OpenToRead(File$)
	Repeat
		ThisLine$ = ReadLine(ThisFile)
		If ThisLine$ <> "" //Not sure why it's adding a blank line to the end of the file when Generated...
			ThisItem as Item
				ThisItem.ID$ = GetStringToken(ThisLine$,",",1)
				ThisItem.ItemNum$ = GetStringToken(ThisLine$,",",2)
				ThisItem.ItemName$ = GetStringToken(ThisLine$,",",3)
				ThisItem.ItemDetails$ = GetStringToken(ThisLine$,",",4)
			Inventory.InsertSorted(ThisItem) //will only help so much.
		EndIf
	Until FileEOF(ThisFile)
	CloseFile(ThisFile)
EndFunction

ID$ = STR(Random(1,20)) //Searchable

// Project: table 
// Created: 2022-07-26

// show all errors
SetErrorMode(2)

SetWindowSize( 1024, 768, 0 )
SetVirtualResolution( 1024, 768 )
SetSyncRate( 60, 0 )
UseNewDefaultFonts( 1 )


#constant table_color = makeColor(92,92,92)

Type DataTable
	x as float
	y as float
	width as float
	height as float
	cols as integer
	rows as integer
	data as integer[-1,-1]
	voffset as float
EndType


mytable as DataTable
mytable = createTable(400,300,5,16)
positionTable(mytable, 100, 100)


setCellValue(mytable, 2, 2, "this is a really long test of brown foxes")

a# = 0

do
	
	// Start vertical scrolling
	z = floor(GetRawMouseWheelDelta())
	
	if z
		if z < 0 // scroll down
			a# = -4.0
		else // scroll up
			a# = 4.0
		endif
	endif
	
	if a# <> 0
		if a# < 0
			inc a#, 0.2
			if a# > 0 then a# = 0
			inc mytable.voffset, a#
		else
			dec a#, 0.2
			if a# < 0 then a# = 0
			inc mytable.voffset, a#
		endif
		
		if mytable.voffset > 0 then mytable.voffset = 0
		//updateTable(mytable)
	endif
	// End vertical scrolling
	
	
	if getRawKeyState(37) then mytable.width = mytable.width - 2
	if getRawKeyState(39) then mytable.width = mytable.width + 2
	
	if getRawKeyState(38) then mytable.height = mytable.height - 2
	if getRawKeyState(40) then mytable.height = mytable.height + 2
	

	
	// Draw table borders
	drawTable(mytable)
	
	
	// For efficiency, this should only be called if the table was resized, repositioned, or scrolled
	updateTable(mytable)


    Sync()
loop




function drawTable(t as DataTable)

	drawBox(t.x, t.y, t.x+t.width, t.y+t.height, table_color,table_color,table_color,table_color, 0)
	
	// Column borders
	cellWidth# = t.width / t.cols
	for i = 1 to t.cols-1
		x = t.x + i * cellWidth#
		drawLine(x, t.y, x, t.y+t.height, table_color, table_color)
	next i
	
	
	// Row borders
	cellHeight# = getTextSize(t.data[0,0])*1.5	
	viewableRows = floor(t.height / cellHeight#)
	d = abs(floor(t.voffset / cellHeight#))
	
	for i = d to d+viewableRows 
		y = t.y + i*cellHeight# + t.voffset
		if y < t.y+t.height then drawLine(t.x, y, t.x+t.width, y, table_color, table_color)
	next i
	
	
endfunction


	
function createTable(width, height, cols, rows) 
	t as DataTable
	
	t.width  = width
	t.height = height
	t.rows   = rows
	t.cols   = cols
	t.data.length = cols

	for i = 0 to cols-1
		t.data[i].length = rows
	next i
	
	
	for i = 0 to cols-1
		for j = 0 to rows-1
			t$ = "Field "+str(i)+":"+str(j)
			if i = 0 then t$ = str(j)
			t.data[i,j] = createText(t$)
			setTextSize(t.data[i,j], 15)
		next j
	next i
	
endfunction t





function positionTable(table ref as DataTable, x, y)
	table.x = x
	table.y = y
	
	cellWidth# = table.width / table.cols
	cellHeight# = getTextSize(table.data[0,0]) * 1.5
	
	for i = 0 to table.cols-1
		for j = 0 to table.rows-1
			cx = x + cellWidth# * i
			cy = y + cellHeight# * j + table.voffset
			h1# = max(cy, table.y)
			h# = min(cy+cellHeight#, table.y+table.height)
			setTextPosition(table.data[i,j], cx, cy)
			SetTextScissor(table.data[i,j], cx, h1#, cx+cellWidth#, h#)
			
		next j
	next i
endfunction




function updateTable(table as DataTable)
	cellWidth# = table.width / table.cols
	cellHeight# = getTextSize(table.data[0,0]) * 1.5
	
	for i = 0 to table.cols-1
		for j = 0 to table.rows-1
			cx = table.x + cellWidth# * i
			cy = table.y + cellHeight# * j + table.voffset
			h1# = max(cy, table.y)
			h# = min(cy+cellHeight#, table.y+table.height)
			setTextPosition(table.data[i,j], cx, cy)
			SetTextScissor(table.data[i,j], cx, h1#, cx+cellWidth#, h#)
		next j
	next i
endfunction





function setCellValue(table ref as DataTable, row, col, value$)
	setTextString(table.data[row,col], value$)
endfunction



function min(n1, n2)
	if n1 > n2 then exitfunction n2
endfunction n1


function max(n1, n2)
	if n1 > n2 then exitfunction n1
endfunction n2