How to rotate 3 spheres on external axis??

Author

Message

Vues3d on Kalimee

21

Years of Service

User Offline

Joined: 12th May 2004

Location: NYON (SWITZERLAND)

Posted: 3rd Dec 2004 19:28

Link

Here's my problem - that's just a matematic problem :

I have 3 spheres & would like to rotate them around a point. (See picture)
What kind of formula have I to use??

A little code should be really helpful...
Thanx in advance for all of you that will help.

Guido
http://www.vues3d.com

Back to top

Profile PM Email Website

French gui

21

Years of Service

User Offline

Joined: 11th May 2004

Location: France

Posted: 3rd Dec 2004 21:13 Edited at: 3rd Dec 2004 21:16

Link

hmmm....

d is distance between spheres and center point
x and z are your center point:
a1,a2 and a3 are the angles of each sphere (for ex: 0,120,240)

position object (sphere1),x+cos(a1)*d,0,z+sin(a1)*d
idem for sphere2 and 3

You just have to increase a1,a2 and a3 to rotate them.
Note that they will turn only around the y axis.(If you have to turn around any axis better buy EZ rotate...

)

My English is not so good I'm just French

Back to top

Profile PM Website

Van B

Moderator

22

Years of Service

User Offline

Joined: 8th Oct 2002

Location: Sunnyvale

Posted: 3rd Dec 2004 21:25 Edited at: 3rd Dec 2004 21:27

Link

You could offset limb 0 - then rotate the object, you'd offset on the Y axis by your desired radius you see, then the mesh is like a lollipop without the stick

. The problem is that it can be quite tricky to avoid occlusion problems, like the bounding box does'nt change - it might work nicely if you make a spere 5 times as big as you need it, then scale it down to 20,20,20 - this might leave the bounding box in a usable state.

You'd probably make good use of EZRotate anyway, did you buy the special offer thing?

Van-B

It's c**p being the only coder in the village.

Back to top

Profile PM Email

Mnemonix

22

Years of Service

User Offline

Joined: 2nd Dec 2002

Location: Skaro

Posted: 4th Dec 2004 04:32

Link

Im not very good at 3d, but would it work if you used an invisible object in the middle and then made the spheres limbs of the invisible object or something to that effect. If this is wrong then please ignore me because I am not good at 3D.

The 3d chat is coming...
Rights For Traffic Cones!

Back to top

Profile PM Email Website

Benjamin

22

Years of Service

User Offline

Joined: 24th Nov 2002

Location: France

Posted: 4th Dec 2004 04:45

Link

Do what French gui said, thats how I normally do it.

Raven: That said, I DO say 'that said' a lot. 'Nuf said.

Back to top

Profile PM Email

Lost in Thought

21

Years of Service

User Offline

Joined: 4th Feb 2004

Location: U.S.A. : Douglas, Georgia

Posted: 4th Dec 2004 11:26

Link

Yeah I just cheat as well because I don't know much about 3d math.

+ Code Snippet

sync on : sync rate 0
hide mouse
backdrop on
color backdrop 0
autocam off
position camera 0,40,0
point camera 0,0,0

make object sphere 1, 3
for i = 2 to 3
	make object sphere 2, 3
	make mesh from object 1,2
	add limb 1,i-1,1
	delete mesh 1
	delete object 2
next i
offset limb 1,0,0,0,5
offset limb 1,1,4.33012676239,0,-2.5
offset limb 1,2,-4.33012676239,0,-2.5
color limb 1,0,rgb(255,0,0)
color limb 1,1,rgb(0,255,0)
color limb 1,2,rgb(0,0,255)

do
	yrotate object 1, object angle y(1)+.2
	sync
loop

But as soon as I find a way to get EZRotate to work with NGC properly I wil buy it and just use the rotate object around point command

Back to top

Profile PM Email

Vues3d on Kalimee

21

Years of Service

User Offline

Joined: 12th May 2004

Location: NYON (SWITZERLAND)

Posted: 6th Dec 2004 17:00

Link

Hi there!!

Thanx to everybody for the help.
I will manage the use of the code done by "Lost in Thought" & adapt it on my purposes.
I've to study the Limb commands to better understand the way it works, (Also because I've to manage the rotation of each sphere around the center point).
Will post the result as soon as I finish the code.
This will take place in the L5.

Guido
http://www.vues3d.com

Back to top

Profile PM Email Website

Lost in Thought

21

Years of Service

User Offline

Joined: 4th Feb 2004

Location: U.S.A. : Douglas, Georgia

Posted: 6th Dec 2004 17:50 Edited at: 6th Dec 2004 18:00

Link

Here is a better version. Just change the first 4 variables and it does all the work.

Orbit_Diam
Orb_Obj_Num
Orbit_x#
Orbit_z#

[edit] edited code to recolor all limbs no matter how many you set
and increased the number of orbit objects and the orbit diameter

