distances in 3d - GameCreators Forum

Author

Message

DBasic Khan

20

Years of Service

User Offline

Joined: 3rd Dec 2003

Location: Alpha Quadrent, Sector 1,1 SOL SYS

Posted: 9th Mar 2004 20:33

Link

does anyone know the mathamatical formula to calculate distance between 2 points in 3D space? I know the one for 2D:
squar root((x1-x2)+ (y1-y2))
but what is it for 3D?

Im using Dbasic Classic

Back to top

Profile PM

ReD_eYe

21

Years of Service

User Offline

Joined: 9th Mar 2003

Location: United Kingdom

Posted: 9th Mar 2004 20:40

Link

+ Code Snippet

Function Dist(Obj1,Obj2)
   Ob1x#=object position x(Obj1)
   Ob1z#=object position z(Obj1)
   Ob1y#=object position y(Obj1)
   Ob2x#=object position x(Obj2)
   Ob2z#=object position z(Obj2)
   Ob2y#=object position y(Obj2)

   Dist#=Sqrt((Ob1x#-Ob2x#)^2+(Ob1y#-Ob2y#)^2+(Ob1z#-Ob2z#)^2)
Endfunction dist#

thats the function i use, seems to work

In the beginning, the universe was created...
This made alot of people very angry and it has been widely regarded as a bad idea...
Visit http://redeye.dbspot.com

Back to top

Profile PM Email Website

DBasic Khan

20

Years of Service

User Offline

Joined: 3rd Dec 2003

Location: Alpha Quadrent, Sector 1,1 SOL SYS

Posted: 9th Mar 2004 21:04

Link

yes but that should only work in 2d

Back to top

Profile PM

ReD_eYe

21

Years of Service

User Offline

Joined: 9th Mar 2003

Location: United Kingdom

Posted: 9th Mar 2004 21:06

Link

except it works in 3d, trust me, i've used it many times...

In the beginning, the universe was created...
This made alot of people very angry and it has been widely regarded as a bad idea...
Visit http://redeye.dbspot.com

Back to top

Profile PM Email Website

Tim Ballisto

20

Years of Service

User Offline

Joined: 10th Feb 2004

Location: Right behind you.

Posted: 10th Mar 2004 02:53 Edited at: 10th Mar 2004 02:57

Link

i do believe this is the code you are looking for.

Distance = sqrt((object position x(object1)-object position x(object2))^2 + (object position y(object1)-object position y(object2))^2 + (object position z(object1)-object position z(object2))^2)

i learned this code from hyrichter(i think), so if it's wrong blame HIM, and if it's right thank ME!

Back to top

Profile PM Website

Philip

21

Years of Service

User Offline

Joined: 15th Jun 2003

Location: United Kingdom

Posted: 10th Mar 2004 14:56

Link

Yuck, thats a lot of typing. Why not just use my function? Its much more user friendly. I put it into the codebase here: http://darkbasicpro.thegamecreators.com/?m=codebase_edit&i=59748ee96250002a4455566559c1856a

Cheers

Philip

What do you mean, bears aren't supposed to wear hats and a tie? P1.3ghz / 384 megs / GeForce MX 5200 128meg / WinXP home

Back to top

Profile PM Email

Philip

21

Years of Service

User Offline

Joined: 15th Jun 2003

Location: United Kingdom

Posted: 10th Mar 2004 14:57

Link

... and if that link doesn't work, try this code box:

+ Code Snippet

Rem PJY - simple function to calculate the length of a 3d vector using DBPro's inbuilt 3d maths commands

