I'm sure it would be fairly easy to create a bunch of fixed dust particles that are deleted and created as the ship moves, the way to do this would be to check the distance of the particles behind the ship, when they move out of range then place them at a random x,y point on the plane ahead of the ship, I might write some code for this later. Only problem is, if you are really paying attention to the particles and are moving dead slow, you could reverse and notice that the particles aren't in the same place... I'm sure that won't matter.
rem Initialisation
sync on
sync rate 30
hide mouse
autocam off
rem Make player object and matrix. If you hide the matrix it is
rem a better idea of how it should work
make matrix 1,10000,10000,50,50
make object box 1,100,100,100
noofdust#=50
rem Make the dust
dim dust#(noofdust#,3)
for i=0 to noofdust#-1
make object sphere i+2,4
dust#(i,0)=int(rnd(1000)-500)
dust#(i,1)=int(rnd(1000)-500)
dust#(i,2)=int(rnd(1000)-500)
next i
x#=5000
z#=5000
do
a#=wrapvalue(a#+mousemovex())
rem If the player moves, move the dust in the opposite direction
rem It's all relative.
if mouseclick()=1
x#=x#+(sin(a#)*20)
z#=z#+(cos(a#)*20)
for i=0 to noofdust#-1
dust#(i,0)=dust#(i,0)-(sin(a#)*20)
dust#(i,2)=dust#(i,2)-(cos(a#)*20)
next i
endif
for i=0 to noofdust#-1
rem This just places the dust on the other side of the
rem 'dust box' if it moves out of range. You should have a
rem random dust placer here
if dust#(i,0)>500 then dust#(i,0)=int(rnd(100))-500
if dust#(i,0)<-500 then dust#(i,0)=int(rnd(100))+500
if dust#(i,1)>500 then dust#(i,1)=int(rnd(100))-500
if dust#(i,1)<-500 then dust#(i,1)=int(rnd(100))+500
if dust#(i,2)>500 then dust#(i,2)=int(rnd(100))-500
if dust#(i,2)<-500 then dust#(i,2)=int(rnd(100))+500
rem Position the dust relative to the player.
position object i+2,x#+dust#(i,0),y#+dust#(i,1),z#+dust#(i,2)
next i
rem Position object, camera, rotate object.
position object 1,x#,y#,z#
yrotate object 1,a#
position camera x#,200,z#-300
point camera x#,0,z#
sync
loop
This code demonstrates the principle of scrolling dust, it is by no means perfect. The dust is in a 'dust box' which scrolls around as the player moves. Click the mouse to move.