sync on : sync rate 0
hide mouse
backdrop on
color backdrop 0
autocam off

`set diameter of orbit wanted
Orbit_Diam = 20
`number of objects to orbit
Orb_Obj_Num = 20
`set where to orbit on x and z axis
Orbit_x# = 20
Orbit_z# = 20

dim obj_x#(Orb_Obj_Num) as float
dim obj_y#(Orb_Obj_Num) as float
dim obj_z#(Orb_Obj_Num) as float

`make objects to orbit
for i = 1 to Orb_Obj_Num
	make object sphere i, 3
next i
rotate_value = (360/Orb_Obj_Num)
Limb_Num = 0
`rotate objects and move orbit distance
`and record positions in orbit for limb offsets
for i = 1 to Orb_Obj_Num
	yrotate object i, rotate_value*Limb_Num
	move object i, Orbit_Diam
	inc Limb_Num, 1
	obj_x#(i) = object position x(i)
	obj_y#(i) = object position y(i)
	obj_z#(i) = object position z(i)
next i

`from #2 to Orb_Obj_Num
`add objects to limb and delete unneeded objects and meshes
for i = 2 to Orb_Obj_Num
	make mesh from object 1, i
	add limb 1,i-1,1
	delete mesh 1
	delete object i
next i

`offset limbs from values stored earlier
for i = 1 to Orb_Obj_Num
	offset limb 1,i-1,obj_x#(i),obj_y#(i),obj_z#(i)
	color limb 1,i-1,rgb(rnd(255),rnd(255),rnd(255))
next i

`make an object to show you where it should orbit.
make object sphere 4, 1
`position marker object, orbit object, and camera where orbit wanted
position object 4, Orbit_x#, 0, Orbit_z#
position object 1, Orbit_x#, 0, Orbit_z#
position camera Orbit_x#,40,Orbit_z#
`point camera at orbit center
point camera Orbit_x#,0,Orbit_z#

do
	`make object orbit
	yrotate object 1, object angle y(1)+.2
	sync
loop

+ Code Snippet

sync on : sync rate 0
hide mouse
backdrop on
color backdrop 0
autocam off

`set diameter of orbit wanted
Orbit_Diam = 20
`number of objects to orbit
Orb_Obj_Num = 20
`set where to orbit on x and z axis
Orbit_x# = 20
Orbit_z# = 20

dim obj_x#(Orb_Obj_Num) as float
dim obj_y#(Orb_Obj_Num) as float
dim obj_z#(Orb_Obj_Num) as float

`make objects to orbit
for i = 1 to Orb_Obj_Num
	make object sphere i, 3
next i
rotate_value = (360/Orb_Obj_Num)
Limb_Num = 0
`rotate objects and move orbit distance
`and record positions in orbit for limb offsets
for i = 1 to Orb_Obj_Num
	yrotate object i, rotate_value*Limb_Num
	move object i, Orbit_Diam
	inc Limb_Num, 1
	obj_x#(i) = object position x(i)
	obj_y#(i) = object position y(i)
	obj_z#(i) = object position z(i)
next i

`from #2 to Orb_Obj_Num
`add objects to limb and delete unneeded objects and meshes
for i = 2 to Orb_Obj_Num
	make mesh from object 1, i
	add limb 1,i-1,1
	delete mesh 1
	delete object i
next i

`offset limbs from values stored earlier
for i = 1 to Orb_Obj_Num
	offset limb 1,i-1,obj_x#(i),obj_y#(i),obj_z#(i)
	color limb 1,i-1,rgb(rnd(255),rnd(255),rnd(255))
next i

`make an object to show you where it should orbit.
make object sphere 4, 1
`position marker object, orbit object, and camera where orbit wanted
position object 4, Orbit_x#, 0, Orbit_z#
position object 1, Orbit_x#, 0, Orbit_z#
position camera Orbit_x#,40,Orbit_z#
`point camera at orbit center
point camera Orbit_x#,0,Orbit_z#

do
	`make object orbit
	yrotate object 1, object angle y(1)+.2
	sync
loop

Back to top

Profile PM Email

Vues3d on Kalimee

21

Years of Service

User Offline

Joined: 12th May 2004

Location: NYON (SWITZERLAND)

Posted: 6th Dec 2004 18:24

Link

Yes!! Lost, with your last post, you solved all the problem I should encounter & indirectly answered to all the questions I would have.
The code is perfect & now I also know HOW to handle limbs.
This helped me a lot & I won at least 1 day of coding!!!!

REALLY REALLY THANX!!!

Guido
http://www.vues3d.com

Back to top

Profile PM Email Website

Lost in Thought

21

Years of Service

User Offline

Joined: 4th Feb 2004

Location: U.S.A. : Douglas, Georgia

Posted: 7th Dec 2004 02:55

Link

Glad I could help.

Back to top

Profile PM Email

Sorry your browser is not supported!

DarkBASIC Professional Discussion / How to rotate 3 spheres on external axis??