FUNCTION threeD_distance(x1# AS float, x2# AS float, y1# AS float, y2# AS float, z1# AS float, z2# AS float)

	temp = 1
	null = make vector3(temp)
     set vector3 temp, x1# - x2#, y1# - y2#, z1# - z2#
     length_vector = abs(length vector3(temp))
     null = delete vector3(temp)
               
ENDFUNCTION length_vector

Philip

What do you mean, bears aren't supposed to wear hats and a tie? P1.3ghz / 384 megs / GeForce MX 5200 128meg / WinXP home

Back to top

Profile PM Email

hyrichter

20

Years of Service

User Offline

Joined: 15th Feb 2004

Location: Arizona

Posted: 10th Mar 2004 16:38

Link

Yes, Tim, you did get that code from me.

But I learned it from the Monster Hunt tutorial, so blame THEM if it doesn't work!!

Back to top

Profile PM Email

David T

Retired Moderator

22

Years of Service

User Offline

Joined: 27th Aug 2002

Location: England

Posted: 10th Mar 2004 20:43

Link

+ Code Snippet

Function Dist(Obj1,Obj2)
   Ob1x#=object position x(Obj1)
   Ob1z#=object position z(Obj1)
   Ob1y#=object position y(Obj1)
   Ob2x#=object position x(Obj2)
   Ob2z#=object position z(Obj2)
   Ob2y#=object position y(Obj2)

   Dist#=Sqrt((Ob1x#-Ob2x#)^2+(Ob1y#-Ob2y#)^2+(Ob1z#-Ob2z#)^2)
Endfunction dist#

lol, this looks remarkably similar to a function I wrote and circulated a few years ago.

+ Code Snippet

function dist_obj(o,o2)
ox#=object position x(o2)
oz#=object position z(o2)
oy#=object position y(o2)
dx#=object position x(o)-ox#
dz#=object position z(o)-oz#
dy#=object position y(o)-oy#
dist#=sqrt((dx#*dx#)+(dz#*dz#)+(dy#*dy#))
endfunction dist#

I was once supplied with my own function when I asked a question - how kind

"To do is to be" - Descartes
"To be is to do" - Voltaire
"Do be do be do" - Frank Sinatra

Back to top

Profile PM Email Website

Philip

21

Years of Service

User Offline

Joined: 15th Jun 2003

Location: United Kingdom

Posted: 13th Mar 2004 08:16 Edited at: 13th Mar 2004 08:17

Link

As you'd expect, using the SQRT command (per David T's snippet) is fractionally faster than setting up a DBPro Vector3 and applying the length vector command to it (per my code). This is because the length vector command will itself perform a square root calculation. Both methods ultimately have to use pythagorus' equation.

See:

+ Code Snippet

sync on
sync rate 0
set display mode 1024, 768, 32

temp1 = timer()
for i = 1 to 1000000
	
	number# = Dist(1, 2, 3, 4, 5, 6)	
	
next i
temp2 = timer()
result1 = temp2 - temp1

text 1024 / 2, 768 / 2, "Time1 = " + str$(result1)

sync

wait key

temp1 = timer()
for i = 1 to 1000000
	
	number# = threeD_distance(1, 2, 3, 4, 5, 6)	
	
next i
temp2 = timer()
result2 = temp2 - temp1

text 1024 / 2, 768 / 2, "Time1 = " + str$(result1)
text 1024 / 2, (768 / 2) + 20, "Time2 = " + str$(result2)

sync

wait key



