Changing Image Colours - GameCreators Forum

Author

Message

kozma_11

22

Years of Service

User Offline

Joined: 17th Sep 2003

Location: Scotland

Posted: 13th Sep 2004 05:19

Link

Hi all,

Here's my problem: I'm currently making a champ man style footy management game and you have the ability to build your clubs stadium and I want the option of modifying the seat colours. So basically I have a bmp file that I want to load up on DB (not pro) and change the colour of the seats from green to say red.

Any ideas would be appreciated!

Thanks!

El Presidente

Back to top

Profile PM Email

Dot Merix

22

Years of Service

User Offline

Joined: 15th Oct 2003

Location: Canada

Posted: 13th Sep 2004 05:36

Link

Why not just have different bmp files, and when the color has been changed, load in the greenchair.bmp, and toss out the redchair.bmp for example?

- Merix

Athlon xp 2400+, 1.0GB Ram, Radeon 9800PRO 128mb

Back to top

Profile PM

kozma_11

22

Years of Service

User Offline

Joined: 17th Sep 2003

Location: Scotland

Posted: 13th Sep 2004 06:04

Link

That's what I'm thinkin of doin but there something like 25 pics for each colour so if I want 10 different colours then thats 10 times as much pics that I need - seems like a waste of space if I can write a function to carry it out as required. Also, I've got small football guys that you will be able to watch score goals etc but will need to have their strips changed for each team. So if their are 400 teams to choose from then I would need to have 400 sets of animated sprites when I want to do it with one and simply change the colours as required

El Presidente

Back to top

Profile PM Email

the_winch

23

Years of Service

User Offline

Joined: 1st Feb 2003

Location: Oxford, UK

Posted: 13th Sep 2004 07:47

Link

Unfortunatly db is a bit lacking in these sorts of commands.
I think the only way you can do is go through the image a pixel at a time and changee the colour of the pixel if required.
The quickest way to do it will be with an image memblock.

it's cool to hate

Back to top

Profile PM Website

Pincho Paxton

23

Years of Service

User Offline

Joined: 8th Dec 2002

Location:

Posted: 14th Sep 2004 20:32

Link

You can make a grey seat.
Then have a rgb slider that you will have to make.
cls hidden screen with the colour of the slider.
get image from hidden screen.
put image on plain.
ghost plain.
Put ghosted plain over the seat. Or dark ghosted.
get seat image.

May need a bit of experimentation. You could also..

Get image red
Get image green
Get image blue
Put images on 3 plains
Ghost plains

Then use them combined as a colour filter.

I think you get the idea.

Back to top

Profile PM Email Website

IanM

Retired Moderator

23

Years of Service

User Offline

Joined: 11th Sep 2002

Location: In my moon base

Posted: 17th Sep 2004 03:57

Link

If you can come up with a colour or colour range that you want to change, then it is possible - as long as you don't want it to be lightning fast too.

Here is a very basic example - run in 32 bit mode only:

` Simplified colour constants
#constant C_BLACK      0x00
#constant C_BLUE       0x01
#constant C_GREEN      0x02
#constant C_CYAN       0x03
#constant C_RED        0x04
#constant C_PURPLE     0x05
#constant C_YELLOW     0x06
#constant C_WHITE      0x07

sync on
sync rate 0
sync
sync

set window off
set display mode 640, 480, 32

for i=0 to 40
   ink SelectColour( rnd(6)+1 ), 0
   DrawBox(rnd(47), rnd(47), 16-rnd(15), 16-rnd(15))
next i

get image 1, 0, 0, 64, 64, 1

do
   cls
   ChangeFrom = rnd(7)
   repeat
      ChangeTo   = rnd(7)
   until ChangeTo <> ChangeFrom

ConvertImageColour(1, 2, SelectColour( ChangeFrom ), SelectColour( ChangeTo ) )

sprite 1, 50, 50, 1
   sprite 2, 120, 50, 2

text 0, 0, "Changing the colour " + ColourName(ChangeFrom) + " to " + ColourName(ChangeTo)

sync
   wait key
loop

function ConvertImageColour(SourceImg as integer, DestImg as integer, SourceCol as dword, DestCol as dword)
   local i as integer

make memblock from image 1, SourceImg

i=12
   while i < get memblock size(1)
      if (memblock dword(1, i) || 0xff000000) = SourceCol then write memblock dword 1, i, DestCol
      inc i, 4
   endwhile

make image from memblock DestImg, 1
   delete memblock 1
endfunction

function DrawBox(x as integer, y as integer, width as integer, height as integer)
   box x, y, x+width, y+height
endfunction

` Provide simplified colours
function SelectColour(Colour as dword)
   local Red as integer
   local Green as integer
   local Blue as integer
   local Result as dword

