This what you want?
` set up display and camera
sync on
sync rate 60
backdrop on
autocam off
set camera range 0.5, 30000
` movement
g_fSpeed# = 0.05
g_fTurn# = 0.3
` set the directory to media
set dir "media"
` load base and detail texture
load image "texture.bmp", 1
load image "detail.tga", 2
make object terrain 1 ` create the terrain object
set terrain heightmap 1, "map.bmp" ` set the heightmap
set terrain scale 1, 1, .1, 1 ` set the scale
set terrain split 1, 16 ` split value by 16 * 16
set terrain tiling 1, 4 ` detail map tiling
set terrain light 1, 1, -0.25, 0, 1, 1, 0.78, 0.5 ` light - xdir, ydir, zdir, red, green, blue, intensity
set terrain texture 1, 1, 2 ` base and detail texture
build terrain 1 ` finally build the terrain
` load our skybox
load object "skybox2.x", 200
set object light 200, 0
set object texture 200, 3, 1
position object 200, 1000, 2000, 4000
scale object 200, 30000, 30000, 30000
` reset the directory
set dir ".."
REM Car
make object cube 2,100
scale object 2, 3,1,5
color object 2, 120
make object cone 6, 5
hide limb 6,0
glue object to limb 2,6,0
DO
gosub _controls
tilt(1,x#,z#,a#)
gosub _camera
update terrain
sync
loop
_controls:
if upkey()=1 then x#=newxvalue(x#,a#,.5) : z#=newzvalue(z#,a#,.5)
if leftkey()=1 then a#=wrapvalue(a#-1.0)
if rightkey()=1 then a#=wrapvalue(a#+1.0)
y# = get terrain ground height(1,x#,z#)
RETURN
_camera:
rem Position camera to the back of the character
cx#=newxvalue(x#,wrapvalue(a#+180),30)
cz#=newzvalue(z#,wrapvalue(a#+180),30)
cy#=get terrain ground height(1,cx#,cz#)+30.0
position camera cx#,cy#,cz#
rem Point camera at object
point camera x#,y#+5,z#
RETURN
function tilt(number as integer, x# as float, z# as float, ang# as float)
h1# = get terrain ground height(number, x#, z#)
tx# = newxvalue(x#,wrapvalue(ang#+90),2)
tz# = newzvalue(z#,wrapvalue(ang#+90),2)
h2# = get terrain ground height(number, tx#, tz#)
at# = h2# - h1#
b# = 2
angz# = atan(at#/b#)
tx# = newxvalue(x#,ang#,2)
tz# = newzvalue(z#,ang#,2)
h2# = get terrain ground height(number, tx#, tz#)
at# = h2# - h1#
angx# = 360 - atan(at#/b#)
position object 6, x#, h1#+0.5, z#
yrotate object 6,ang#
rotate object 2,angx#,0,angz#
endfunction
"eureka" - Archimedes