Function Dist(Ob1x#, Ob2x#, Ob1y#, Ob2y#, Ob1z#, Ob2z#)

   Dist# = Sqrt((Ob1x#-Ob2x#)^2+(Ob1y#-Ob2y#)^2+(Ob1z#-Ob2z#)^2)
   
Endfunction dist#




FUNCTION threeD_distance(x1# AS float, x2# AS float, y1# AS float, y2# AS float, z1# AS float, z2# AS float)

     temp = 1
     null = make vector3(temp)
     set vector3 temp, x1# - x2#, y1# - y2#, z1# - z2#
     length_vector = length vector3(temp)
     null = delete vector3(temp)
               
ENDFUNCTION length_vector#

My computer's results for this are:

SQRT route: 2671
Length vector route: 2750

However, the length vector command option will be very considerably faster when you already have vectors created. This is because you no longer have the overhead of making a vector3 each time.

See, for example:

+ Code Snippet

sync on
sync rate 0
set display mode 1024, 768, 32

temp = 1
null = make vector3(temp)
set vector3 temp, 1 - 2, 3 - 4, 5 - 6

temp1 = timer()
for i = 1 to 1000000
	
	Dist# = Sqrt((1 - 2) ^ 2 + (3 - 4) ^ 2 + (5 - 6) ^ 2)
	
next i
temp2 = timer()
result1 = temp2 - temp1

text 1024 / 2, 768 / 2, "Time1 = " + str$(result1)

sync

wait key

temp1 = timer()
for i = 1 to 1000000
	
     length_vector# = length vector3(temp)
	
next i
temp2 = timer()
result2 = temp2 - temp1

text 1024 / 2, 768 / 2, "Time1 = " + str$(result1)
text 1024 / 2, (768 / 2) + 20, "Time2 = " + str$(result2)

sync

wait key
null = delete vector3(temp)

In this situation my results are:

SQRT route: 3511
Length vector route: 120

So thats quite a dramatic difference.

The one thing that does puzzle me with this is why the SQRT route seems to take longer when the function call is omitted. I would have thought the converse should be true.

Cheers

Philip

What do you mean, bears aren't supposed to wear hats and a tie? P1.3ghz / 384 megs / GeForce MX 5200 128meg / WinXP home

Back to top

Profile PM Email

Philip

21

Years of Service

User Offline

Joined: 15th Jun 2003

Location: United Kingdom

Posted: 13th Mar 2004 08:37

Link

Theres one other point I should make. It is that if you are going to use the SQRT method then the ^ 2 mathematical calculation should be avoided if possible. In computational terms this is a slow calculation. Its better to use multiplication instead.

See:

+ Code Snippet

sync on
sync rate 0
set display mode 1024, 768, 32

Rem PJY - the ^ 2 is in computational terms a slow mathematical calculation
temp1 = timer()
for i = 1 to 1000000
	
	Dist# = Sqrt((1 - 2) ^ 2 + (3 - 4) ^ 2 + (5 - 6) ^ 2)
	
next i
temp2 = timer()
result1 = temp2 - temp1

text 1024 / 2, 768 / 2, "Time1 = " + str$(result1)

sync

wait key

Rem PJY - this is better
temp1 = timer()
for i = 1 to 1000000
	
     x# = 1 - 2
	y# = 3 - 4
	z# = 5 - 6
	Dist2# = Sqrt((x# * x#) + (y# * y#) + (z# * z#))
	
next i
temp2 = timer()
result2 = temp2 - temp1

text 1024 / 2, 768 / 2, "Time1 = " + str$(result1)
text 1024 / 2, (768 / 2) + 20, "Time2 = " + str$(result2)

sync

wait key

My computer gives the following results:

^ 2 method: 3538
Multiplication method: 567

So, again, a dramatic difference.

Philip

What do you mean, bears aren't supposed to wear hats and a tie? P1.3ghz / 384 megs / GeForce MX 5200 128meg / WinXP home

Back to top

Profile PM Email

Philip

21

Years of Service

User Offline

Joined: 15th Jun 2003

Location: United Kingdom

Posted: 13th Mar 2004 08:41 Edited at: 13th Mar 2004 08:44

Link

Although I finish off by proving that my length vector method is faster even the multiplication method using SQRT.

See:

+ Code Snippet

sync on
sync rate 0
set display mode 1024, 768, 32

temp = 1
null = make vector3(temp)
set vector3 temp, 1 - 2, 3 - 4, 5 - 6

Rem PJY - even the multiplication method is slower than my length vector method
x# = 1 - 2
y# = 3 - 4
z# = 5 - 6
temp1 = timer()
for i = 1 to 1000000
	
	Dist2# = Sqrt((x# * x#) + (y# * y#) + (z# * z#))
	
next i
temp2 = timer()
result1 = temp2 - temp1

text 1024 / 2, 768 / 2, "Time1 = " + str$(result1)

sync

wait key

Rem PJY - my length vector method is faster
temp1 = timer()
for i = 1 to 1000000
	
     length_vector# = length vector3(temp)
	
next i
temp2 = timer()
result2 = temp2 - temp1

text 1024 / 2, 768 / 2, "Time1 = " + str$(result1)
text 1024 / 2, (768 / 2) + 20, "Time2 = " + str$(result2)

sync

null = delete vector3(temp)

wait key

My computer's results are:

SQRT multiplication method: 480
Length vector method: 117

And that, ladies and gentlemen, is as much as anyone will ever want to know about how to perform quick 3d distance calculations.

Now I'm off to do something more valuable with my life.

Philip

What do you mean, bears aren't supposed to wear hats and a tie? P1.3ghz / 384 megs / GeForce MX 5200 128meg / WinXP home

Back to top

Profile PM Email

Sorry your browser is not supported!

Newcomers DBPro Corner / distances in 3d