if (Colour && 4) > 0 then Red = 255
   if (Colour && 2) > 0 then Green = 255
   if (Colour && 1) > 0 then Blue = 255

Result = rgb(Red, Green, Blue)
endfunction Result

function ColourName(colour as dword)
   local Name as string
   select colour
      case C_BLACK  : Name = "Black"   : endcase
      case C_BLUE   : Name = "Blue"    : endcase
      case C_GREEN  : Name = "Green"   : endcase
      case C_CYAN   : Name = "Cyan"    : endcase
      case C_RED    : Name = "Red"     : endcase
      case C_PURPLE : Name = "Purple"  : endcase
      case C_YELLOW : Name = "Yellow"  : endcase
      case C_WHITE  : Name = "White"   : endcase
   endselect
endfunction Name

+ Code Snippet

` Simplified colour constants
#constant C_BLACK      0x00
#constant C_BLUE       0x01
#constant C_GREEN      0x02
#constant C_CYAN       0x03
#constant C_RED        0x04
#constant C_PURPLE     0x05
#constant C_YELLOW     0x06
#constant C_WHITE      0x07

sync on
sync rate 0
sync
sync

set window off
set display mode 640, 480, 32

for i=0 to 40
   ink SelectColour( rnd(6)+1 ), 0
   DrawBox(rnd(47), rnd(47), 16-rnd(15), 16-rnd(15))
next i

get image 1, 0, 0, 64, 64, 1

do
   cls
   ChangeFrom = rnd(7)
   repeat
      ChangeTo   = rnd(7)
   until ChangeTo <> ChangeFrom

   ConvertImageColour(1, 2, SelectColour( ChangeFrom ), SelectColour( ChangeTo ) )

   sprite 1, 50, 50, 1
   sprite 2, 120, 50, 2

   text 0, 0, "Changing the colour " + ColourName(ChangeFrom) + " to " + ColourName(ChangeTo)

   sync
   wait key
loop

function ConvertImageColour(SourceImg as integer, DestImg as integer, SourceCol as dword, DestCol as dword)
   local i as integer

   make memblock from image 1, SourceImg

   i=12
   while i < get memblock size(1)
      if (memblock dword(1, i) || 0xff000000) = SourceCol then write memblock dword 1, i, DestCol
      inc i, 4
   endwhile

   make image from memblock DestImg, 1
   delete memblock 1
endfunction


function DrawBox(x as integer, y as integer, width as integer, height as integer)
   box x, y, x+width, y+height
endfunction

` Provide simplified colours
function SelectColour(Colour as dword)
   local Red as integer
   local Green as integer
   local Blue as integer
   local Result as dword

   if (Colour && 4) > 0 then Red = 255
   if (Colour && 2) > 0 then Green = 255
   if (Colour && 1) > 0 then Blue = 255

   Result = rgb(Red, Green, Blue)
endfunction Result

function ColourName(colour as dword)
   local Name as string
   select colour
      case C_BLACK  : Name = "Black"   : endcase
      case C_BLUE   : Name = "Blue"    : endcase
      case C_GREEN  : Name = "Green"   : endcase
      case C_CYAN   : Name = "Cyan"    : endcase
      case C_RED    : Name = "Red"     : endcase
      case C_PURPLE : Name = "Purple"  : endcase
      case C_YELLOW : Name = "Yellow"  : endcase
      case C_WHITE  : Name = "White"   : endcase
   endselect
endfunction Name

*** Coming soon - Network Plug-in - Check my site for info ***
For free Plug-ins, source and the Interface library for Visual C++ 6, .NET and now for Dev-C++ http://www.matrix1.demon.co.uk

Back to top

Profile PM Email Website

Sorry your browser is not supported!

2D All the way! / Changing Image Colours